build/tizen-cmake/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 1)
  12 SET(${name}_VERSION_PATCH 1)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24
  25 # Set up compiler definitions
  26
  27 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  28   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  29   SET(ENABLE_DEBUG ON)
  30 ELSE()
  31   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  32 ENDIF()
  33
  34 ADD_DEFINITIONS(-DPLATFORM_TIZEN -DDALI_COMPILATION)
  35 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  36
  37 IF("${ARCH}" STREQUAL "arm")
  38   ADD_DEFINITIONS("-DTARGET")
  39 ENDIF("${ARCH}" STREQUAL "arm")
  40
  41 IF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  42   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  43 ENDIF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  44
  45 IF( ENABLE_DEBUG )
  46   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  47 ENDIF( ENABLE_DEBUG )
  48
  49 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  50   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  51 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  52
  53 IF( ENABLE_LOCK_BACKTRACE )
  54   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  55 ENDIF( ENABLE_LOCK_BACKTRACE )
  56
  57 # Deployment folder should come from spec file or command line:
  58 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  59 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  60
  61 # from root/build/tizen, get back to root
  62 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  63
  64 # Set up the include dir
  65 SET( INCLUDE_DIR $ENV{includedir} )
  66 IF( NOT INCLUDE_DIR )
  67   SET( INCLUDE_DIR ${PREFIX}/include )
  68 ENDIF()
  69
  70 # Set up the lib dir
  71 SET( LIB_DIR $ENV{libdir} )
  72 IF( NOT LIB_DIR )
  73   SET( LIB_DIR ${PREFIX}/lib )
  74 ENDIF()
  75
  76 # Configure the pkg-config file
  77 # Requires the following variables to be setup:
  78 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  79 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
  80 SET( CORE_PKG_CFG_FILE dali-core.pc )
  81 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
  82
  83 # Set up compiler flags and warnings
  84 #ADD_COMPILE_OPTIONS( -std=c++11 -ggdb )
  85 ADD_COMPILE_OPTIONS( -std=c++11 -gdwarf-4 )
  86 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  87 ADD_COMPILE_OPTIONS( -Werror -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
  88
  89 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
  90   ADD_COMPILE_OPTIONS( --coverage )
  91   SET(ENABLE_COVERAGE ON)
  92   SET(COVERAGE --coverage)
  93 ENDIF()
  94
  95 INCLUDE_DIRECTORIES(
  96   ${ROOT_SRC_DIR}
  97 )
  98
  99 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 100 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 101
 102 SET(SOURCES "")
 103
 104 # could use INCLUDE to get the source lists a different way;
 105 # would then need to specify a build folder somehow...
 106 ADD_SUBDIRECTORY( ${SOURCE_DIR}/internal dali/internal )
 107 ADD_SUBDIRECTORY( ${SOURCE_DIR}/integration-api dali/integration-api )
 108 ADD_SUBDIRECTORY( ${SOURCE_DIR}/public-api dali/public-api )
 109 ADD_SUBDIRECTORY( ${SOURCE_DIR}/devel-api dali/devel-api )
 110 ADD_SUBDIRECTORY( ${PACKAGE_DOXY_SRC_DIR} doc )
 111
 112 ADD_LIBRARY( ${name} SHARED ${SOURCES} )
 113
 114 TARGET_LINK_LIBRARIES( ${name}
 115   -lpthread
 116   ${COVERAGE}
 117 )
 118
 119 SET_TARGET_PROPERTIES( ${name}
 120   PROPERTIES
 121   VERSION ${DALI_VERSION}
 122   SOVERSION ${${name}_VERSION_MAJOR}
 123   CLEAN_DIRECT_OUPUT 1
 124 )
 125
 126 # Install the library so file and symlinks
 127 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 128
 129 # Install the pkg-config file
 130 INSTALL( FILES ${CMAKE_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 131
 132 # macro for installing headers by replacing prefix. (TODO, investigate
 133 # if there is a CMAKE way of doing this automatically)
 134 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 135   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 136   FOREACH(HEADER ${${HEADER_LIST}})
 137     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 138     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 139     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 140   ENDFOREACH(HEADER)
 141 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 142
 143 # Install headers using lists defined by ADD_SUBDIRECTORY
 144 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${SOURCE_DIR} "dali")
 145 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${SOURCE_DIR} "dali")
 146 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${SOURCE_DIR} "dali")
 147 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 148
 149 IF(UNIX)
 150   # Define custom rules for coverage
 151   SET(COVERAGE_DIR .cov)
 152   SET(COVERAGE_OUTPUT_DIR doc/coverage)
 153
 154   # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 155   # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 156   EXECUTE_PROCESS( COMMAND bash -c "lcov --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 157   STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 158   IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 159     SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 160   ENDIF()
 161
 162   ADD_CUSTOM_TARGET( cov_data lcov ${LCOV_OPTS} --base-directory dali --directory . -c -o dali.info
 163           COMMAND lcov ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 164
 165   ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 166     DEPENDS cov_data )
 167
 168   ADD_CUSTOM_TARGET( reset_coverage @lcov -z --directory `pwd` )
 169
 170   # Define custom rule for distclean
 171   ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 172   ADD_CUSTOM_COMMAND(
 173         DEPENDS clean
 174         COMMENT "distribution clean"
 175         COMMAND find
 176         ARGS    .
 177         -not -name config.cmake -and \(
 178         -name tester.c -or
 179         -name Testing -or
 180         -name CMakeFiles -or
 181         -name cmake.depends -or
 182         -name cmake.check_depends -or
 183         -name CMakeCache.txt -or
 184         -name cmake.check_cache -or
 185         -name *.cmake -or
 186         -name Makefile -or
 187         -name core -or
 188         -name core.* -or
 189         -name gmon.out -or
 190         -name install_manifest.txt -or
 191         -name *.pc -or
 192         -name *.gcov -or
 193         -name *.gcno -or
 194         -name *.gcda -or
 195         -name *~ \)
 196         | grep -v TC | xargs rm -rf
 197         TARGET  distclean
 198         VERBATIM
 199         )
 200
 201 ENDIF(UNIX)
 202
 203
 204 MESSAGE( STATUS "Configuration:\n" )
 205 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 206 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 207 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 208 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 209 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 210 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 211 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 212 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 213 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )