dali-scene3d/internal/graphics/shaders/default-physically-based-shader.frag

   1 #version 300 es
   2
   3 // Original Code
   4 // https://github.com/KhronosGroup/glTF-Sample-Viewer/blob/glTF-WebGL-PBR/shaders/pbr-frag.glsl
   5 // Commit dc84b5e374fb3d23153d2248a338ef88173f9eb6
   6 //
   7 // This fragment shader defines a reference implementation for Physically Based Shading of
   8 // a microfacet surface material defined by a glTF model.For the DamagedHelmet.gltf and its Assets
   9 //
  10 // References:
  11 // [1] Real Shading in Unreal Engine 4
  12 //     http://blog.selfshadow.com/publications/s2013-shading-course/karis/s2013_pbs_epic_notes_v2.pdf
  13 // [2] Physically Based Shading at Disney
  14 //     http://blog.selfshadow.com/publications/s2012-shading-course/burley/s2012_pbs_disney_brdf_notes_v3.pdf
  15 // [3] README.md - Environment Maps
  16 //     https://github.com/KhronosGroup/glTF-Sample-Viewer/#environment-maps
  17 // [4] \"An Inexpensive BRDF Model for Physically based Rendering\" by Christophe Schlick
  18 //     https://www.cs.virginia.edu/~jdl/bib/appearance/analytic%20models/schlick94b.pdf
  19
  20 #ifdef HIGHP
  21 precision highp float;
  22 #else
  23 precision mediump float;
  24 #endif
  25
  26 #ifdef GLTF_CHANNELS
  27 #define METALLIC b
  28 #define ROUGHNESS g
  29 #else //GLTF_CHANNELS
  30 #define METALLIC r
  31 #define ROUGHNESS a
  32 #endif //GLTF_CHANNELS
  33
  34 uniform lowp vec4 uColor; // Color from SceneGraph
  35 uniform lowp vec4 uColorFactor; // Color from material
  36 uniform lowp float uMetallicFactor;
  37 uniform lowp float uRoughnessFactor;
  38 uniform lowp float uDielectricSpecular;
  39
  40 #ifdef THREE_TEX
  41 #ifdef BASECOLOR_TEX
  42 uniform sampler2D sAlbedoAlpha;
  43 #endif // BASECOLOR_TEX
  44 #ifdef METALLIC_ROUGHNESS_TEX
  45 uniform sampler2D sMetalRoughness;
  46 #endif // METALLIC_ROUGHNESS_TEX
  47 #ifdef NORMAL_TEX
  48 uniform sampler2D sNormal;
  49 uniform float uNormalScale;
  50 #endif // NORMAL_TEX
  51 #else // THREE_TEX
  52 uniform sampler2D sAlbedoMetal;
  53 uniform sampler2D sNormalRoughness;
  54 #endif
  55
  56 #ifdef OCCLUSION
  57 uniform sampler2D sOcclusion;
  58 uniform float uOcclusionStrength;
  59 #endif
  60
  61 #ifdef EMISSIVE_TEXTURE
  62 uniform sampler2D sEmissive;
  63 #endif
  64 uniform vec3 uEmissiveFactor;
  65
  66 uniform float uSpecularFactor;
  67 uniform vec3  uSpecularColorFactor;
  68 #ifdef MATERIAL_SPECULAR_TEXTURE
  69 uniform sampler2D sSpecular;
  70 #endif
  71 #ifdef MATERIAL_SPECULAR_COLOR_TEXTURE
  72 uniform sampler2D sSpecularColor;
  73 #endif
  74
  75 //// For IBL
  76 uniform sampler2D sbrdfLUT;
  77 uniform samplerCube sDiffuseEnvSampler;
  78 uniform samplerCube sSpecularEnvSampler;
  79 uniform float uIblIntensity;
  80 uniform vec3 uYDirection;
  81 uniform float uMaxLOD;
  82
  83 // For Alpha Mode.
  84 uniform lowp float uOpaque;
  85 uniform lowp float uMask;
  86 uniform lowp float uAlphaThreshold;
  87
  88 // TODO: Multiple texture coordinate will be supported.
  89 in mediump vec2 vUV;
  90 in lowp mat3 vTBN;
  91 #ifdef COLOR_ATTRIBUTE
  92 in lowp vec4 vColor;
  93 #endif
  94 in highp vec3 vPositionToCamera;
  95
  96 out vec4 FragColor;
  97
  98 const float c_MinRoughness = 0.04;
  99
 100 vec3 linear(vec3 color)
 101 {
 102   return pow(color, vec3(2.2));
 103 }
 104
 105 void main()
 106 {
 107   // Metallic and Roughness material properties are packed together
 108   // In glTF, these factors can be specified by fixed scalar values
 109   // or from a metallic-roughness map
 110   // Roughness is stored in the 'g' channel, metallic is stored in the 'b' channel.
 111   // This layout intentionally reserves the 'r' channel for (optional) occlusion map data
 112   lowp float metallic = uMetallicFactor;
 113   lowp float perceptualRoughness = uRoughnessFactor;
 114   // If there isn't normal texture, use surface normal
 115   mediump vec3 n = normalize(vTBN[2].xyz);
 116
 117 #ifdef THREE_TEX
 118   // The albedo may be defined from a base texture or a flat color
 119 #ifdef BASECOLOR_TEX
 120   lowp vec4 baseColor = texture(sAlbedoAlpha, vUV);
 121   baseColor = vec4(linear(baseColor.rgb), baseColor.w) * uColorFactor;
 122 #else // BASECOLOR_TEX
 123 #ifdef COLOR_ATTRIBUTE
 124   lowp vec4 baseColor = vColor * uColorFactor;
 125 #else // COLOR_ATTRIBUTE
 126   lowp vec4 baseColor = uColorFactor;
 127 #endif // COLOR_ATTRIBUTE
 128 #endif // BASECOLOR_TEX
 129
 130 #ifdef METALLIC_ROUGHNESS_TEX
 131   lowp vec4 metrou = texture(sMetalRoughness, vUV);
 132   metallic = metrou.METALLIC * metallic;
 133   perceptualRoughness = metrou.ROUGHNESS * perceptualRoughness;
 134 #endif // METALLIC_ROUGHNESS_TEX
 135
 136 #ifdef NORMAL_TEX
 137   n = texture(sNormal, vUV).rgb;
 138   n = normalize(vTBN * ((2.0 * n - 1.0) * vec3(uNormalScale, uNormalScale, 1.0)));
 139 #endif // NORMAL_TEX
 140 #else // THREE_TEX
 141   vec4 albedoMetal = texture(sAlbedoMetal, vUV);
 142 #ifdef COLOR_ATTRIBUTE
 143   lowp vec4 baseColor = vec4(linear(albedoMetal.rgb), 1.0) * vColor * uColorFactor;
 144 #else // COLOR_ATTRIBUTE
 145   lowp vec4 baseColor = vec4(linear(albedoMetal.rgb), 1.0) * uColorFactor;
 146 #endif // COLOR_ATTRIBUTE
 147
 148   metallic = albedoMetal.METALLIC * metallic;
 149
 150   vec4 normalRoughness = texture(sNormalRoughness, vUV);
 151   perceptualRoughness = normalRoughness.ROUGHNESS * perceptualRoughness;
 152
 153   n = normalRoughness.rgb;
 154   n = normalize(vTBN * ((2.0 * n - 1.0) * vec3(uNormalScale, uNormalScale, 1.0)));
 155 #endif // THREE_TEX
 156
 157   // The value of uOpaque and uMask can be 0.0 or 1.0.
 158   // If uMask is 1.0, a Pixel that has bigger alpha than uAlphaThreashold becomes fully opaque,
 159   // and, a pixel that has smaller alpha than uAlphaThreashold becomes fully transparent.
 160   // If uOpaque is 1.0, alpha value of final color is 1.0;
 161   // https://www.khronos.org/registry/glTF/specs/2.0/glTF-2.0.html#_material_alphamode
 162   if(uMask > 0.5 && baseColor.a < uAlphaThreshold)
 163   {
 164     discard;
 165   }
 166   baseColor.a = mix(baseColor.a, 1.0, uOpaque);
 167
 168   metallic = clamp(metallic, 0.0, 1.0);
 169   // Roughness is authored as perceptual roughness; as is convention,
 170   // convert to material roughness by squaring the perceptual roughness [2].
 171   perceptualRoughness = clamp(perceptualRoughness, c_MinRoughness, 1.0);
 172
 173   // Material ior
 174   lowp vec3 f0 = vec3(uDielectricSpecular);
 175
 176   // Material Specular
 177   float specularWeight = 1.0;
 178   vec4 materialSpecularTexture = vec4(1.0);
 179 #ifdef MATERIAL_SPECULAR_TEXTURE
 180   materialSpecularTexture.a = texture(sSpecular, vUV).a;
 181 #endif
 182 #ifdef MATERIAL_SPECULAR_COLOR_TEXTURE
 183   materialSpecularTexture.rgb = texture(sSpecularColor, vUV).rgb;
 184 #endif
 185   specularWeight = uSpecularFactor * materialSpecularTexture.a;
 186   f0 = min(f0 * uSpecularColorFactor * materialSpecularTexture.rgb, vec3(1.0));
 187   f0 = mix(f0, baseColor.rgb, metallic);
 188
 189   mediump vec3 v = normalize(vPositionToCamera); // Vector from surface point to camera
 190   mediump float NdotV = clamp(abs(dot(n, v)), 0.001, 1.0);
 191   mediump vec3 reflection = -normalize(reflect(v, n));
 192   lowp vec3 brdf = texture(sbrdfLUT, vec2(NdotV, 1.0 - perceptualRoughness)).rgb;
 193   vec3 Fr = max(vec3(1.0 - perceptualRoughness), f0) - f0;
 194   vec3 k_S = f0 + Fr * pow(1.0 - NdotV, 5.0);
 195   vec3 FssEss = specularWeight * (k_S * brdf.x + brdf.y);
 196
 197   // Specular Light
 198   // uMaxLOD that means mipmap level of specular texture is used for bluring of reflection of specular following roughness.
 199   float lod = perceptualRoughness * (uMaxLOD - 1.0);
 200   lowp vec3 specularLight = linear(textureLod(sSpecularEnvSampler, reflection * uYDirection, lod).rgb);
 201   lowp vec3 specular = specularLight * FssEss;
 202
 203   // Diffuse Light
 204   lowp vec3 diffuseColor = mix(baseColor.rgb, vec3(0), metallic);
 205   lowp vec3 irradiance = linear(texture(sDiffuseEnvSampler, n * uYDirection).rgb);
 206   float Ems = (1.0 - (brdf.x + brdf.y));
 207   vec3 F_avg = specularWeight * (f0 + (1.0 - f0) / 21.0);
 208   vec3 FmsEms = Ems * FssEss * F_avg / (1.0 - F_avg * Ems);
 209   vec3 k_D = diffuseColor * (1.0 - FssEss + FmsEms);
 210   lowp vec3 diffuse = (FmsEms + k_D) * irradiance;
 211
 212   lowp vec3 color = (diffuse + specular) * uIblIntensity;
 213
 214 #ifdef OCCLUSION
 215   lowp float ao = texture(sOcclusion, vUV).r;
 216   color = mix(color, color * ao, uOcclusionStrength);
 217 #endif // OCCLUSION
 218
 219 #ifdef EMISSIVE_TEXTURE
 220   lowp vec3 emissive = linear(texture(sEmissive, vUV).rgb) * uEmissiveFactor;
 221 #else
 222   lowp vec3 emissive = uEmissiveFactor;
 223 #endif // EMISSIVE_TEXTURE
 224   color += emissive;
 225
 226   FragColor = vec4(pow(color, vec3(1.0 / 2.2)), baseColor.a) * uColor;
 227 }