build/tizen/adaptor/configure.ac

   1 #
   2 # Copyright (c) 2015 Samsung Electronics Co., Ltd.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 # http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 m4_define([dali_version],[0.1.0])
  18 AC_INIT([dali], [dali_version])
  19 AM_INIT_AUTOMAKE([-Wall foreign])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_CXX
  24 AC_PROG_LIBTOOL
  25 AC_PROG_MKDIR_P
  26
  27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  28
  29 LT_INIT
  30
  31 DALI_ADAPTOR_VERSION=dali_version
  32 AC_SUBST(DALI_ADAPTOR_VERSION)
  33
  34 FREETYPE_REQUIRED=9.16.3
  35 # 17.1.11 = Freetype version 2.5.2
  36 FREETYPE_BITMAP_SUPPORT_VERSION=17.1.11
  37
  38 PKG_CHECK_MODULES(DALICORE, dali-core)
  39 PKG_CHECK_MODULES(EXIF, libexif)
  40 PKG_CHECK_MODULES(FREETYPE, [freetype2 >= $FREETYPE_REQUIRED])
  41 PKG_CHECK_MODULES(FREETYPE_BITMAP_SUPPORT, [freetype2 >= $FREETYPE_BITMAP_SUPPORT_VERSION], [ freetype_bitmap_support=yes  ], [ freetype_bitmap_support=no ] )
  42 PKG_CHECK_MODULES(FONTCONFIG, fontconfig)
  43 PKG_CHECK_MODULES(PNG, libpng)
  44 PKG_CHECK_MODULES(LIBEXIF, libexif)
  45 PKG_CHECK_MODULES(LIBDRM, libdrm)
  46 PKG_CHECK_MODULES(LIBCURL, libcurl)
  47 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz)
  48 PKG_CHECK_MODULES(FRIBIDI, fribidi)
  49 PKG_CHECK_MODULES(TTRACE,  ttrace, AC_DEFINE(ENABLE_TTRACE, 1, [ttrace available]),
  50                   [ AC_MSG_NOTICE([Tizen Trace not avaiable]) ]
  51                   )
  52
  53 # Currently, dali-adaptor always requires EFL on all platforms.
  54 # (on Wayland & X11, on Tizen devices & Ubuntu PC).
  55 enable_efl=yes
  56 if test "x$enable_efl" = "xyes"; then
  57 PKG_CHECK_MODULES(ECORE, ecore)
  58 PKG_CHECK_MODULES(ECORE_IPC, ecore-ipc)
  59 PKG_CHECK_MODULES(ECORE_IMF, [ecore-imf >= 1.13], [ecore_imf_1_13=yes], [ecore_imf_1_13=no])
  60 PKG_CHECK_MODULES(ELEMENTARY, elementary)
  61 # Check for EldBus.h in ECore
  62 PKG_CHECK_MODULES(ELDBUS, eldbus, [ eldbus_available=yes ],  [ eldbus_available=no ] )
  63 fi
  64
  65
  66 DALI_ELDBUS_AVAILABLE=
  67 if test "x$eldbus_available" = "xyes"; then
  68   DALI_ELDBUS_AVAILABLE=true
  69   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_ELDBUS_AVAILABLE "
  70 fi
  71 AC_SUBST(DALI_ELDBUS_AVAILABLE)
  72
  73
  74 PKG_CHECK_MODULES(TPKP_CURL, tpkp-curl, [ tpkp_curl_available=yes ], [ tpkp_curl_available=no ] )
  75
  76 if test "x$tpkp_curl_available" = "xyes"; then
  77   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DTPK_CURL_ENABLED "
  78 fi
  79
  80 PKG_CHECK_MODULES(UTILX, utilX, [ utilx_available=yes ], [ utilx_available=no ] )
  81
  82 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DPLATFORM_TIZEN"
  83
  84 AC_ARG_ENABLE(exportall,
  85               [AC_HELP_STRING([--enable-exportall],
  86                               [enables the exporting of all the symbols in the library])],
  87               [enable_exportall=yes],
  88               [enable_exportall=no])
  89
  90 AC_ARG_ENABLE([debug],
  91               [AC_HELP_STRING([--enable-debug],
  92                               [Turns on debugging])],
  93               [enable_debug=$enableval],
  94               [enable_debug=no])
  95
  96 AC_ARG_ENABLE(shaderbincache,
  97               [AC_HELP_STRING([--enable-shaderbincache],
  98                               [enables shader binary cache])],
  99               [enable_shaderbincache=$enableval],
 100               [enable_shaderbincache=DISABLE])
 101
 102 AC_ARG_ENABLE(networklogging,
 103               [AC_HELP_STRING([--enable-networklogging],
 104                               [enables network for debug tool])],
 105               [enable_networklogging=$enableval],
 106               [enable_networklogging=no])
 107
 108
 109 if test "x$enable_debug" = "xyes"; then
 110   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDEBUG_ENABLED"
 111 fi
 112
 113 if test "x$enable_debug" = "xno" -a "x$enable_exportall" = "xno"; then
 114   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -fvisibility=hidden -DHIDE_DALI_INTERNALS"
 115 fi
 116
 117 if test "x$enable_shaderbincache" = "xENABLE"; then
 118   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DSHADERBIN_CACHE_ENABLED"
 119 fi
 120
 121 if test "x$enable_networklogging" = "xyes"; then
 122   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DNETWORK_LOGGING_ENABLED"
 123 fi
 124
 125 # If Ecore IMF version is greater than 1.13, then some structures are different
 126 if test "x$ecore_imf_1_13" = "xyes"; then
 127   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DECORE_IMF_1_13"
 128 fi
 129
 130 AC_ARG_ENABLE([gles],
 131               [AC_HELP_STRING([--enable-gles],
 132                               [Specify the OpenGL ES version for backwards compatibility])],
 133               [enable_gles=$enableval],
 134               [enable_gles=20])
 135
 136 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_GLES_VERSION=${enable_gles}"
 137
 138 # Currently, dali-adaptor always does not require libuv because it runs on ecore on all platforms.
 139 # (on Wayland & X11, on Tizen devices & Ubuntu PC).
 140 with_libuv=no
 141
 142 # Node.JS already has a libuv main loop running,so we have to integrate with it
 143 AM_CONDITIONAL(LIB_UV_EVENT_LOOP, test x$with_libuv != xno)
 144
 145
 146 build_for_libuv=no
 147 if test "x$with_libuv" != "xno"; then
 148   AC_MSG_NOTICE("build with libuv mainloop (Node.JS support) == yes");
 149   [build_for_libuv=yes]
 150   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DNODE_JS_SUPPORT  -I${with_libuv}"
 151 else
 152  #not using libuv build
 153   AC_MSG_NOTICE("build with libuv mainloop == no (Node.JS not supported)");
 154 fi
 155
 156 # Currently, dali-adaptor requires appfw on Tizen
 157 # and does not require it on Ubuntu.
 158 # So we should be able to enable/disable this option for dali-adaptor.
 159 AC_ARG_ENABLE([appfw],
 160               [AC_HELP_STRING([--enable-appfw],
 161                               [Builds with Tizen App framework libraries, off by default])],
 162               [enable_appfw=$enableval],
 163               [enable_appfw=no])
 164
 165 # Option to allow building with Tizen SDK 2.2
 166 AC_ARG_WITH([tizen-2-2-compatibility],
 167             [AC_HELP_STRING([--with-tizen-2-2-compatibility],
 168                             [Use Tizen SDK 2.2 compatibility])],
 169             [with_tizen_2_2_compatibility=$withval],
 170             [with_tizen_2_2_compatibility=no])
 171
 172 # Tizen Profile options
 173 AC_ARG_ENABLE([profile],
 174               [AC_HELP_STRING([--enable-profile=COMMON,MOBILE,WEARABLE,TV,IVI,UBUNTU],
 175                             [Select the variant of tizen])],
 176               [enable_profile=$enableval],
 177               [enable_profile=UBUNTU])
 178
 179 # Ensure valid profile selected
 180 if test "x$enable_profile" != "xCOMMON" -a "x$enable_profile" != "xMOBILE" -a "x$enable_profile" != "xWEARABLE" -a "x$enable_profile" != "xTV" -a "x$enable_profile" != "xIVI" -a "x$enable_profile" != "xUBUNTU"; then
 181   AC_MSG_ERROR([$enable_profile is an invalid profile])
 182 fi
 183
 184 AC_ARG_ENABLE(wayland,
 185               [  --enable-wayland       Build on Wayland],
 186               enable_wayland=yes,
 187               enable_wayland=no)
 188
 189 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_PROFILE_${enable_profile}"
 190 DALI_PROFILE_CFLAGS=" -DDALI_PROFILE_${enable_profile}"
 191 AM_CONDITIONAL([COMMON_PROFILE], [test x$enable_profile = xCOMMON])
 192 AM_CONDITIONAL([MOBILE_PROFILE], [test x$enable_profile = xMOBILE])
 193 AM_CONDITIONAL([WEARABLE_PROFILE], [test x$enable_profile = xWEARABLE])
 194 AM_CONDITIONAL([TV_PROFILE], [test x$enable_profile = xTV])
 195 AM_CONDITIONAL([IVI_PROFILE], [test x$enable_profile = xIVI])
 196 AM_CONDITIONAL([UBUNTU_PROFILE], [test x$enable_profile = xUBUNTU])
 197 AM_CONDITIONAL([WAYLAND], [test x$enable_wayland = xyes])
 198 AM_CONDITIONAL([USE_EFL], [test x$enable_efl = xyes])
 199 AM_CONDITIONAL([USE_APPFW], [test x$enable_appfw = xyes])
 200
 201 # Platforms with highp shader support can use vector based text
 202 AM_CONDITIONAL([ENABLE_VECTOR_BASED_TEXT_RENDERING], [test x$enable_profile = xUBUNTU])
 203
 204 AM_CONDITIONAL([ENABLE_NETWORK_LOGGING], [test x$enable_networklogging = xyes])
 205
 206 # Platforms should either enable features or remove them, they
 207 # should not disable features. This allows the developer to override
 208 # features through the command line.
 209
 210 if test "x$enable_profile" = "xCOMMON"; then
 211 PKG_CHECK_MODULES(OPENGLES20, glesv2 egl)
 212 fi
 213
 214 if test "x$enable_profile" = "xMOBILE"; then
 215 PKG_CHECK_MODULES(OPENGLES20, glesv2 egl)
 216 enable_assimp=no
 217 fi
 218
 219 if test "x$enable_profile" = "xLITE"; then
 220 PKG_CHECK_MODULES(OPENGLES20, gles20)
 221 fi
 222
 223 if test "x$enable_profile" = "xWEARABLE"; then
 224 PKG_CHECK_MODULES(OPENGLES20, glesv2)
 225 PKG_CHECK_MODULES(SCREENCONNECTORPROVIDER, screen_connector_provider)
 226 PKG_CHECK_MODULES(APPFW_WATCH, capi-appfw-watch-application,
 227    [watch_available=yes], [watch_available=no] )
 228 PKG_CHECK_MODULES(APPCORE_WATCH, appcore-watch)
 229 if test "x$watch_available" = "xyes"; then
 230   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DAPPCORE_WATCH_AVAILABLE"
 231 fi
 232 fi
 233
 234 if test "x$enable_profile" = "xTV"; then
 235 PKG_CHECK_MODULES(OPENGLES20, glesv2)
 236 fi
 237
 238 if test "x$enable_profile" = "xIVI"; then
 239 PKG_CHECK_MODULES(OPENGLES20, glesv2)
 240 fi
 241
 242 if test "x$enable_profile" = "xUBUNTU"; then
 243 PKG_CHECK_MODULES(OPENGLES20, glesv2 egl)
 244 else
 245
 246
 247
 248 PKG_CHECK_MODULES(DLOG, dlog)
 249 PKG_CHECK_MODULES(TTS, tts)
 250 PKG_CHECK_MODULES(VCONF, vconf)
 251
 252 if test "x$enable_efl" = "xyes"; then
 253 if test "x$with_tizen_2_2_compatibility" = "xno"; then
 254 PKG_CHECK_MODULES(CAPI_SYSTEM_INFO, capi-system-info)
 255 PKG_CHECK_MODULES(CAPI_SYSTEM_SENSOR, capi-system-sensor, [ capi_system_sensor_support=yes ], [ capi_system_sensor_support=no ] )
 256
 257 if test "x$capi_system_sensor_support" = "xyes"; then
 258   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DCAPI_SYSTEM_SENSOR_SUPPORT"
 259 fi
 260
 261 fi
 262 fi
 263
 264 fi # ubuntu profile test
 265
 266 if test "x$enable_appfw" = "xyes"; then
 267 PKG_CHECK_MODULES(CAPI_APPFW_APPLICATION, capi-appfw-application)
 268 PKG_CHECK_MODULES(CAPI_SYSTEM_SYSTEM_SETTINGS, capi-system-system-settings)
 269 fi
 270
 271 # Using EFL api's for  WAYLAND AND X11 to run on ecore mainloop
 272 if test "x$enable_efl" = "xyes"; then
 273 if test "x$enable_wayland" = "xyes"; then
 274 PKG_CHECK_MODULES(WAYLAND, [ecore-wayland egl wayland-egl wayland-client >= 1.2.0 xkbcommon libtbm],
 275                   [DALI_USE_ECORE_WAYLAND=1],
 276                   [DALI_USE_ECORE_WAYLAND=0])
 277
 278 else
 279 PKG_CHECK_MODULES(ECORE_X, [ecore-x],
 280                   [DALI_USE_ECORE_X11=1],
 281                   [DALI_USE_ECORE_X11=0])
 282 PKG_CHECK_MODULES(X11, [x11],
 283                   [DALI_USE_X11=1],
 284                   [DALI_USE_X11=0])
 285 fi
 286 fi
 287 # Using Wayland API directly  ( main loop agnostic, typically for running on libuv)
 288 #  wayland-extension-client include xdg-shell-client
 289 if test "x$enable_efl" = "xno"; then
 290 if test "x$enable_wayland" = "xyes"; then
 291 PKG_CHECK_MODULES(WAYLAND, [ egl wayland-egl wayland-client >= 1.2.0 xkbcommon libtbm],
 292                   [DALI_USE_WAYLAND=1],
 293                   [DALI_USE_WAYLAND=0])
 294 fi
 295 fi
 296
 297 # remove this when we update common repos
 298 # common profile currently does not have wayland extensions like xdg-shell
 299 if test "x$enable_wayland" = "xyes"; then
 300 if test "x$enable_profile" != "xCOMMON"; then
 301 PKG_CHECK_MODULES(WAYLAND_EXTENSION, xdg-shell-client text-client input-method-client)
 302 fi
 303 fi
 304 AM_CONDITIONAL([USE_ECORE_WAYLAND], [test "$DALI_USE_ECORE_WAYLAND" -eq 1])
 305
 306 if test x$DALI_DATA_RW_DIR != x; then
 307   dataReadWriteDir=$DALI_DATA_RW_DIR
 308 else
 309   dataReadWriteDir=${prefix}/share/dali/
 310 fi
 311
 312 if test x$DALI_DATA_RO_DIR != x; then
 313   dataReadOnlyDir=$DALI_DATA_RO_DIR
 314 else
 315   dataReadOnlyDir=${prefix}/share/dali/
 316 fi
 317
 318 if test x$TIZEN_PLATFORM_CONFIG_SUPPORTED != x; then
 319   tizenPlatformConfigSupported=$TIZEN_PLATFORM_CONFIG_SUPPORTED
 320 else
 321   tizenPlatformConfigSupported=0
 322 fi
 323
 324 if test x$FONT_CONFIGURATION_FILE != x; then
 325   fontConfigurationFile=$FONT_CONFIGURATION_FILE
 326 fi
 327
 328 AC_SUBST(dataReadWriteDir)
 329 AC_SUBST(dataReadOnlyDir)
 330 AC_SUBST(DALI_ADAPTOR_CFLAGS)
 331 AC_SUBST(DALI_PROFILE_CFLAGS)
 332 AC_SUBST(fontConfigurationFile)
 333 AC_SUBST(tizenPlatformConfigSupported)
 334
 335 # Specify the include directory for development headers
 336 #devincludepath=${includedir}/dali/internal
 337 devincludepath=${includedir}
 338 AC_SUBST(devincludepath)
 339
 340 AC_CONFIG_FILES([
 341  Makefile
 342  dali-adaptor.pc
 343  dali-adaptor-integration.pc
 344 ])
 345
 346 if test "x$freetype_bitmap_support" = "xyes"; then
 347 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DFREETYPE_BITMAP_SUPPORT"
 348 fi
 349
 350 AC_OUTPUT
 351
 352
 353 echo "
 354 Configuration
 355 -------------
 356   Prefix:                           $prefix
 357   Debug Build:                      $enable_debug
 358   Compile flags:                    $DALI_ADAPTOR_CFLAGS
 359   Freetype bitmap support (Emoji):  $freetype_bitmap_support
 360   Profile:                          $enable_profile
 361   Data Dir (Read/Write):            $dataReadWriteDir
 362   Data Dir (Read Only):             $dataReadOnlyDir
 363   Tizen SDK 2.2 compatibility:      $with_tizen_2_2_compatibility
 364   EldBus:                           $eldbus_available
 365   Shader Binary Cache:              $enable_shaderbincache
 366   Using LibUV mainloop (Node.JS)    $build_for_libuv
 367   Ecore Version At Least 1.13.0     $ecore_imf_1_13
 368   Network logging enabled:          $enable_networklogging
 369   Font config file:                 $fontConfigurationFile
 370   Building with EFL Libraries:      $enable_efl
 371   Using Tizen APP FW libraries:     $enable_appfw
 372   OpenGL ES version:                $enable_gles
 373   Tizen Platform Config supported   $tizenPlatformConfigSupported
 374 "
 375 # optional output of node.js source path if we're building with libuv
 376 if test "x$build_for_libuv" != "xno"; then
 377 echo "  LibUV header path         $with_libuv"
 378 fi