build/tizen-cmake/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 1)
  12 SET(${name}_VERSION_PATCH 1)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24
  25 # Set up compiler definitions
  26
  27 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  28   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  29   SET(ENABLE_DEBUG ON)
  30 ELSE()
  31   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  32 ENDIF()
  33
  34 ADD_DEFINITIONS(-DPLATFORM_TIZEN -DDALI_COMPILATION)
  35 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  36
  37 IF("${ARCH}" STREQUAL "arm")
  38   ADD_DEFINITIONS("-DTARGET")
  39 ENDIF("${ARCH}" STREQUAL "arm")
  40
  41 IF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  42   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  43 ENDIF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  44
  45 IF( ENABLE_DEBUG )
  46   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  47 ENDIF( ENABLE_DEBUG )
  48
  49 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  50   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  51 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  52
  53 IF( ENABLE_LOCK_BACKTRACE )
  54   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  55 ENDIF( ENABLE_LOCK_BACKTRACE )
  56
  57 # Deployment folder should come from spec file or command line:
  58 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  59 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  60
  61 # from root/build/tizen, get back to root
  62 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  63
  64 # Make sure the path is absolute
  65 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  66
  67 # Set up the include dir
  68 SET( INCLUDE_DIR $ENV{includedir} )
  69 IF( NOT INCLUDE_DIR )
  70   SET( INCLUDE_DIR ${PREFIX}/include )
  71 ENDIF()
  72
  73 # Set up the lib dir
  74 SET( LIB_DIR $ENV{libdir} )
  75 IF( NOT LIB_DIR )
  76   SET( LIB_DIR ${PREFIX}/lib )
  77 ENDIF()
  78
  79 # Configure the pkg-config file
  80 # Requires the following variables to be setup:
  81 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  82 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
  83 SET( CORE_PKG_CFG_FILE dali-core.pc )
  84 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
  85
  86 # Set up compiler flags and warnings
  87 #ADD_COMPILE_OPTIONS( -std=c++11 -ggdb )
  88 ADD_COMPILE_OPTIONS( -std=c++11 -gdwarf-4 )
  89 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  90
  91 # TODO: Clang is a lot more strict with warnings, we should address
  92 # those issues at some point.
  93 IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
  94   ADD_COMPILE_OPTIONS( -Werror )
  95 ENDIF()
  96
  97 ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
  98
  99 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 100   ADD_COMPILE_OPTIONS( --coverage )
 101   SET(ENABLE_COVERAGE ON)
 102   SET(COVERAGE --coverage)
 103 ENDIF()
 104
 105 INCLUDE_DIRECTORIES(
 106   ${ROOT_SRC_DIR}
 107 )
 108
 109 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 110 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 111
 112 SET(SOURCES "")
 113
 114 # Run sources update script automatically
 115 EXECUTE_PROCESS( COMMAND /bin/bash ${CMAKE_CURRENT_SOURCE_DIR}/update-file-lists.sh
 116                  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} )
 117
 118 # could use INCLUDE to get the source lists a different way;
 119 # would then need to specify a build folder somehow...
 120 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-list.cmake )
 121 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file-list.cmake )
 122 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file-list.cmake )
 123 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file-list.cmake )
 124
 125 ADD_SUBDIRECTORY( ${PACKAGE_DOXY_SRC_DIR} doc )
 126
 127 SET(LIBTYPE SHARED)
 128 IF(DEFINED STATIC)
 129   SET(LIBTYPE STATIC)
 130 ENDIF()
 131
 132 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 133
 134 TARGET_LINK_LIBRARIES( ${name}
 135   -lpthread
 136   ${COVERAGE}
 137 )
 138
 139 SET_TARGET_PROPERTIES( ${name}
 140   PROPERTIES
 141   VERSION ${DALI_VERSION}
 142   SOVERSION ${${name}_VERSION_MAJOR}
 143   CLEAN_DIRECT_OUPUT 1
 144 )
 145
 146 # Install the library so file and symlinks
 147 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 148
 149 # Install the pkg-config file
 150 INSTALL( FILES ${CMAKE_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 151
 152 # macro for installing headers by replacing prefix. (TODO, investigate
 153 # if there is a CMAKE way of doing this automatically)
 154 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 155   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 156   FOREACH(HEADER ${${HEADER_LIST}})
 157     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 158     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 159     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 160   ENDFOREACH(HEADER)
 161 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 162
 163 # Install headers using lists defined by ADD_SUBDIRECTORY
 164 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 165 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 166 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 167 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 168
 169 IF(UNIX)
 170   # Define custom rules for coverage
 171   SET(COVERAGE_DIR .cov)
 172   SET(COVERAGE_OUTPUT_DIR doc/coverage)
 173
 174   # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 175   # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 176   EXECUTE_PROCESS( COMMAND bash -c "lcov --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 177   STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 178   IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 179     SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 180   ENDIF()
 181
 182   ADD_CUSTOM_TARGET( cov_data lcov ${LCOV_OPTS} --base-directory dali --directory . -c -o dali.info
 183           COMMAND lcov ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 184
 185   ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 186     DEPENDS cov_data )
 187
 188   ADD_CUSTOM_TARGET( reset_coverage @lcov -z --directory `pwd` )
 189
 190   # Define custom rule for distclean
 191   ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 192   ADD_CUSTOM_COMMAND(
 193         DEPENDS clean
 194         COMMENT "distribution clean"
 195         COMMAND find
 196         ARGS    .
 197         -not -name config.cmake -and \(
 198         -name tester.c -or
 199         -name Testing -or
 200         -name CMakeFiles -or
 201         -name cmake.depends -or
 202         -name cmake.check_depends -or
 203         -name CMakeCache.txt -or
 204         -name cmake.check_cache -or
 205         -name *.cmake -or
 206         -name Makefile -or
 207         -name core -or
 208         -name core.* -or
 209         -name gmon.out -or
 210         -name install_manifest.txt -or
 211         -name *.pc -or
 212         -name *.gcov -or
 213         -name *.gcno -or
 214         -name *.gcda -or
 215         -name *~ \)
 216         | grep -v TC | xargs rm -rf
 217         TARGET  distclean
 218         VERBATIM
 219         )
 220
 221 ENDIF(UNIX)
 222
 223
 224 MESSAGE( STATUS "Configuration:\n" )
 225 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 226 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 227 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 228 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 229 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 230 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 231 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 232 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 233 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )