dali-scene3d/internal/graphics/shaders/default-physically-based-shader.frag

   1 #version 300 es
   2
   3 // Original Code
   4 // https://github.com/KhronosGroup/glTF-Sample-Viewer/blob/glTF-WebGL-PBR/shaders/pbr-frag.glsl
   5 // Commit dc84b5e374fb3d23153d2248a338ef88173f9eb6
   6 //
   7 // This fragment shader defines a reference implementation for Physically Based Shading of
   8 // a microfacet surface material defined by a glTF model.For the DamagedHelmet.gltf and its Assets
   9 //
  10 // References:
  11 // [1] Real Shading in Unreal Engine 4
  12 //     http://blog.selfshadow.com/publications/s2013-shading-course/karis/s2013_pbs_epic_notes_v2.pdf
  13 // [2] Physically Based Shading at Disney
  14 //     http://blog.selfshadow.com/publications/s2012-shading-course/burley/s2012_pbs_disney_brdf_notes_v3.pdf
  15 // [3] README.md - Environment Maps
  16 //     https://github.com/KhronosGroup/glTF-Sample-Viewer/#environment-maps
  17 // [4] \"An Inexpensive BRDF Model for Physically based Rendering\" by Christophe Schlick
  18 //     https://www.cs.virginia.edu/~jdl/bib/appearance/analytic%20models/schlick94b.pdf
  19
  20 #ifdef HIGHP
  21 precision highp float;
  22 #else
  23 precision mediump float;
  24 #endif
  25
  26 #ifdef GLTF_CHANNELS
  27 #define METALLIC b
  28 #define ROUGHNESS g
  29 #else //GLTF_CHANNELS
  30 #define METALLIC r
  31 #define ROUGHNESS a
  32 #endif //GLTF_CHANNELS
  33
  34 uniform lowp vec4 uColor; // Color from SceneGraph
  35 uniform lowp vec4 uColorFactor; // Color from material
  36 uniform lowp float uMetallicFactor;
  37 uniform lowp float uRoughnessFactor;
  38 uniform lowp float uDielectricSpecular;
  39
  40 #ifdef THREE_TEX
  41 #ifdef BASECOLOR_TEX
  42 uniform sampler2D sAlbedoAlpha;
  43 #endif // BASECOLOR_TEX
  44 #ifdef METALLIC_ROUGHNESS_TEX
  45 uniform sampler2D sMetalRoughness;
  46 #endif // METALLIC_ROUGHNESS_TEX
  47 #ifdef NORMAL_TEX
  48 uniform sampler2D sNormal;
  49 uniform float uNormalScale;
  50 #endif // NORMAL_TEX
  51 #else // THREE_TEX
  52 uniform sampler2D sAlbedoMetal;
  53 uniform sampler2D sNormalRoughness;
  54 #endif
  55
  56 #ifdef OCCLUSION
  57 uniform sampler2D sOcclusion;
  58 uniform float uOcclusionStrength;
  59 #endif
  60
  61 #ifdef EMISSIVE_TEXTURE
  62 uniform sampler2D sEmissive;
  63 #endif
  64 uniform vec3 uEmissiveFactor;
  65
  66 uniform float uSpecularFactor;
  67 uniform vec3  uSpecularColorFactor;
  68 #ifdef MATERIAL_SPECULAR_TEXTURE
  69 uniform sampler2D sSpecular;
  70 #endif
  71 #ifdef MATERIAL_SPECULAR_COLOR_TEXTURE
  72 uniform sampler2D sSpecularColor;
  73 #endif
  74
  75 //// For IBL
  76 uniform sampler2D sbrdfLUT;
  77 uniform samplerCube sDiffuseEnvSampler;
  78 uniform samplerCube sSpecularEnvSampler;
  79 uniform float uIblIntensity;
  80 uniform vec3 uYDirection;
  81 uniform float uMaxLOD;
  82
  83 // For Alpha Mode.
  84 uniform lowp float uOpaque;
  85 uniform lowp float uMask;
  86 uniform lowp float uAlphaThreshold;
  87
  88 // TODO: Multiple texture coordinate will be supported.
  89 in mediump vec2 vUV;
  90 in lowp mat3 vTBN;
  91 in lowp vec4 vColor;
  92 in highp vec3 vPositionToCamera;
  93
  94 out vec4 FragColor;
  95
  96 const float c_MinRoughness = 0.04;
  97
  98 vec3 linear(vec3 color)
  99 {
 100   return pow(color, vec3(2.2));
 101 }
 102
 103 void main()
 104 {
 105   // Metallic and Roughness material properties are packed together
 106   // In glTF, these factors can be specified by fixed scalar values
 107   // or from a metallic-roughness map
 108   // Roughness is stored in the 'g' channel, metallic is stored in the 'b' channel.
 109   // This layout intentionally reserves the 'r' channel for (optional) occlusion map data
 110   lowp float metallic = uMetallicFactor;
 111   lowp float perceptualRoughness = uRoughnessFactor;
 112   // If there isn't normal texture, use surface normal
 113   mediump vec3 n = normalize(vTBN[2].xyz);
 114
 115 #ifdef THREE_TEX
 116   // The albedo may be defined from a base texture or a flat color
 117 #ifdef BASECOLOR_TEX
 118   lowp vec4 baseColor = texture(sAlbedoAlpha, vUV);
 119   baseColor = vColor * vec4(linear(baseColor.rgb), baseColor.w) * uColorFactor;
 120 #else // BASECOLOR_TEX
 121   lowp vec4 baseColor = vColor * uColorFactor;
 122 #endif // BASECOLOR_TEX
 123
 124 #ifdef METALLIC_ROUGHNESS_TEX
 125   lowp vec4 metrou = texture(sMetalRoughness, vUV);
 126   metallic = metrou.METALLIC * metallic;
 127   perceptualRoughness = metrou.ROUGHNESS * perceptualRoughness;
 128 #endif // METALLIC_ROUGHNESS_TEX
 129
 130 #ifdef NORMAL_TEX
 131   n = texture(sNormal, vUV).rgb;
 132   n = normalize(vTBN * ((2.0 * n - 1.0) * vec3(uNormalScale, uNormalScale, 1.0)));
 133 #endif // NORMAL_TEX
 134 #else // THREE_TEX
 135   vec4 albedoMetal = texture(sAlbedoMetal, vUV);
 136   lowp vec4 baseColor = vec4(linear(albedoMetal.rgb), 1.0) * vColor * uColorFactor;
 137
 138   metallic = albedoMetal.METALLIC * metallic;
 139
 140   vec4 normalRoughness = texture(sNormalRoughness, vUV);
 141   perceptualRoughness = normalRoughness.ROUGHNESS * perceptualRoughness;
 142
 143   n = normalRoughness.rgb;
 144   n = normalize(vTBN * ((2.0 * n - 1.0) * vec3(uNormalScale, uNormalScale, 1.0)));
 145 #endif // THREE_TEX
 146
 147   // The value of uOpaque and uMask can be 0.0 or 1.0.
 148   // If uMask is 1.0, a Pixel that has bigger alpha than uAlphaThreashold becomes fully opaque,
 149   // and, a pixel that has smaller alpha than uAlphaThreashold becomes fully transparent.
 150   // If uOpaque is 1.0, alpha value of final color is 1.0;
 151   // https://www.khronos.org/registry/glTF/specs/2.0/glTF-2.0.html#_material_alphamode
 152   if(uMask > 0.5 && baseColor.a < uAlphaThreshold)
 153   {
 154     discard;
 155   }
 156   baseColor.a = mix(baseColor.a, 1.0, uOpaque);
 157
 158   metallic = clamp(metallic, 0.0, 1.0);
 159   // Roughness is authored as perceptual roughness; as is convention,
 160   // convert to material roughness by squaring the perceptual roughness [2].
 161   perceptualRoughness = clamp(perceptualRoughness, c_MinRoughness, 1.0);
 162
 163   // Material ior
 164   lowp vec3 f0 = vec3(uDielectricSpecular);
 165
 166   // Material Specular
 167   float specularWeight = 1.0;
 168   vec4 materialSpecularTexture = vec4(1.0);
 169 #ifdef MATERIAL_SPECULAR_TEXTURE
 170   materialSpecularTexture.a = texture(sSpecular, vUV).a;
 171 #endif
 172 #ifdef MATERIAL_SPECULAR_COLOR_TEXTURE
 173   materialSpecularTexture.rgb = texture(sSpecularColor, vUV).rgb;
 174 #endif
 175   specularWeight = uSpecularFactor * materialSpecularTexture.a;
 176   f0 = min(f0 * uSpecularColorFactor * materialSpecularTexture.rgb, vec3(1.0));
 177   f0 = mix(f0, baseColor.rgb, metallic);
 178
 179   mediump vec3 v = normalize(vPositionToCamera); // Vector from surface point to camera
 180   mediump float NdotV = clamp(abs(dot(n, v)), 0.001, 1.0);
 181   mediump vec3 reflection = -normalize(reflect(v, n));
 182   lowp vec3 brdf = texture(sbrdfLUT, vec2(NdotV, 1.0 - perceptualRoughness)).rgb;
 183   vec3 Fr = max(vec3(1.0 - perceptualRoughness), f0) - f0;
 184   vec3 k_S = f0 + Fr * pow(1.0 - NdotV, 5.0);
 185   vec3 FssEss = specularWeight * (k_S * brdf.x + brdf.y);
 186
 187   // Specular Light
 188   // uMaxLOD that means mipmap level of specular texture is used for bluring of reflection of specular following roughness.
 189   float lod = perceptualRoughness * (uMaxLOD - 1.0);
 190   lowp vec3 specularLight = linear(textureLod(sSpecularEnvSampler, reflection * uYDirection, lod).rgb);
 191   lowp vec3 specular = specularLight * FssEss;
 192
 193   // Diffuse Light
 194   lowp vec3 diffuseColor = mix(baseColor.rgb, vec3(0), metallic);
 195   lowp vec3 irradiance = linear(texture(sDiffuseEnvSampler, n * uYDirection).rgb);
 196   float Ems = (1.0 - (brdf.x + brdf.y));
 197   vec3 F_avg = specularWeight * (f0 + (1.0 - f0) / 21.0);
 198   vec3 FmsEms = Ems * FssEss * F_avg / (1.0 - F_avg * Ems);
 199   vec3 k_D = diffuseColor * (1.0 - FssEss + FmsEms);
 200   lowp vec3 diffuse = (FmsEms + k_D) * irradiance;
 201
 202   lowp vec3 color = (diffuse + specular) * uIblIntensity;
 203
 204 #ifdef OCCLUSION
 205   lowp float ao = texture(sOcclusion, vUV).r;
 206   color = mix(color, color * ao, uOcclusionStrength);
 207 #endif // OCCLUSION
 208
 209 #ifdef EMISSIVE_TEXTURE
 210   lowp vec3 emissive = linear(texture(sEmissive, vUV).rgb) * uEmissiveFactor;
 211 #else
 212   lowp vec3 emissive = uEmissiveFactor;
 213 #endif // EMISSIVE_TEXTURE
 214   color += emissive;
 215
 216   FragColor = vec4(pow(color, vec3(1.0 / 2.2)), baseColor.a) * uColor;
 217 }