build/tizen-cmake/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 1)
  12 SET(${name}_VERSION_PATCH 1)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24 SET(GLES_VERSION 20 CACHE INTEGER "Gles Version")
  25
  26 # Set up compiler definitions
  27
  28 ADD_DEFINITIONS(-DPLATFORM_TIZEN -DDALI_COMPILATION)
  29 ADD_DEFINITIONS(-DDALI_GLES_VERSION=${GLES_VERSION})
  30 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  31
  32 IF("${ARCH}" STREQUAL "arm")
  33     ADD_DEFINITIONS("-DTARGET")
  34 ENDIF("${ARCH}" STREQUAL "arm")
  35
  36 IF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  37   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  38 ENDIF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  39
  40 IF( ENABLE_DEBUG )
  41   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  42 ENDIF( ENABLE_DEBUG )
  43
  44 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  45   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  46 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  47
  48 IF( ENABLE_LOCK_BACKTRACE )
  49   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  50 ENDIF( ENABLE_LOCK_BACKTRACE )
  51
  52 # Deployment folder should come from spec file or command line:
  53 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  54 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  55
  56 # from root/build/tizen, get back to root
  57 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  58
  59 # Requires the following variables to be setup
  60 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIBDIR@ @DEV_INCLUDE_PATH@
  61 SET(INCLUDE_DIR $ENV{includedir})
  62 SET(DEV_INCLUDE_PATH ${INCLUDE_DIR})
  63 SET(LIB_DIR $ENV{libdir})
  64 CONFIGURE_FILE( dali-core.pc.in dali-core.pc )
  65
  66 MESSAGE( STATUS "CMAKE_BUILD_TYPE: " ${CMAKE_BUILD_TYPE} )
  67 if(CMAKE_BUILD_TYPE MATCHES Debug)
  68     MESSAGE("Setting variable: DEBUG_ENABLED")
  69     SET(DEBUG_ENABLED "1")
  70 ENDIF()
  71
  72 # Set up compiler flags and warnings
  73 #ADD_COMPILE_OPTIONS( -std=c++11 -ggdb )
  74 ADD_COMPILE_OPTIONS( -std=c++11 -gdwarf-4 )
  75 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  76 ADD_COMPILE_OPTIONS( -Werror -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
  77
  78 IF( ENABLE_DEBUG )
  79   ADD_COMPILE_OPTIONS( -O0 )
  80 ELSE( ENABLE_DEBUG )
  81   ADD_COMPILE_OPTIONS( -Os )
  82 ENDIF( ENABLE_DEBUG )
  83
  84 IF( ENABLE_COVERAGE OR CXXFLAGS MATCHES --coverage)
  85   ADD_COMPILE_OPTIONS( --coverage )
  86   SET(COVERAGE --coverage)
  87 ENDIF()
  88
  89 INCLUDE_DIRECTORIES(
  90   ${ROOT_SRC_DIR}
  91 )
  92
  93 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
  94
  95 SET(SOURCES "")
  96
  97 # could use INCLUDE to get the source lists a different way;
  98 # would then need to specify a build folder somehow...
  99 ADD_SUBDIRECTORY( ${SOURCE_DIR}/internal dali/internal )
 100 ADD_SUBDIRECTORY( ${SOURCE_DIR}/integration-api dali/integration-api )
 101 ADD_SUBDIRECTORY( ${SOURCE_DIR}/public-api dali/public-api )
 102 ADD_SUBDIRECTORY( ${SOURCE_DIR}/devel-api dali/devel-api )
 103
 104 ADD_LIBRARY( ${name} SHARED ${SOURCES} )
 105
 106 TARGET_LINK_LIBRARIES( ${name}
 107   -lpthread
 108   ${COVERAGE}
 109 )
 110
 111 SET_TARGET_PROPERTIES( ${name}
 112   PROPERTIES
 113   VERSION ${DALI_VERSION}
 114   SOVERSION ${${name}_VERSION_MAJOR}
 115   CLEAN_DIRECT_OUPUT 1
 116 )
 117
 118 # Install the library so file and symlinks
 119 INSTALL( TARGETS ${name} DESTINATION ${PREFIX}/lib )
 120
 121 # macro for installing headers by replacing prefix. (TODO, investigate
 122 # if there is a CMAKE way of doing this automatically)
 123 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 124   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 125   FOREACH(HEADER ${${HEADER_LIST}})
 126     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 127     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 128     INSTALL(FILES ${HEADER} DESTINATION ${PREFIX}/include/${NEWDIR})
 129   ENDFOREACH(HEADER)
 130 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 131
 132 # Install headers using lists defined by ADD_SUBDIRECTORY
 133 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${SOURCE_DIR} "dali")
 134 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${SOURCE_DIR} "dali")
 135 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${SOURCE_DIR} "dali")
 136
 137 IF(UNIX)
 138   # Define custom rules for coverage
 139   SET(COVERAGE_DIR .cov)
 140   SET(COVERAGE_OUTPUT_DIR doc/coverage)
 141
 142   # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 143   # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 144   EXECUTE_PROCESS( COMMAND bash -c "lcov --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 145   STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 146   IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 147     SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 148   ENDIF()
 149
 150   ADD_CUSTOM_TARGET( cov_data lcov ${LCOV_OPTS} --base-directory dali --directory . -c -o dali.info
 151           COMMAND lcov ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 152
 153   ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 154     DEPENDS cov_data )
 155
 156   ADD_CUSTOM_TARGET( reset_coverage @lcov -z --directory `pwd` )
 157
 158   # Define custom rule for distclean
 159   ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 160   ADD_CUSTOM_COMMAND(
 161         DEPENDS clean
 162         COMMENT "distribution clean"
 163         COMMAND find
 164         ARGS    .
 165         -not -name config.cmake -and \(
 166         -name tester.c -or
 167         -name Testing -or
 168         -name CMakeFiles -or
 169         -name cmake.depends -or
 170         -name cmake.check_depends -or
 171         -name CMakeCache.txt -or
 172         -name cmake.check_cache -or
 173         -name *.cmake -or
 174         -name Makefile -or
 175         -name core -or
 176         -name core.* -or
 177         -name gmon.out -or
 178         -name install_manifest.txt -or
 179         -name *.pc -or
 180         -name *.gcov -or
 181         -name *.gcno -or
 182         -name *.gcda -or
 183         -name *~ \)
 184         | grep -v TC | xargs rm -rf
 185         TARGET  distclean
 186         VERBATIM
 187         )
 188
 189 ENDIF(UNIX)
 190
 191
 192 MESSAGE( STATUS "Configuration:\n" )
 193 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 194 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 195 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 196 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 197 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )