dali-toolkit/internal/graphics/shaders/color-visual-shader.vert

   1 INPUT mediump vec2 aPosition;
   2 #if defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE) || defined(IS_REQUIRED_BLUR)
   3 OUTPUT mediump vec2 vPosition;
   4 OUTPUT mediump vec2 vRectSize;
   5 OUTPUT mediump vec2 vOptRectSize;
   6 #ifdef IS_REQUIRED_ROUNDED_CORNER
   7 OUTPUT mediump vec4 vCornerRadius;
   8 #endif
   9 #endif
  10
  11 uniform highp mat4 uMvpMatrix;
  12 uniform highp vec3 uSize;
  13
  14 //Visual size and offset
  15 uniform mediump vec2 offset;
  16 uniform highp vec2 size;
  17 uniform mediump vec4 offsetSizeMode;
  18 uniform mediump vec2 origin;
  19 uniform mediump vec2 anchorPoint;
  20 #ifdef IS_REQUIRED_BLUR
  21 uniform mediump float blurRadius;
  22 #elif defined(IS_REQUIRED_BORDERLINE)
  23 uniform mediump float borderlineWidth;
  24 uniform mediump float borderlineOffset;
  25 #endif
  26 #ifdef IS_REQUIRED_ROUNDED_CORNER
  27 uniform mediump vec4 cornerRadius;
  28 uniform mediump float cornerRadiusPolicy;
  29 #endif
  30 uniform mediump vec2 extraSize;
  31
  32 vec4 ComputeVertexPosition()
  33 {
  34   vec2 visualSize = mix(size * uSize.xy, size, offsetSizeMode.zw ) + extraSize;
  35   vec2 visualOffset = mix(offset * uSize.xy, offset, offsetSizeMode.xy);
  36
  37 #if defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE) || defined(IS_REQUIRED_BLUR)
  38   vRectSize = visualSize * 0.5;
  39   vOptRectSize = vRectSize;
  40 #endif
  41
  42 #ifdef IS_REQUIRED_ROUNDED_CORNER
  43 #ifdef IS_REQUIRED_BLUR
  44   mediump float minSize = min(visualSize.x, visualSize.y);
  45 #elif defined(IS_REQUIRED_BORDERLINE)
  46   mediump float minSize = min(visualSize.x, visualSize.y) + (1.0 + clamp(borderlineOffset, -1.0, 1.0)) * borderlineWidth;
  47 #else
  48   mediump float minSize = min(visualSize.x, visualSize.y);
  49 #endif
  50   vCornerRadius = mix(cornerRadius * minSize, cornerRadius, cornerRadiusPolicy);
  51   vCornerRadius = min(vCornerRadius, minSize * 0.5);
  52   // Optimize fragment shader. 0.2929 ~= 1.0 - sqrt(0.5)
  53   mediump float maxRadius = max(max(vCornerRadius.x, vCornerRadius.y), max(vCornerRadius.z, vCornerRadius.w));
  54   vOptRectSize -= 0.2929 * maxRadius + 1.0;
  55 #endif
  56
  57 #ifdef IS_REQUIRED_BLUR
  58   vPosition = aPosition * (visualSize + 2.0 * blurRadius);
  59   vOptRectSize -= blurRadius + 1.0;
  60 #elif defined(IS_REQUIRED_BORDERLINE)
  61   vPosition = aPosition * (visualSize + (1.0 + clamp(borderlineOffset, -1.0, 1.0))* borderlineWidth);
  62   vOptRectSize -= (1.0 - clamp(borderlineOffset, -1.0, 1.0)) * 0.5 * borderlineWidth + 1.0;
  63 #elif defined(IS_REQUIRED_ROUNDED_CORNER)
  64   vPosition = aPosition * visualSize;
  65 #else
  66   mediump vec2 vPosition = aPosition * visualSize;
  67 #endif
  68   return vec4(vPosition + anchorPoint * visualSize + visualOffset + origin * uSize.xy, 0.0, 1.0);
  69 }
  70
  71 void main()
  72 {
  73   gl_Position = uMvpMatrix * ComputeVertexPosition();
  74 }