build/tizen-cmake/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 1)
  12 SET(${name}_VERSION_PATCH 1)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24 SET(GLES_VERSION 20 CACHE INTEGER "Gles Version")
  25
  26 # Set up compiler definitions
  27
  28 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  29   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  30   SET(ENABLE_DEBUG ON)
  31 ELSE()
  32   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  33 ENDIF()
  34
  35 ADD_DEFINITIONS(-DPLATFORM_TIZEN -DDALI_COMPILATION)
  36 ADD_DEFINITIONS(-DDALI_GLES_VERSION=${GLES_VERSION})
  37 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  38
  39 IF("${ARCH}" STREQUAL "arm")
  40   ADD_DEFINITIONS("-DTARGET")
  41 ENDIF("${ARCH}" STREQUAL "arm")
  42
  43 IF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  44   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  45 ENDIF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  46
  47 IF( ENABLE_DEBUG )
  48   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  49 ENDIF( ENABLE_DEBUG )
  50
  51 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  52   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  53 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  54
  55 IF( ENABLE_LOCK_BACKTRACE )
  56   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  57 ENDIF( ENABLE_LOCK_BACKTRACE )
  58
  59 # Deployment folder should come from spec file or command line:
  60 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  61 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  62
  63 # from root/build/tizen, get back to root
  64 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  65
  66 # Set up the include dir
  67 SET( INCLUDE_DIR $ENV{includedir} )
  68 IF( NOT INCLUDE_DIR )
  69   SET( INCLUDE_DIR ${PREFIX}/include )
  70 ENDIF()
  71
  72 # Set up the lib dir
  73 SET( LIB_DIR $ENV{libdir} )
  74 IF( NOT LIB_DIR )
  75   SET( LIB_DIR ${PREFIX}/lib )
  76 ENDIF()
  77
  78 # Configure the pkg-config file
  79 # Requires the following variables to be setup:
  80 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  81 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
  82 SET( CORE_PKG_CFG_FILE dali-core.pc )
  83 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
  84
  85 # Set up compiler flags and warnings
  86 #ADD_COMPILE_OPTIONS( -std=c++11 -ggdb )
  87 ADD_COMPILE_OPTIONS( -std=c++11 -gdwarf-4 )
  88 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  89 ADD_COMPILE_OPTIONS( -Werror -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
  90
  91 IF( ENABLE_DEBUG )
  92   ADD_COMPILE_OPTIONS( -O0 )
  93 ELSE( ENABLE_DEBUG )
  94   ADD_COMPILE_OPTIONS( -Os )
  95 ENDIF( ENABLE_DEBUG )
  96
  97 IF( ENABLE_COVERAGE OR $ENV{CXXFLAGS} MATCHES --coverage )
  98   ADD_COMPILE_OPTIONS( --coverage )
  99   SET(ENABLE_COVERAGE ON)
 100   SET(COVERAGE --coverage)
 101 ENDIF()
 102
 103 INCLUDE_DIRECTORIES(
 104   ${ROOT_SRC_DIR}
 105 )
 106
 107 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 108 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 109
 110 SET(SOURCES "")
 111
 112 # could use INCLUDE to get the source lists a different way;
 113 # would then need to specify a build folder somehow...
 114 ADD_SUBDIRECTORY( ${SOURCE_DIR}/internal dali/internal )
 115 ADD_SUBDIRECTORY( ${SOURCE_DIR}/integration-api dali/integration-api )
 116 ADD_SUBDIRECTORY( ${SOURCE_DIR}/public-api dali/public-api )
 117 ADD_SUBDIRECTORY( ${SOURCE_DIR}/devel-api dali/devel-api )
 118 ADD_SUBDIRECTORY( ${PACKAGE_DOXY_SRC_DIR} doc )
 119
 120 ADD_LIBRARY( ${name} SHARED ${SOURCES} )
 121
 122 TARGET_LINK_LIBRARIES( ${name}
 123   -lpthread
 124   ${COVERAGE}
 125 )
 126
 127 SET_TARGET_PROPERTIES( ${name}
 128   PROPERTIES
 129   VERSION ${DALI_VERSION}
 130   SOVERSION ${${name}_VERSION_MAJOR}
 131   CLEAN_DIRECT_OUPUT 1
 132 )
 133
 134 # Install the library so file and symlinks
 135 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 136
 137 # Install the pkg-config file
 138 INSTALL( FILES ${CMAKE_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 139
 140 # macro for installing headers by replacing prefix. (TODO, investigate
 141 # if there is a CMAKE way of doing this automatically)
 142 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 143   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 144   FOREACH(HEADER ${${HEADER_LIST}})
 145     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 146     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 147     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 148   ENDFOREACH(HEADER)
 149 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 150
 151 # Install headers using lists defined by ADD_SUBDIRECTORY
 152 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${SOURCE_DIR} "dali")
 153 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${SOURCE_DIR} "dali")
 154 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${SOURCE_DIR} "dali")
 155 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 156
 157 IF(UNIX)
 158   # Define custom rules for coverage
 159   SET(COVERAGE_DIR .cov)
 160   SET(COVERAGE_OUTPUT_DIR doc/coverage)
 161
 162   # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 163   # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 164   EXECUTE_PROCESS( COMMAND bash -c "lcov --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 165   STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 166   IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 167     SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 168   ENDIF()
 169
 170   ADD_CUSTOM_TARGET( cov_data lcov ${LCOV_OPTS} --base-directory dali --directory . -c -o dali.info
 171           COMMAND lcov ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 172
 173   ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 174     DEPENDS cov_data )
 175
 176   ADD_CUSTOM_TARGET( reset_coverage @lcov -z --directory `pwd` )
 177
 178   # Define custom rule for distclean
 179   ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 180   ADD_CUSTOM_COMMAND(
 181         DEPENDS clean
 182         COMMENT "distribution clean"
 183         COMMAND find
 184         ARGS    .
 185         -not -name config.cmake -and \(
 186         -name tester.c -or
 187         -name Testing -or
 188         -name CMakeFiles -or
 189         -name cmake.depends -or
 190         -name cmake.check_depends -or
 191         -name CMakeCache.txt -or
 192         -name cmake.check_cache -or
 193         -name *.cmake -or
 194         -name Makefile -or
 195         -name core -or
 196         -name core.* -or
 197         -name gmon.out -or
 198         -name install_manifest.txt -or
 199         -name *.pc -or
 200         -name *.gcov -or
 201         -name *.gcno -or
 202         -name *.gcda -or
 203         -name *~ \)
 204         | grep -v TC | xargs rm -rf
 205         TARGET  distclean
 206         VERBATIM
 207         )
 208
 209 ENDIF(UNIX)
 210
 211
 212 MESSAGE( STATUS "Configuration:\n" )
 213 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 214 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 215 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 216 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 217 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 218 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 219 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )