build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_C_STANDARD 99)
   5 SET(CMAKE_CXX_STANDARD 17)
   6 PROJECT(${name} CXX)
   7 SET(PKG_NAME ${name})
   8
   9 SET(name "dali2-adaptor")
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  19 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  20 OPTION(ENABLE_ATSPI          "Enable AT-SPI accessibility" ON)
  21
  22 # Include additional macros
  23 INCLUDE( common.cmake )
  24
  25 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  26   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  27   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  28   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  29 ELSE()
  30   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  31 ENDIF()
  32
  33 # from root/build/tizen, get back to root.
  34 # set the variable only if it's not set yet. it allows to access build script
  35 # from top-level directory
  36 IF( NOT ROOT_SRC_DIR )
  37   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  38 ENDIF()
  39 # Make sure the path is absolute
  40 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  41
  42 # API VERSION (Not DALi release version)
  43 SET(${name}_VERSION_MAJOR 2)
  44 SET(${name}_VERSION_MINOR 0)
  45 SET(${name}_VERSION_PATCH 0)
  46 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  47
  48 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  49
  50 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  51   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  52   FIND_PACKAGE( dali2-core REQUIRED)
  53 ENDIF()
  54
  55 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  56
  57 IF( UNIX )
  58   ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  59   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  60
  61   IF("${ARCH}" STREQUAL "arm")
  62     ADD_DEFINITIONS("-DTARGET")
  63   ENDIF("${ARCH}" STREQUAL "arm")
  64 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  65   IF(NOT DEFINED STATIC)
  66     ADD_DEFINITIONS( "-DBUILDING_DALI_ADAPTOR" )
  67   ENDIF()
  68
  69   ADD_DEFINITIONS( "-DDALI_ADAPTOR_COMPILATION" )
  70   ADD_DEFINITIONS( "-D_NSIG=65" )
  71 ENDIF()
  72
  73 # Deployment folder should come from spec file or command line:
  74 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  75 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  76
  77 # Set up the include dir
  78 SET( INCLUDE_DIR $ENV{includedir} )
  79 IF( NOT INCLUDE_DIR )
  80   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  81 ENDIF()
  82 IF( NOT INCLUDE_DIR )
  83   SET( INCLUDE_DIR ${PREFIX}/include )
  84 ENDIF()
  85
  86 # Set up the lib dir
  87 SET( LIB_DIR $ENV{libdir} )
  88 IF( NOT LIB_DIR )
  89   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  90 ENDIF()
  91 IF( NOT LIB_DIR )
  92   SET( LIB_DIR ${PREFIX}/lib )
  93 ENDIF()
  94
  95 # Set up the bin dir
  96 SET( BIN_DIR $ENV{bindir} )
  97 IF( NOT BIN_DIR )
  98   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
  99 ENDIF()
 100 IF( NOT BIN_DIR )
 101   SET( BIN_DIR ${PREFIX}/bin )
 102 ENDIF()
 103
 104 IF( UNIX )
 105   INCLUDE( deps-check.cmake )
 106 ENDIF()
 107
 108 IF( NOT DALI_ELDBUS_AVAILABLE )
 109   SET( ENABLE_ATSPI OFF )
 110 ENDIF()
 111
 112 # Set up compiler flags and warnings
 113 IF( UNIX )
 114   ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
 115 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 116   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) #
 117   ADD_COMPILE_OPTIONS( /FIextern-definitions.h )        # Adds missing definitions.
 118   ADD_COMPILE_OPTIONS( /FIpreprocessor-definitions.h )  #
 119   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 120   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 121 ENDIF()
 122
 123 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES
 124                  ${DEFINITIONS} )
 125
 126 # from root/build/tizen, get back to root
 127 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
 128
 129 # Make sure the path is absolute
 130 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 131
 132 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 133 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 134 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 135 SET(SOURCES "")
 136
 137 # Include list of modules
 138 INCLUDE( module-list.cmake )
 139
 140 # Include profile specific setup
 141 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 142
 143 IF ( ENABLE_ATSPI )
 144   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_bridge_src_files} )
 145 ELSE()
 146   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_dummy_src_files} )
 147 ENDIF()
 148
 149 IF( ENABLE_PKG_CONFIGURE )
 150   # Configure the pkg-config file
 151   # Requires the following variables to be setup:
 152   # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 153   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 154   SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor.pc )
 155   SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor-integration.pc )
 156   CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 157   CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 158 ENDIF()
 159
 160 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 161
 162 SET( THIRD_PARTY_WINDOWS_PLATFORM "" )
 163 IF( WIN32 )
 164   SET( THIRD_PARTY_WINDOWS_PLATFORM ${ROOT_SRC_DIR}/third-party/windows-platform )
 165 ENDIF()
 166
 167 SET( THIRD_PARTY_MACOS_PLATFORM "" )
 168 IF( APPLE )
 169   SET( THIRD_PARTY_MACOS_PLATFORM ${ROOT_SRC_DIR}/third-party/macos-platform )
 170 ENDIF()
 171
 172 INCLUDE_DIRECTORIES(
 173   ${ROOT_SRC_DIR}
 174   ${PROFILE_INCLUDE_DIRECTORIES}
 175   ${THIRD_PARTY_WINDOWS_PLATFORM}
 176   ${THIRD_PARTY_MACOS_PLATFORM}
 177   ${VCPKG_INCLUDE_DIR}
 178   ${INCLUDE_DIR}
 179 )
 180
 181 SET(LIBTYPE SHARED)
 182 IF(DEFINED STATIC)
 183   SET(LIBTYPE STATIC)
 184 ENDIF()
 185
 186 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 187
 188 IF( UNIX )
 189   # pthread required due to gcc issue
 190   FIND_LIBRARY( PTHREAD pthread )
 191   IF( PTHREAD AND NOT ANDROID_PROFILE )
 192     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 193   ENDIF()
 194 ENDIF()
 195
 196 TARGET_LINK_LIBRARIES( ${name}
 197                        ${DALI_LDFLAGS}
 198                        ${REQUIRED_LIBS}
 199                        ${OPTIONAL_LIBS}
 200                        ${COVERAGE}
 201 )
 202
 203 SET_TARGET_PROPERTIES( ${name}
 204   PROPERTIES
 205   VERSION ${DALI_ADAPTOR_VERSION}
 206   SOVERSION ${${name}_VERSION_MAJOR}
 207   CLEAN_DIRECT_OUPUT 1
 208 )
 209
 210 IF( INSTALL_CMAKE_MODULES )
 211   IF( ENABLE_DEBUG )
 212     SET( BIN_DIR "${BIN_DIR}/debug" )
 213     SET( LIB_DIR "${LIB_DIR}/debug" )
 214   ENDIF()
 215
 216   # Install the library files.
 217   INSTALL( TARGETS ${name}
 218     EXPORT ${name}-targets
 219     LIBRARY DESTINATION ${LIB_DIR}
 220     ARCHIVE DESTINATION ${LIB_DIR}
 221     RUNTIME DESTINATION ${BIN_DIR}
 222   )
 223
 224   # Install the cmake modules.
 225   INSTALL(
 226     EXPORT ${name}-targets
 227     NAMESPACE ${name}::
 228     FILE ${name}-targets.cmake
 229     DESTINATION share/${name}
 230   )
 231
 232   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 233     include(CMakeFindDependencyMacro)
 234     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 235   ")
 236   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 237
 238   # Install the pdb file.
 239   IF( ENABLE_DEBUG AND WIN32 )
 240     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 241   ENDIF()
 242 ELSE()
 243   # Install the library so file and symlinks
 244   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 245 ENDIF()
 246
 247 IF( ENABLE_PKG_CONFIGURE )
 248   # Install the pkg-config file
 249   INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 250   INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 251 ENDIF()
 252
 253 # macro for installing headers by replacing prefix. (TODO, investigate
 254 # if there is a CMAKE way of doing this automatically)
 255 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 256   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 257   FOREACH(HEADER ${${HEADER_LIST}})
 258     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 259     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 260     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 261   ENDFOREACH(HEADER)
 262 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 263
 264
 265 ########################################################################################
 266 # INSTALL:
 267 # Set deployment directories
 268 # Due to complicated adaptor deployment the install section is pretty much converted from
 269 # the automake counterpart.
 270 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 271 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 272 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 273 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 274 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 275 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 276 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 277 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 278 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 279
 280 # Android framework headers for Android build
 281 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 282
 283 # Install headers
 284 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 285 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 286 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 287 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 288 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 289
 290 # Install Android framework headers for Android build
 291 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 292
 293 # Install DOXY
 294 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 295 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 296 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 297 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 298
 299 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE AND NOT WINDOWS_PROFILE AND NOT MACOS_PROFILE )
 300   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 301   IF( NOT WAYLAND )
 302     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 303   ENDIF()
 304 ENDIF()
 305
 306 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 307 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 308 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 309 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 310
 311 IF( ANDROID_PROFILE )
 312   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 313   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 314 ELSEIF( UNIX )
 315   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 316   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 317 ENDIF()
 318
 319 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 320
 321 ########################################################################################
 322
 323 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 324 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 325 # target names duplication with other DALi modules.
 326 IF( ENABLE_COVERAGE )
 327   FIND_PROGRAM( LCOV_BIN "lcov" )
 328   IF( LCOV_BIN )
 329
 330     # Define custom rules for coverage
 331     SET(COVERAGE_DIR .cov)
 332     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 333
 334     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 335     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 336     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 337     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 338     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 339       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 340     ENDIF()
 341
 342     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 343
 344     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 345       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"*/third-party/*\" \"/usr/local/include/*\" -o dali.info )
 346
 347     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 348       DEPENDS cov_data )
 349
 350     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 351
 352     # Define custom rule for distclean
 353     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 354     ADD_CUSTOM_COMMAND(
 355           DEPENDS clean
 356           COMMENT "distribution clean"
 357           COMMAND find
 358           ARGS    .
 359           -not -name config.cmake -and \(
 360           -name tester.c -or
 361           -name Testing -or
 362           -name CMakeFiles -or
 363           -name doc -or
 364           -name cmake.depends -or
 365           -name cmake.check_depends -or
 366           -name CMakeCache.txt -or
 367           -name cmake.check_cache -or
 368           -name *.cmake -or
 369           -name Makefile -or
 370           -name core -or
 371           -name core.* -or
 372           -name gmon.out -or
 373           -name install_manifest.txt -or
 374           -name *.pc -or
 375           -name *.gcov -or
 376           -name *.gcno -or
 377           -name *.gcda -or
 378           -name *~ -or
 379           -name libdali*.so* \)
 380           | grep -v TC | xargs rm -rf
 381           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 382           VERBATIM
 383           )
 384
 385   ENDIF( LCOV_BIN )
 386 ENDIF()
 387
 388 IF( ENABLE_LINK_TEST )
 389   # Linker Test
 390   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 391   SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 392   SET( LINKER_TEST_SOURCES
 393     linker-test.cpp
 394   )
 395   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 396   MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 397   TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 398   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} )
 399   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 400 ENDIF()
 401
 402 # Configuration Messages
 403 MESSAGE( STATUS "Configuration:\n" )
 404 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 405 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 406 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 407 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 408 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 409 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 410 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 411 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 412 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 413 MESSAGE( STATUS "WebP:                             ${webp_available_ENABLED}")
 414 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 415 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORKLOGGING}")
 416 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 417 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 418 MESSAGE( STATUS "Use pkg configure:                ${ENABLE_PKG_CONFIGURE}" )
 419 MESSAGE( STATUS "Enable link test:                 ${ENABLE_LINK_TEST}" )
 420 MESSAGE( STATUS "Enable AT-SPI:                    ${ENABLE_ATSPI}" )
 421 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 422 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 423 MESSAGE( STATUS "Compile flags:                    ${CMAKE_C_FLAGS}")
 424 MESSAGE( STATUS "CMAKE_SYSROOT:                    ${CMAKE_SYSROOT}")
 425 MESSAGE( STATUS "CMAKE_SYSTEM_INCLUDE_PATH:        ${CMAKE_SYSTEM_INCLUDE_PATH}")
 426 MESSAGE( STATUS "CMAKE_SYSTEM_LIBRARY_PATH:        ${CMAKE_SYSTEM_LIBRARY_PATH}")
 427 IF( enable_feedback )
 428   ADD_SUBDIRECTORY( plugins )
 429 ENDIF()
 430
 431 CLEAN_ARG_CACHE()