build/tizen/configure.ac

   1 # Copyright (c) 2014 Samsung Electronics Co., Ltd.
   2
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15
  16 m4_define([dali_version],[0.1.1])
  17 AC_INIT([dali], [dali_version])
  18 AM_INIT_AUTOMAKE([-Wall foreign])
  19
  20 AC_PROG_CXX
  21 AC_PROG_LIBTOOL
  22 AC_PROG_MKDIR_P
  23
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 LT_INIT
  27
  28 DALI_VERSION=dali_version
  29 AC_SUBST(DALI_VERSION)
  30
  31 DALI_CFLAGS=-DPLATFORM_TIZEN
  32
  33 # Use C++ 11
  34 DALI_CFLAGS="$DALI_CFLAGS -std=c++11"
  35
  36 AC_ARG_ENABLE(exportall,
  37               [AC_HELP_STRING([--enable-exportall],
  38                               [enables the exporting of all the symbols in the library])],
  39               [enable_exportall=yes],
  40               [enable_exportall=no])
  41
  42 AC_ARG_ENABLE([debug],
  43               [AC_HELP_STRING([--enable-debug],
  44                               [Turns on debugging])],
  45               [enable_debug=$enableval],
  46               [enable_debug=no])
  47
  48 AC_ARG_ENABLE([emscripten],
  49               [AC_HELP_STRING([--enable-emscripten],
  50                               [Emscripten builds])],
  51               [enable_emscripten=$enableval],
  52               [enable_emscripten=no])
  53
  54 AC_ARG_ENABLE([backtrace],
  55               [AC_HELP_STRING([--enable-backtrace],
  56                               [Backtrace for exceptions])],
  57               [enable_backtrace=$enableval],
  58               [enable_backtrace=yes])
  59
  60 AC_ARG_ENABLE([lock_backtrace],
  61               [AC_HELP_STRING([--enable-lock-backtrace],
  62                               [Backtrace for when more than 1 lock is held on the same thread])],
  63               [enable_lock_backtrace=$enableval],
  64               [enable_lock_backtrace=no])
  65
  66 AC_ARG_ENABLE([gles],
  67               [AC_HELP_STRING([--enable-gles],
  68                               [Specify the OpenGL ES version for backwards compatibility])],
  69               [enable_gles=$enableval],
  70               [enable_gles=20])
  71
  72 DALI_CFLAGS="$DALI_CFLAGS -DDALI_GLES_VERSION=${enable_gles}"
  73
  74 if test "x$enable_debug" = "xyes"; then
  75   DALI_CFLAGS="$DALI_CFLAGS -DDEBUG_ENABLED"
  76 fi
  77
  78 if test "x$enable_debug" = "xno" -a "x$enable_exportall" = "xno"; then
  79   DALI_CFLAGS="$DALI_CFLAGS -fvisibility=hidden -DHIDE_DALI_INTERNALS"
  80 fi
  81
  82 if test "x$enable_emscripten" = "xyes"; then
  83   DALI_CFLAGS="$DALI_CFLAGS -DEMSCRIPTEN -std=c++11"
  84   # Automatically turn off backtrace support and mutex locks
  85   enable_backtrace="no"
  86   enable_lock_backtrace="no"
  87 fi
  88
  89 # Must come after Emscripten feature test
  90 if test "x$enable_lock_backtrace" = "xyes"; then
  91   DALI_CFLAGS="$DALI_CFLAGS -DLOCK_BACKTRACE_ENABLED"
  92   enable_backtrace="yes"
  93 fi
  94
  95 # Must come after Emscripten & locks backtrace feature test
  96 if test "x$enable_backtrace" = "xyes"; then
  97   DALI_CFLAGS="$DALI_CFLAGS -DBACKTRACE_ENABLED"
  98 fi
  99
 100 if test x$DALI_DATA_RW_DIR != x; then
 101   dataReadWriteDir=$DALI_DATA_RW_DIR
 102 else
 103   dataReadWriteDir=${prefix}/share/dali/
 104 fi
 105
 106 if test x$DALI_DATA_RO_DIR != x; then
 107   dataReadOnlyDir=$DALI_DATA_RO_DIR
 108 else
 109   dataReadOnlyDir=${prefix}/share/dali/
 110 fi
 111
 112 DALI_CFLAGS="$DALI_CFLAGS -I${includedir}"
 113 DALI_LDFLAGS="-L${libdir}"
 114
 115 AC_SUBST(dataReadWriteDir)
 116 AC_SUBST(dataReadOnlyDir)
 117 AC_SUBST(DALI_CFLAGS)
 118 AC_SUBST(DALI_LDFLAGS)
 119
 120 # Specify the include directory for development headers
 121 devincludepath=${includedir}
 122 AC_SUBST(devincludepath)
 123
 124 AC_CONFIG_FILES([
 125  Makefile
 126  dali-core/Makefile
 127  dali-core.pc
 128 ])
 129
 130 AC_OUTPUT
 131
 132 echo "
 133 Configuration
 134 -------------
 135   Prefix:                           $prefix
 136   Debug Build:                      $enable_debug
 137   Data Dir (Read/Write):            $dataReadWriteDir
 138   Data Dir (Read Only):             $dataReadOnlyDir
 139   Emscripten:                       $enable_emscripten
 140   Backtrace:                        $enable_backtrace
 141   ScopedLock Backtrace:             $enable_lock_backtrace
 142 "