build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.1)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-core")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 PROJECT(${name})
   8 SET(PKG_NAME ${name})
   9
  10 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  11 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  13     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  14   ENDIF()
  15 ENDIF()
  16
  17 # API VERSION (Not DALi release version)
  18 SET(${name}_VERSION_MAJOR 2)
  19 SET(${name}_VERSION_MINOR 0)
  20 SET(${name}_VERSION_PATCH 0)
  21 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  22
  23 SET(DALI_VERSION ${${name}_VERSION} )
  24
  25 # Define options to CMake
  26
  27 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  28 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  29 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  30 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  31 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  32 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  33 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  34 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  35
  36 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  37   FIND_PACKAGE( dali-windows-dependencies REQUIRED )
  38 ENDIF()
  39
  40 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  41
  42 # Set up compiler definitions
  43
  44 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  45   SET( ENABLE_DEBUG ON )
  46 ENDIF()
  47
  48 IF( ENABLE_DEBUG )
  49   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  50   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  51   SET( ENABLE_EXPORTALL ON )
  52 ELSE()
  53   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  54 ENDIF()
  55
  56 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  57
  58   IF(NOT DEFINED STATIC)
  59     ADD_DEFINITIONS( "-DBUILDING_DALI_CORE" )
  60   ENDIF()
  61
  62 ELSEIF( UNIX )
  63
  64   IF( NOT ${ENABLE_EXPORTALL} )
  65     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
  66   ENDIF()
  67
  68   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  69
  70   IF("${ARCH}" STREQUAL "arm")
  71     ADD_DEFINITIONS("-DTARGET")
  72   ENDIF()
  73
  74 ENDIF()
  75
  76 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  77   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  78 ENDIF()
  79
  80 IF( ENABLE_LOCK_BACKTRACE )
  81   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  82 ENDIF()
  83
  84 IF( ENABLE_TRACE )
  85   ADD_DEFINITIONS("-DTRACE_ENABLED")
  86 ENDIF()
  87
  88 # Deployment folder should come from spec file or command line:
  89 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  90 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  91
  92 # from root/build/tizen, get back to root
  93 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
  94
  95 # Make sure the path is absolute
  96 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  97
  98 # Set up the include dir
  99 SET( INCLUDE_DIR $ENV{includedir} )
 100 IF( NOT INCLUDE_DIR )
 101   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 102 ENDIF()
 103 IF( NOT INCLUDE_DIR )
 104   SET( INCLUDE_DIR ${PREFIX}/include )
 105 ENDIF()
 106
 107 # Set up the lib dir
 108 SET( LIB_DIR $ENV{libdir} )
 109 IF( NOT LIB_DIR )
 110   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 111 ENDIF()
 112 IF( NOT LIB_DIR )
 113   SET( LIB_DIR ${PREFIX}/lib )
 114 ENDIF()
 115
 116 # Set up the bin dir
 117 SET( BIN_DIR $ENV{bindir} )
 118 IF( NOT BIN_DIR )
 119   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 120 ENDIF()
 121 IF( NOT BIN_DIR )
 122   SET( BIN_DIR ${PREFIX}/bin )
 123 ENDIF()
 124
 125 IF( ENABLE_PKG_CONFIGURE )
 126   # Configure the pkg-config file
 127   # Requires the following variables to be setup:
 128   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 129   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 130   SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-core.pc )
 131   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 132 ENDIF()
 133
 134 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 135
 136   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 137   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 138   ADD_COMPILE_OPTIONS( /std:c++17 )                     # c++17 support
 139   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 140
 141 ELSEIF( UNIX )
 142
 143   # Set up compiler flags and warnings
 144   ADD_COMPILE_OPTIONS( -std=c++17 )                     # c++17 support
 145   ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
 146
 147   # TODO: Clang is a lot more strict with warnings, we should address
 148   # those issues at some point.
 149   IF( NOT ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang" )
 150     ADD_COMPILE_OPTIONS( -Werror )
 151   ENDIF()
 152
 153   ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal -Wno-class-memaccess -Wno-cast-function-type )
 154
 155   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 156     ADD_COMPILE_OPTIONS( --coverage )
 157     SET(ENABLE_COVERAGE ON)
 158     SET(COVERAGE --coverage)
 159   ENDIF()
 160
 161   IF( NOT ${ENABLE_EXPORTALL} )
 162     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 163   ENDIF()
 164
 165 ENDIF()
 166
 167 INCLUDE_DIRECTORIES(
 168   ${ROOT_SRC_DIR}
 169   ${VCPKG_INCLUDE_DIR}
 170   ${INCLUDE_DIR}
 171 )
 172
 173 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 174 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 175
 176 SET(SOURCES "")
 177
 178 # could use INCLUDE to get the source lists a different way;
 179 # would then need to specify a build folder somehow...
 180 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 181 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 182 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 183 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 184 IF( WIN32 )
 185   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-windows.list )
 186 ELSEIF( UNIX )
 187   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-unix.list )
 188 ENDIF()
 189 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 190
 191 SET(LIBTYPE SHARED)
 192 IF(DEFINED STATIC)
 193   SET(LIBTYPE STATIC)
 194 ENDIF()
 195
 196 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 197
 198 # pthread required due to gcc issue
 199 IF( WIN32 )
 200     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} dali-windows-dependencies::dali-windows-dependencies )
 201 ELSEIF( UNIX )
 202   FIND_LIBRARY(PTHREAD pthread)
 203   IF(PTHREAD)
 204     SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 205   ENDIF()
 206 ENDIF()
 207
 208 TARGET_LINK_LIBRARIES( ${name}
 209   ${OPTIONAL_LIBS}
 210   ${COVERAGE}
 211 )
 212
 213 SET_TARGET_PROPERTIES( ${name}
 214   PROPERTIES
 215   VERSION ${DALI_VERSION}
 216   SOVERSION ${${name}_VERSION_MAJOR}
 217   CLEAN_DIRECT_OUPUT 1
 218 )
 219
 220 IF( INSTALL_CMAKE_MODULES )
 221   IF( ENABLE_DEBUG )
 222     SET( BIN_DIR "${BIN_DIR}/debug" )
 223     SET( LIB_DIR "${LIB_DIR}/debug" )
 224   ENDIF()
 225
 226   # Install the library files.
 227   INSTALL( TARGETS ${name}
 228     EXPORT ${name}-targets
 229     LIBRARY DESTINATION ${LIB_DIR}
 230     ARCHIVE DESTINATION ${LIB_DIR}
 231     RUNTIME DESTINATION ${BIN_DIR}
 232   )
 233
 234   # Install the cmake modules.
 235   INSTALL(
 236     EXPORT ${name}-targets
 237     NAMESPACE ${name}::
 238     FILE ${name}-targets.cmake
 239     DESTINATION share/${name}
 240   )
 241
 242   FILE( WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 243     include(CMakeFindDependencyMacro)
 244     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 245   ")
 246   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name} )
 247
 248   # Install the pdb file.
 249   IF( ENABLE_DEBUG )
 250     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 251   ENDIF()
 252 ELSE()
 253   # Install the library so file and symlinks.
 254   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 255 ENDIF()
 256
 257
 258 # Install the pkg-config file
 259 IF( ENABLE_PKG_CONFIGURE )
 260   INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 261 ENDIF()
 262
 263 # macro for installing headers by replacing prefix. (TODO, investigate
 264 # if there is a CMAKE way of doing this automatically)
 265 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 266   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 267   FOREACH(HEADER ${${HEADER_LIST}})
 268     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 269     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 270     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 271   ENDFOREACH(HEADER)
 272 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 273
 274 # Install headers using lists defined by ADD_SUBDIRECTORY
 275 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 276 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 277 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 278 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 279
 280 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 281 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 282 # target names duplication with other DALi modules.
 283 IF( ENABLE_COVERAGE )
 284   FIND_PROGRAM( LCOV_BIN "lcov" )
 285   IF( LCOV_BIN )
 286
 287     # Define custom rules for coverage
 288     SET(COVERAGE_DIR .cov)
 289     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 290
 291     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 292     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 293     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 294     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 295     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 296       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 297     ENDIF()
 298
 299     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 300
 301     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 302       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 303
 304     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 305       DEPENDS cov_data )
 306
 307     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 308
 309     # Define custom rule for distclean
 310     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 311     ADD_CUSTOM_COMMAND(
 312           DEPENDS ${DALI_CORE_PREFIX}clean
 313           COMMENT "distribution clean"
 314           COMMAND find
 315           ARGS    .
 316           -not -name config.cmake -and \(
 317           -name tester.c -or
 318           -name Testing -or
 319           -name CMakeFiles -or
 320           -name doc -or
 321           -name cmake.depends -or
 322           -name cmake.check_depends -or
 323           -name CMakeCache.txt -or
 324           -name cmake.check_cache -or
 325           -name *.cmake -or
 326           -name Makefile -or
 327           -name core -or
 328           -name core.* -or
 329           -name gmon.out -or
 330           -name install_manifest.txt -or
 331           -name *.pc -or
 332           -name *.gcov -or
 333           -name *.gcno -or
 334           -name *.gcda -or
 335           -name *~ -or
 336           -name libdali*.so* \)
 337           | grep -v TC | xargs rm -rf
 338           TARGET  ${DALI_CORE_PREFIX}distclean
 339           VERBATIM
 340           )
 341
 342   ENDIF( LCOV_BIN )
 343 ENDIF()
 344
 345 IF( ENABLE_LINK_TEST )
 346   # Linker Test
 347   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 348   SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 349   SET( LINKER_TEST_SOURCES
 350     linker-test.cpp
 351     ${DALI_TEST_SUITE_DIR}/test-application.cpp
 352     ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 353     ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 354     ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 355     ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 356     ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 357   )
 358   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 359   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 360   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 361 ENDIF()
 362
 363 # Configuration Messages
 364 MESSAGE( STATUS "Configuration:\n" )
 365 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 366 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 367 MESSAGE( STATUS "Bin Dir:               " ${BIN_DIR} )
 368 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 369 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 370 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 371 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 372 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 373 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 374 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 375 MESSAGE( STATUS "Use pkg configure:     " ${ENABLE_PKG_CONFIGURE} )
 376 MESSAGE( STATUS "Enable link test:      " ${ENABLE_LINK_TEST} )
 377 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 378 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )