src/third_party/libc++abi/trunk/CMakeLists.txt

   1 #===============================================================================
   2 # Setup Project
   3 #===============================================================================
   4
   5 cmake_minimum_required(VERSION 2.8.8)
   6
   7 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
   8   project(libcxxabi)
   9
  10   # Rely on llvm-config.
  11   set(CONFIG_OUTPUT)
  12   find_program(LLVM_CONFIG "llvm-config")
  13   if(DEFINED LLVM_PATH)
  14     set(LLVM_INCLUDE_DIR ${LLVM_INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  15     set(LLVM_PATH ${LLVM_PATH} CACHE PATH "Path to LLVM source tree")
  16     set(LLVM_MAIN_SRC_DIR ${LLVM_PATH})
  17     set(LLVM_CMAKE_PATH "${LLVM_PATH}/cmake/modules")
  18   elseif(LLVM_CONFIG)
  19     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  20     set(CONFIG_COMMAND ${LLVM_CONFIG}
  21       "--includedir"
  22       "--prefix"
  23       "--src-root")
  24     execute_process(
  25       COMMAND ${CONFIG_COMMAND}
  26       RESULT_VARIABLE HAD_ERROR
  27       OUTPUT_VARIABLE CONFIG_OUTPUT
  28     )
  29     if(NOT HAD_ERROR)
  30       string(REGEX REPLACE
  31         "[ \t]*[\r\n]+[ \t]*" ";"
  32         CONFIG_OUTPUT ${CONFIG_OUTPUT})
  33     else()
  34       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  35       message(STATUS "${CONFIG_COMMAND_STR}")
  36       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  37     endif()
  38
  39     list(GET CONFIG_OUTPUT 0 INCLUDE_DIR)
  40     list(GET CONFIG_OUTPUT 1 LLVM_OBJ_ROOT)
  41     list(GET CONFIG_OUTPUT 2 MAIN_SRC_DIR)
  42
  43     set(LLVM_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  44     set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  45     set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  46     set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR}/share/llvm/cmake")
  47     set(LLVM_LIT_PATH "${LLVM_PATH}/utils/lit/lit.py")
  48   else()
  49     message(FATAL_ERROR "llvm-config not found and LLVM_MAIN_SRC_DIR not defined")
  50   endif()
  51
  52   if(EXISTS ${LLVM_CMAKE_PATH})
  53     list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  54     include("${LLVM_CMAKE_PATH}/AddLLVM.cmake")
  55     include("${LLVM_CMAKE_PATH}/HandleLLVMOptions.cmake")
  56   else()
  57     message(FATAL_ERROR "Not found: ${LLVM_CMAKE_PATH}")
  58   endif()
  59
  60   set(PACKAGE_NAME libcxxabi)
  61   set(PACKAGE_VERSION 3.6.0svn)
  62   set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  63   set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  64
  65   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
  66     set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
  67   else()
  68     # Seek installed Lit.
  69     find_program(LLVM_LIT "lit.py" ${LLVM_MAIN_SRC_DIR}/utils/lit
  70       DOC "Path to lit.py")
  71   endif()
  72
  73   if(LLVM_LIT)
  74     # Define the default arguments to use with 'lit', and an option for the user
  75     # to override.
  76     set(LIT_ARGS_DEFAULT "-sv")
  77     if (MSVC OR XCODE)
  78       set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
  79     endif()
  80     set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
  81
  82     # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
  83     if( WIN32 AND NOT CYGWIN )
  84       set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
  85     endif()
  86   else()
  87     set(LLVM_INCLUDE_TESTS OFF)
  88   endif()
  89
  90   set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  91   set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  92
  93   set(LIBCXXABI_BUILT_STANDALONE 1)
  94 else()
  95   set(LLVM_LIT "${CMAKE_SOURCE_DIR}/utils/lit/lit.py")
  96 endif()
  97
  98 #===============================================================================
  99 # Setup CMake Options
 100 #===============================================================================
 101
 102 # Define options.
 103 option(LIBCXXABI_ENABLE_ASSERTIONS "Enable assertions independent of build mode." ON)
 104 option(LIBCXXABI_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 105 option(LIBCXXABI_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 106 option(LIBCXXABI_USE_LLVM_UNWINDER "Build and use the LLVM unwinder." OFF)
 107
 108 # Default to building a shared library so that the default options still test
 109 # the libc++abi that is being built. There are two problems with testing a
 110 # static libc++abi. In the case of a standalone build, the tests will link the
 111 # system's libc++, which might not have been built against our libc++abi. In the
 112 # case of an in tree build, libc++ will prefer a dynamic libc++abi from the
 113 # system over a static libc++abi from the output directory.
 114 option(LIBCXXABI_ENABLE_SHARED "Build libc++abi as a shared library." ON)
 115
 116 find_path(
 117   LIBCXXABI_LIBCXX_INCLUDES
 118   vector
 119   PATHS ${LIBCXXABI_LIBCXX_INCLUDES}
 120         ${CMAKE_BINARY_DIR}/${LIBCXXABI_LIBCXX_INCLUDES}
 121         ${LLVM_MAIN_SRC_DIR}/projects/libcxx/include
 122         ${LLVM_INCLUDE_DIR}/c++/v1
 123   )
 124
 125 set(LIBCXXABI_LIBCXX_INCLUDES "${LIBCXXABI_LIBCXX_INCLUDES}" CACHE STRING
 126     "Specify path to libc++ includes." FORCE)
 127
 128 #===============================================================================
 129 # Configure System
 130 #===============================================================================
 131
 132 # Add path for custom modules
 133 set(CMAKE_MODULE_PATH
 134   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 135   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
 136   ${CMAKE_MODULE_PATH}
 137   )
 138
 139 # Configure compiler.
 140 include(config-ix)
 141
 142 #===============================================================================
 143 # Setup Compiler Flags
 144 #===============================================================================
 145
 146 # Get required flags.
 147 macro(append_if list condition var)
 148   if (${condition})
 149     list(APPEND ${list} ${var})
 150   endif()
 151 endmacro()
 152
 153 if (LIBCXXABI_HAS_NOSTDINCXX_FLAG)
 154   list(APPEND LIBCXXABI_CXX_REQUIRED_FLAGS -nostdinc++)
 155 endif()
 156
 157 append_if(LIBCXXABI_CXX_REQUIRED_FLAGS LIBCXXABI_HAS_WERROR_FLAG -Werror=return-type)
 158
 159 # Get warning flags
 160 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_W_FLAG -W)
 161 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WALL_FLAG -Wall)
 162 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WCHAR_SUBSCRIPTS_FLAG -Wchar-subscripts)
 163 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WCONVERSION_FLAG -Wconversion)
 164 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WMISMATCHED_TAGS_FLAG -Wmismatched-tags)
 165 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WMISSING_BRACES_FLAG -Wmissing-braces)
 166 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WNEWLINE_EOF_FLAG -Wnewline-eof)
 167 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WNO_UNUSED_FUNCTION_FLAG -Wno-unused-function)
 168 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WSHADOW_FLAG -Wshadow)
 169 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WSHORTEN_64_TO_32_FLAG -Wshorten-64-to-32)
 170 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WSIGN_COMPARE_FLAG -Wsign-compare)
 171 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WSIGN_CONVERSION_FLAG -Wsign-conversion)
 172 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WSTRICT_ALIASING_FLAG -Wstrict-aliasing=2)
 173 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WSTRICT_OVERFLOW_FLAG -Wstrict-overflow=4)
 174 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WUNUSED_PARAMETER_FLAG -Wunused-parameter)
 175 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WUNUSED_VARIABLE_FLAG -Wunused-variable)
 176 append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WWRITE_STRINGS_FLAG -Wwrite-strings)
 177
 178 if (LIBCXXABI_ENABLE_WERROR)
 179   append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WERROR_FLAG -Werror)
 180   append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WX_FLAG -WX)
 181 else()
 182   append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_WNO_ERROR_FLAG -Wno-error)
 183   append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_NO_WX_FLAG -WX-)
 184 endif()
 185 if (LIBCXXABI_ENABLE_PEDANTIC)
 186   append_if(LIBCXXABI_CXX_WARNING_FLAGS LIBCXXABI_HAS_PEDANTIC_FLAG -pedantic)
 187 endif()
 188
 189 # Get feature flags.
 190 # Exceptions
 191 # Catches C++ exceptions only and tells the compiler to assume that extern C
 192 # functions never throw a C++ exception.
 193 append_if(LIBCXXABI_CXX_FEATURE_FLAGS LIBCXXABI_HAS_FSTRICT_ALIASING_FLAG -fstrict-aliasing)
 194 append_if(LIBCXXABI_CXX_FEATURE_FLAGS LIBCXXABI_HAS_EHSC_FLAG -EHsc)
 195
 196 # Assert
 197 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 198 if (LIBCXXABI_ENABLE_ASSERTIONS)
 199   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
 200   if (NOT MSVC)
 201     list(APPEND LIBCXXABI_CXX_FEATURE_FLAGS -D_DEBUG)
 202   endif()
 203   # On Release builds cmake automatically defines NDEBUG, so we
 204   # explicitly undefine it:
 205   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 206     list(APPEND LIBCXXABI_CXX_FEATURE_FLAGS -UNDEBUG)
 207   endif()
 208 else()
 209   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 210     list(APPEND LIBCXXABI_CXX_FEATURE_FLAGS -DNDEBUG)
 211   endif()
 212 endif()
 213 # Static library
 214 if (NOT LIBCXXABI_ENABLE_SHARED)
 215   list(APPEND LIBCXXABI_CXX_FEATURE_FLAGS -D_LIBCPP_BUILD_STATIC)
 216 endif()
 217
 218 # This is the _ONLY_ place where add_definitions is called.
 219 if (MSVC)
 220   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 221 endif()
 222
 223 string(REPLACE ";" " " LIBCXXABI_CXX_REQUIRED_FLAGS "${LIBCXXABI_CXX_REQUIRED_FLAGS}")
 224 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${LIBCXXABI_CXX_REQUIRED_FLAGS}")
 225
 226 string(REPLACE ";" " " LIBCXXABI_CXX_WARNING_FLAGS "${LIBCXXABI_CXX_WARNING_FLAGS}")
 227 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${LIBCXXABI_CXX_WARNING_FLAGS}")
 228
 229 string(REPLACE ";" " " LIBCXXABI_CXX_FEATURE_FLAGS "${LIBCXXABI_CXX_FEATURE_FLAGS}")
 230 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${LIBCXXABI_CXX_FEATURE_FLAGS}")
 231
 232 #===============================================================================
 233 # Setup Source Code
 234 #===============================================================================
 235
 236 include_directories(include)
 237
 238 # Add source code. This also contains all of the logic for deciding linker flags
 239 # soname, etc...
 240 add_subdirectory(src)
 241
 242 if (LIBCXXABI_USE_LLVM_UNWINDER)
 243   add_subdirectory(src/Unwind)
 244 endif()
 245
 246 if(NOT LIBCXXABI_ENABLE_SHARED)
 247   # TODO: Fix the libc++ cmake files so that libc++abi can be statically linked.
 248   # As it is now, libc++ will prefer linking against a dynamic libc++abi in the
 249   # system library paths over a static libc++abi in the out directory. This
 250   # would test the system library rather than the one we just built, which isn't
 251   # very helpful.
 252   message(WARNING "The libc++abi tests are currently only valid when "
 253                   "LIBCXXABI_ENABLE_SHARED is on, no check target will be "
 254                   "available!")
 255 else()
 256   add_subdirectory(test)
 257 endif()