build/tizen/configure.ac

   1 #
   2 # Copyright (c) 2014 Samsung Electronics Co., Ltd.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 # http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 m4_define([dali_version],[0.1.0])
  18 AC_INIT([dali], [dali_version])
  19 AM_INIT_AUTOMAKE([-Wall foreign])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_CXX
  24 AC_PROG_LIBTOOL
  25 AC_PROG_MKDIR_P
  26
  27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  28
  29 LT_INIT
  30
  31 DALI_ADAPTOR_VERSION=dali_version
  32 AC_SUBST(DALI_ADAPTOR_VERSION)
  33
  34 FREETYPE_REQUIRED=9.16.3
  35 # 17.1.11 = Freetype version 2.5.2
  36 FREETYPE_BITMAP_SUPPORT_VERSION=17.1.11
  37
  38 PKG_CHECK_MODULES(DALICORE, dali-core)
  39 PKG_CHECK_MODULES(ELEMENTARY, elementary)
  40 PKG_CHECK_MODULES(ECORE, ecore)
  41 PKG_CHECK_MODULES(ECORE_IPC, ecore-ipc)
  42 PKG_CHECK_MODULES(EXIF, libexif)
  43 PKG_CHECK_MODULES(FREETYPE, [freetype2 >= $FREETYPE_REQUIRED])
  44 PKG_CHECK_MODULES(FREETYPE_BITMAP_SUPPORT, [freetype2 >= $FREETYPE_BITMAP_SUPPORT_VERSION], [ freetype_bitmap_support=yes  ], [ freetype_bitmap_support=no ] )
  45 PKG_CHECK_MODULES(FONTCONFIG, fontconfig)
  46 PKG_CHECK_MODULES(PNG, libpng)
  47 PKG_CHECK_MODULES(XML, libxml-2.0)
  48 PKG_CHECK_MODULES(LIBEXIF, libexif)
  49 PKG_CHECK_MODULES(LIBDRM, libdrm)
  50 PKG_CHECK_MODULES(LIBCURL, libcurl)
  51 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz)
  52 PKG_CHECK_MODULES(FRIBIDI, fribidi)
  53 PKG_CHECK_MODULES(TTRACE,  ttrace, AC_DEFINE(ENABLE_TTRACE, 1, [ttrace available]),
  54                   [ AC_MSG_NOTICE([Tizen Trace not avaiable]) ]
  55                   )
  56
  57
  58 # Check for EldBus.h in ECore
  59 PKG_CHECK_MODULES(ELDBUS, eldbus, [ eldbus_available=yes ],  [ eldbus_available=no ] )
  60
  61 DALI_ELDBUS_AVAILABLE=
  62 if test "x$eldbus_available" = "xyes"; then
  63   DALI_ELDBUS_AVAILABLE=true
  64   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_ELDBUS_AVAILABLE "
  65 fi
  66 AC_SUBST(DALI_ELDBUS_AVAILABLE)
  67
  68
  69 PKG_CHECK_EXISTS(bullet, [
  70   BULLET_CFLAGS=`pkg-config --cflags bullet`
  71   BULLET_LIBS=`pkg-config --libs bullet`
  72   BULLET=yes
  73 ], [
  74   AC_MSG_WARN([BulletPhysics development files not found, not building bullet plugin])
  75   BULLET_CFLAGS=
  76   BULLET_LIBS=
  77   BULLET=no
  78 ])
  79
  80 AC_SUBST(BULLET_CFLAGS)
  81 AC_SUBST(BULLET_LIBS)
  82
  83 AC_ARG_ENABLE([bullet],
  84               [AC_HELP_STRING([ --enable-bullet],
  85                               [Enable bullet plugin])],
  86               [enable_bullet=yes],
  87               [enable_bullet=no])
  88
  89
  90 AC_ARG_ENABLE([feedback],
  91               [AC_HELP_STRING([ --enable-feedback],
  92                               [Enable feedback plugin])],
  93               [enable_feedback=yes],
  94               [enable_feedback=no])
  95
  96 AM_CONDITIONAL([USE_BULLET], [test x$BULLET = xyes && test x$enable_bullet = xyes])
  97 AM_CONDITIONAL([USE_FEEDBACK], [test x$enable_feedback = xyes])
  98
  99 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DPLATFORM_TIZEN"
 100
 101 AC_ARG_ENABLE(exportall,
 102               [AC_HELP_STRING([--enable-exportall],
 103                               [enables the exporting of all the symbols in the library])],
 104               [enable_exportall=yes],
 105               [enable_exportall=no])
 106
 107 AC_ARG_ENABLE([debug],
 108               [AC_HELP_STRING([--enable-debug],
 109                               [Turns on debugging])],
 110               [enable_debug=$enableval],
 111               [enable_debug=no])
 112
 113 AC_ARG_ENABLE(shaderbincache,
 114               [AC_HELP_STRING([--enable-shaderbincache],
 115                               [enables shader binary cache])],
 116               [enable_shaderbincache=$enableval],
 117               [enable_shaderbincache=DISABLE])
 118
 119 if test "x$enable_debug" = "xyes"; then
 120   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDEBUG_ENABLED"
 121 fi
 122
 123 if test "x$enable_debug" = "xno" -a "x$enable_exportall" = "xno"; then
 124   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -fvisibility=hidden -DHIDE_DALI_INTERNALS"
 125 fi
 126
 127 if test "x$enable_shaderbincache" = "xENABLE"; then
 128   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DSHADERBIN_CACHE_ENABLED"
 129 fi
 130
 131 AC_ARG_ENABLE([gles],
 132               [AC_HELP_STRING([--enable-gles],
 133                               [Specify the OpenGL ES version for backwards compatibility])],
 134               [enable_gles=$enableval],
 135               [enable_gles=30])
 136
 137 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_GLES_VERSION=${enable_gles}"
 138
 139 AC_ARG_WITH([over-tizen_2_2],
 140             [AC_HELP_STRING([--with-over-tizen_2_2],
 141                             [Use tizen API over ver. 2.2])],
 142             [with_over_tizen_2_2=yes],
 143             [with_over_tizen_2_2=no])
 144
 145 # Tizen Profile options
 146 AC_ARG_ENABLE([profile],
 147               [AC_HELP_STRING([--enable-profile=COMMON,MOBILE,WEARABLE,TV,UBUNTU],
 148                             [Select the variant of tizen])],
 149               [enable_profile=$enableval],
 150               [enable_profile=COMMON])
 151
 152 # Ensure valid profile selected
 153 if test "x$enable_profile" != "xCOMMON" -a "x$enable_profile" != "xMOBILE" -a "x$enable_profile" != "xWEARABLE" -a "x$enable_profile" != "xTV" -a "x$enable_profile" != "xUBUNTU"; then
 154   AC_MSG_ERROR([$enable_profile is an invalid profile])
 155 fi
 156
 157 AC_ARG_ENABLE(wayland,
 158               [  --enable-wayland       Build on Wayland],
 159               enable_wayland=yes,
 160               enable_wayland=no)
 161
 162 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_PROFILE_${enable_profile}"
 163 DALI_PROFILE_CFLAGS=" -DDALI_PROFILE_${enable_profile}"
 164 AM_CONDITIONAL([COMMON_PROFILE], [test x$enable_profile = xCOMMON])
 165 AM_CONDITIONAL([MOBILE_PROFILE], [test x$enable_profile = xMOBILE])
 166 AM_CONDITIONAL([WEARABLE_PROFILE], [test x$enable_profile = xWEARABLE])
 167 AM_CONDITIONAL([TV_PROFILE], [test x$enable_profile = xTV])
 168 AM_CONDITIONAL([UBUNTU_PROFILE], [test x$enable_profile = xUBUNTU])
 169 AM_CONDITIONAL([WAYLAND], [test x$enable_wayland = xyes])
 170
 171 # Platforms should either enable features or remove them, they
 172 # should not disable features. This allows the developer to override
 173 # features through the command line.
 174
 175 PKG_CHECK_MODULES(OPENGLES20, glesv2 egl)
 176
 177 if test "x$enable_profile" != "xUBUNTU"; then
 178 PKG_CHECK_MODULES(CAPI_APPFW_APPLICATION, capi-appfw-application)
 179 PKG_CHECK_MODULES(DLOG, dlog)
 180 PKG_CHECK_MODULES(SENSOR, sensor)
 181 PKG_CHECK_MODULES(TTS, tts)
 182 PKG_CHECK_MODULES(VCONF, vconf)
 183 PKG_CHECK_MODULES(CAPI_SYSTEM_SYSTEM_SETTINGS, capi-system-system-settings)
 184
 185 if test "x$with_over_tizen_2_2" = "xyes"; then
 186 PKG_CHECK_MODULES(CAPI_SYSTEM_INFO, capi-system-info)
 187 fi
 188
 189 fi # ubuntu profile test
 190
 191 if test "x$enable_wayland" = "xyes"; then
 192 PKG_CHECK_MODULES(WAYLAND, [ecore-wayland egl wayland-egl wayland-client >= 1.2.0 xkbcommon],
 193                   [DALI_HAS_ECOREWL=yes],
 194                   [DALI_HAS_ECOREWL=no])
 195 else
 196 PKG_CHECK_MODULES(ECORE_X, [ecore-x],
 197                   [DALI_HAS_ECOREX=yes],
 198                   [DALI_HAS_ECOREX=no])
 199 PKG_CHECK_MODULES(X11, [x11],
 200                   [DALI_HAS_X11=yes],
 201                   [DALI_HAS_X11=no])
 202 fi
 203
 204 if test "x$enable_feedback" = "xyes"; then
 205
 206 if test "x$enable_profile" = "xCOMMON" || test "x$enable_profile" = "xTV"; then
 207 PKG_CHECK_MODULES(HAPTIC, haptic)
 208 fi
 209
 210 if test "x$enable_profile" = "xMOBILE"; then
 211 PKG_CHECK_MODULES(DEVICED, deviced)
 212 fi
 213
 214 PKG_CHECK_MODULES(FEEDBACK, feedback)
 215 PKG_CHECK_MODULES(MMFSOUND, mm-sound)
 216 fi
 217
 218 if test x$DALI_DATA_RW_DIR != x; then
 219   dataReadWriteDir=$DALI_DATA_RW_DIR
 220 else
 221   dataReadWriteDir=${prefix}/share/dali/
 222 fi
 223
 224 if test x$DALI_DATA_RO_DIR != x; then
 225   dataReadOnlyDir=$DALI_DATA_RO_DIR
 226 else
 227   dataReadOnlyDir=${prefix}/share/dali/
 228 fi
 229
 230 AC_SUBST(dataReadWriteDir)
 231 AC_SUBST(dataReadOnlyDir)
 232 AC_SUBST(DALI_ADAPTOR_CFLAGS)
 233 AC_SUBST(DALI_PROFILE_CFLAGS)
 234
 235 # Specify the include directory for development headers
 236 #devincludepath=${includedir}/dali/internal
 237 devincludepath=${includedir}
 238 AC_SUBST(devincludepath)
 239
 240 AC_CONFIG_FILES([
 241  Makefile
 242  adaptor/Makefile
 243  dali.pc
 244  adaptor/dali-adaptor-integration.pc
 245 ])
 246
 247 AM_CONDITIONAL([USE_PLUGIN], [test x$enable_feedback = xyes || test x$enable_bullet = xyes])
 248
 249 if test "x$enable_feedback" = "xyes" || test "x$enable_bullet" = "xyes"; then
 250 AC_CONFIG_FILES([
 251  plugins/Makefile
 252 ])
 253 fi
 254
 255 if test "x$freetype_bitmap_support" = "xyes"; then
 256 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DFREETYPE_BITMAP_SUPPORT"
 257 fi
 258
 259 AC_OUTPUT
 260
 261
 262 echo "
 263 Configuration
 264 -------------
 265   Prefix:                           $prefix
 266   Debug Build:                      $enable_debug
 267   Compile flags                     $DALI_ADAPTOR_CFLAGS
 268   Freetype bitmap support (Emoji):  $freetype_bitmap_support
 269   Profile:                          $enable_profile
 270   Data Dir (Read/Write):            $dataReadWriteDir
 271   Data Dir (Read Only):             $dataReadOnlyDir
 272   OVERTIZEN2.2:                     $with_over_tizen_2_2
 273   EldBus:                           $eldbus_available
 274 "