build/tizen/configure.ac

   1 #
   2 # Copyright (c) 2015 Samsung Electronics Co., Ltd.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 # http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 m4_define([dali_version],[0.1.0])
  18 AC_INIT([dali], [dali_version])
  19 AM_INIT_AUTOMAKE([-Wall foreign])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_CXX
  24 AC_PROG_LIBTOOL
  25 AC_PROG_MKDIR_P
  26
  27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  28
  29 LT_INIT
  30
  31 DALI_ADAPTOR_VERSION=dali_version
  32 AC_SUBST(DALI_ADAPTOR_VERSION)
  33
  34 FREETYPE_REQUIRED=9.16.3
  35 # 17.1.11 = Freetype version 2.5.2
  36 FREETYPE_BITMAP_SUPPORT_VERSION=17.1.11
  37
  38 PKG_CHECK_MODULES(DALICORE, dali-core)
  39 PKG_CHECK_MODULES(ELEMENTARY, elementary)
  40 PKG_CHECK_MODULES(ECORE, ecore)
  41 PKG_CHECK_MODULES(ECORE_IPC, ecore-ipc)
  42 PKG_CHECK_MODULES(EXIF, libexif)
  43 PKG_CHECK_MODULES(FREETYPE, [freetype2 >= $FREETYPE_REQUIRED])
  44 PKG_CHECK_MODULES(FREETYPE_BITMAP_SUPPORT, [freetype2 >= $FREETYPE_BITMAP_SUPPORT_VERSION], [ freetype_bitmap_support=yes  ], [ freetype_bitmap_support=no ] )
  45 PKG_CHECK_MODULES(FONTCONFIG, fontconfig)
  46 PKG_CHECK_MODULES(PNG, libpng)
  47 PKG_CHECK_MODULES(XML, libxml-2.0)
  48 PKG_CHECK_MODULES(LIBEXIF, libexif)
  49 PKG_CHECK_MODULES(LIBDRM, libdrm)
  50 PKG_CHECK_MODULES(LIBCURL, libcurl)
  51 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz)
  52 PKG_CHECK_MODULES(FRIBIDI, fribidi)
  53 PKG_CHECK_MODULES(TTRACE,  ttrace, AC_DEFINE(ENABLE_TTRACE, 1, [ttrace available]),
  54                   [ AC_MSG_NOTICE([Tizen Trace not avaiable]) ]
  55                   )
  56
  57
  58 # Check for EldBus.h in ECore
  59 PKG_CHECK_MODULES(ELDBUS, eldbus, [ eldbus_available=yes ],  [ eldbus_available=no ] )
  60
  61 DALI_ELDBUS_AVAILABLE=
  62 if test "x$eldbus_available" = "xyes"; then
  63   DALI_ELDBUS_AVAILABLE=true
  64   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_ELDBUS_AVAILABLE "
  65 fi
  66 AC_SUBST(DALI_ELDBUS_AVAILABLE)
  67
  68
  69 AC_ARG_ENABLE([feedback],
  70               [AC_HELP_STRING([ --enable-feedback],
  71                               [Enable feedback plugin])],
  72               [enable_feedback=yes],
  73               [enable_feedback=no])
  74
  75 AM_CONDITIONAL([USE_FEEDBACK], [test x$enable_feedback = xyes])
  76
  77 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DPLATFORM_TIZEN"
  78
  79 AC_ARG_ENABLE(exportall,
  80               [AC_HELP_STRING([--enable-exportall],
  81                               [enables the exporting of all the symbols in the library])],
  82               [enable_exportall=yes],
  83               [enable_exportall=no])
  84
  85 AC_ARG_ENABLE([debug],
  86               [AC_HELP_STRING([--enable-debug],
  87                               [Turns on debugging])],
  88               [enable_debug=$enableval],
  89               [enable_debug=no])
  90
  91 AC_ARG_ENABLE(shaderbincache,
  92               [AC_HELP_STRING([--enable-shaderbincache],
  93                               [enables shader binary cache])],
  94               [enable_shaderbincache=$enableval],
  95               [enable_shaderbincache=DISABLE])
  96
  97 if test "x$enable_debug" = "xyes"; then
  98   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDEBUG_ENABLED"
  99 fi
 100
 101 if test "x$enable_debug" = "xno" -a "x$enable_exportall" = "xno"; then
 102   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -fvisibility=hidden -DHIDE_DALI_INTERNALS"
 103 fi
 104
 105 if test "x$enable_shaderbincache" = "xENABLE"; then
 106   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DSHADERBIN_CACHE_ENABLED"
 107 fi
 108
 109 AC_ARG_ENABLE([gles],
 110               [AC_HELP_STRING([--enable-gles],
 111                               [Specify the OpenGL ES version for backwards compatibility])],
 112               [enable_gles=$enableval],
 113               [enable_gles=30])
 114
 115 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_GLES_VERSION=${enable_gles}"
 116
 117 # node.js by default statically links against libuv, so it doesn't need to install
 118 # a libuv headers/ shared library. So we can't use pkg-config to access any headers.
 119 # As a work around we pass the node deps path so we can access the libuv headers inside nodes
 120 # directory
 121 AC_ARG_WITH([node-js],
 122               [AC_HELP_STRING([--with-node-js],
 123                               [Node.JS path that contains Lib UV headers. Setting this configures DALi to work with LibUV mainloop used in Node.JS.
 124                               For example /usr/tmp/downloads/node-v0.12.4/deps/uv/include/ ])],
 125               [with_node_js=$withval],
 126               [with_node_js=no])
 127
 128 # Node.JS already has a libuv main loop running,so we have to integrate with it
 129 AM_CONDITIONAL(LIB_UV_EVENT_LOOP, test x$with_node_js != xno)
 130
 131
 132 build_for_node_js=no
 133 if test "x$with_node_js" != "xno"; then
 134   AC_MSG_NOTICE("build for node_js == yes");
 135   [build_for_node_js=yes]
 136   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DNODE_JS_SUPPORT  -I${with_node_js}"
 137 else
 138  #not using node.js build
 139   AC_MSG_NOTICE("build for node_js == no");
 140 fi
 141
 142
 143 AC_ARG_WITH([over-tizen_2_2],
 144             [AC_HELP_STRING([--with-over-tizen_2_2],
 145                             [Use tizen API over ver. 2.2])],
 146             [with_over_tizen_2_2=yes],
 147             [with_over_tizen_2_2=no])
 148
 149 # Tizen Profile options
 150 AC_ARG_ENABLE([profile],
 151               [AC_HELP_STRING([--enable-profile=COMMON,MOBILE,WEARABLE,TV,UBUNTU],
 152                             [Select the variant of tizen])],
 153               [enable_profile=$enableval],
 154               [enable_profile=COMMON])
 155
 156 # Ensure valid profile selected
 157 if test "x$enable_profile" != "xCOMMON" -a "x$enable_profile" != "xMOBILE" -a "x$enable_profile" != "xWEARABLE" -a "x$enable_profile" != "xTV" -a "x$enable_profile" != "xUBUNTU"; then
 158   AC_MSG_ERROR([$enable_profile is an invalid profile])
 159 fi
 160
 161 AC_ARG_ENABLE(wayland,
 162               [  --enable-wayland       Build on Wayland],
 163               enable_wayland=yes,
 164               enable_wayland=no)
 165
 166 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_PROFILE_${enable_profile}"
 167 DALI_PROFILE_CFLAGS=" -DDALI_PROFILE_${enable_profile}"
 168 AM_CONDITIONAL([COMMON_PROFILE], [test x$enable_profile = xCOMMON])
 169 AM_CONDITIONAL([MOBILE_PROFILE], [test x$enable_profile = xMOBILE])
 170 AM_CONDITIONAL([WEARABLE_PROFILE], [test x$enable_profile = xWEARABLE])
 171 AM_CONDITIONAL([TV_PROFILE], [test x$enable_profile = xTV])
 172 AM_CONDITIONAL([UBUNTU_PROFILE], [test x$enable_profile = xUBUNTU])
 173 AM_CONDITIONAL([WAYLAND], [test x$enable_wayland = xyes])
 174
 175 # Platforms should either enable features or remove them, they
 176 # should not disable features. This allows the developer to override
 177 # features through the command line.
 178
 179 PKG_CHECK_MODULES(OPENGLES20, glesv2 egl)
 180
 181 if test "x$enable_profile" != "xUBUNTU"; then
 182 PKG_CHECK_MODULES(CAPI_APPFW_APPLICATION, capi-appfw-application)
 183 PKG_CHECK_MODULES(DLOG, dlog)
 184 PKG_CHECK_MODULES(SENSOR, sensor)
 185 PKG_CHECK_MODULES(TTS, tts)
 186 PKG_CHECK_MODULES(VCONF, vconf)
 187 PKG_CHECK_MODULES(CAPI_SYSTEM_SYSTEM_SETTINGS, capi-system-system-settings)
 188
 189 if test "x$enable_wayland" != "xyes"; then
 190 PKG_CHECK_MODULES(UTILX, utilX)
 191 fi
 192
 193 if test "x$with_over_tizen_2_2" = "xyes"; then
 194 PKG_CHECK_MODULES(CAPI_SYSTEM_INFO, capi-system-info)
 195 fi
 196
 197 fi # ubuntu profile test
 198
 199 if test "x$enable_wayland" = "xyes"; then
 200 PKG_CHECK_MODULES(WAYLAND, [ecore-wayland egl wayland-egl wayland-client >= 1.2.0 xkbcommon],
 201                   [DALI_HAS_ECOREWL=yes],
 202                   [DALI_HAS_ECOREWL=no])
 203 else
 204 PKG_CHECK_MODULES(ECORE_X, [ecore-x],
 205                   [DALI_HAS_ECOREX=yes],
 206                   [DALI_HAS_ECOREX=no])
 207 PKG_CHECK_MODULES(X11, [x11],
 208                   [DALI_HAS_X11=yes],
 209                   [DALI_HAS_X11=no])
 210 fi
 211
 212 if test "x$enable_feedback" = "xyes"; then
 213
 214 if test "x$enable_profile" = "xCOMMON" || test "x$enable_profile" = "xTV"; then
 215 PKG_CHECK_MODULES(HAPTIC, haptic)
 216 fi
 217
 218 if test "x$enable_profile" = "xMOBILE"; then
 219 PKG_CHECK_MODULES(DEVICED, deviced)
 220 fi
 221
 222 PKG_CHECK_MODULES(FEEDBACK, feedback)
 223 PKG_CHECK_MODULES(MMFSOUND, mm-sound)
 224 fi
 225
 226 if test x$DALI_DATA_RW_DIR != x; then
 227   dataReadWriteDir=$DALI_DATA_RW_DIR
 228 else
 229   dataReadWriteDir=${prefix}/share/dali/
 230 fi
 231
 232 if test x$DALI_DATA_RO_DIR != x; then
 233   dataReadOnlyDir=$DALI_DATA_RO_DIR
 234 else
 235   dataReadOnlyDir=${prefix}/share/dali/
 236 fi
 237
 238 AC_SUBST(dataReadWriteDir)
 239 AC_SUBST(dataReadOnlyDir)
 240 AC_SUBST(DALI_ADAPTOR_CFLAGS)
 241 AC_SUBST(DALI_PROFILE_CFLAGS)
 242
 243 # Specify the include directory for development headers
 244 #devincludepath=${includedir}/dali/internal
 245 devincludepath=${includedir}
 246 AC_SUBST(devincludepath)
 247
 248 AC_CONFIG_FILES([
 249  Makefile
 250  adaptor/Makefile
 251  dali.pc
 252  adaptor/dali-adaptor-integration.pc
 253 ])
 254
 255 AM_CONDITIONAL([USE_PLUGIN], [test x$enable_feedback = xyes])
 256
 257 if test "x$enable_feedback" = "xyes"; then
 258 AC_CONFIG_FILES([
 259  plugins/Makefile
 260 ])
 261 fi
 262
 263 if test "x$freetype_bitmap_support" = "xyes"; then
 264 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DFREETYPE_BITMAP_SUPPORT"
 265 fi
 266
 267 AC_OUTPUT
 268
 269
 270 echo "
 271 Configuration
 272 -------------
 273   Prefix:                           $prefix
 274   Debug Build:                      $enable_debug
 275   Compile flags                     $DALI_ADAPTOR_CFLAGS
 276   Freetype bitmap support (Emoji):  $freetype_bitmap_support
 277   Profile:                          $enable_profile
 278   Data Dir (Read/Write):            $dataReadWriteDir
 279   Data Dir (Read Only):             $dataReadOnlyDir
 280   OVERTIZEN2.2:                     $with_over_tizen_2_2
 281   EldBus:                           $eldbus_available
 282   Shader Binary Cache:              $enable_shaderbincache
 283   Build for Node.JS (LibUV)         $build_for_node_js
 284 "
 285 # optional output of node.js source path if we're building for node.js
 286 if test "x$build_for_node_js" != "xno"; then
 287 echo "  Node.JS LibUV header path         $with_node_js"
 288 fi