meson.build

   1 project('npu-engine', ['c', 'cpp'],
   2   version: '2.4.3',
   3   license: ['Proprietary'],
   4   meson_version: '>=0.47.0',
   5   default_options: [
   6     'werror=true',
   7     'warning_level=1',
   8     'c_std=gnu89',
   9     'cpp_std=gnu++11',
  10   ]
  11 )
  12
  13 cc = meson.get_compiler('c')
  14 cpp = meson.get_compiler('cpp')
  15 sysroot = run_command(
  16     cpp.cmd_array() + ['-print-sysroot']
  17     ).stdout().split('\n')[0]
  18
  19 warning_c_flags = [
  20   '-Wmissing-prototypes',
  21   '-Wmissing-declarations',
  22   '-Wnested-externs',
  23   '-Waggregate-return',
  24   '-Wold-style-definition',
  25   '-Wdeclaration-after-statement'
  26 ]
  27
  28 warning_flags = [
  29   '-Wredundant-decls',
  30   '-Wwrite-strings',
  31   '-Wformat',
  32   '-Wformat-nonliteral',
  33   '-Wformat-security',
  34   '-Winit-self',
  35   '-Waddress',
  36   '-Wno-multichar',
  37   '-Wvla',
  38   '-Wpointer-arith',
  39   '-Wno-sign-compare',
  40   '-Wno-packed-not-aligned'
  41 ]
  42
  43 foreach extra_arg : warning_c_flags
  44   if cc.has_argument (extra_arg)
  45     add_project_arguments([extra_arg], language : 'c')
  46   endif
  47 endforeach
  48
  49 foreach extra_arg : warning_flags
  50   if cc.has_argument (extra_arg)
  51     add_project_arguments([extra_arg], language : 'c')
  52   endif
  53   if cpp.has_argument (extra_arg)
  54     add_project_arguments([extra_arg], language : 'cpp')
  55   endif
  56 endforeach
  57
  58 # Add version arguments
  59 version = meson.project_version().split('.')
  60 add_project_arguments('-DVER_NE_MAJOR=' + version[0], language: ['c', 'cpp'])
  61 add_project_arguments('-DVER_NE_MINOR=' + version[1], language: ['c', 'cpp'])
  62 add_project_arguments('-DVER_NE_EXTRA=' + version[2], language: ['c', 'cpp'])
  63
  64 # Install Paths
  65 ne_prefix = get_option('prefix')
  66 ne_libdir = join_paths(ne_prefix, get_option('libdir'))
  67 ne_bindir = join_paths(ne_prefix, get_option('bindir'))
  68 ne_includedir = join_paths(ne_prefix, get_option('includedir'))
  69 ne_inidir = get_option('sysconfdir')
  70 ne_datadir = join_paths(ne_prefix, join_paths(get_option('datadir'), 'npu-engine'))
  71
  72 add_project_arguments('-DNE_PREFIX="' + ne_prefix + '"', language: ['c', 'cpp'])
  73 add_project_arguments('-DNE_INIDIR="' + ne_inidir + '"', language: ['c', 'cpp'])
  74 add_project_arguments('-DNE_DATADIR="' + ne_datadir + '"', language: ['c', 'cpp'])
  75
  76 ne_common_inc = include_directories('include/common')
  77 ne_host_inc = include_directories('include/host')
  78
  79 # Check build platform
  80 target_platform = get_option('target_platform')
  81 if target_platform == 'tizen'
  82   add_project_arguments('-D__TIZEN__=1', language: ['c', 'cpp'])
  83 elif target_platform == 'fpga'
  84   ne_kernel_hdr = get_option('kernel_hdr_dir')
  85   ne_hernel_hdr_cflags = '-I' + ne_kernel_hdr
  86   if cpp.has_header('misc/trinity.h', args: ne_hernel_hdr_cflags)
  87     add_project_arguments(ne_hernel_hdr_cflags, language: ['c', 'cpp'])
  88     add_project_arguments('-D__FPGA__=1', language: ['c', 'cpp'])
  89   else
  90     if not cpp.has_header('misc/trinity.h')
  91       error('Failed to find \'misc/trintiy.h\'. Try to use the -Dkernel_hdr_dir option.')
  92     endif
  93   endif
  94 else
  95   # Default: debian distro
  96   add_project_arguments('-I' + ne_prefix + '/include', language: ['c', 'cpp'])
  97 endif
  98
  99 if get_option('enable_npu_emul')
 100   add_project_arguments('-DENABLE_EMUL', language: ['c', 'cpp'])
 101 endif
 102
 103 if get_option('enable_npu_cuse')
 104   add_project_arguments('-DENABLE_CUSE', language: ['c', 'cpp'])
 105 endif
 106
 107 if sysroot.startswith('/')
 108   sysroot_inc_cflags_template = '-I@0@/usr/include@1@'
 109   sysroot_inc = sysroot_inc_cflags_template.format(sysroot, '')
 110   add_project_arguments(sysroot_inc, language: ['c', 'cpp'])
 111   sysroot_inc_cflags_iniparser = sysroot_inc_cflags_template.format(sysroot,
 112       '/iniparser')
 113 else
 114   sysroot_inc_cflags_iniparser = '-I/usr/include/iniparser'
 115 endif
 116
 117
 118 libdl_dep = cc.find_library('dl') # DL library
 119 libm_dep = cc.find_library('m') # math library
 120 thread_dep = dependency('threads') # pthread library
 121 iniparser_dep = dependency('iniparser', required: false) # iniparser library
 122 if not iniparser_dep.found()
 123   libiniparser = cpp.find_library('iniparser')
 124   if libiniparser.found() and cpp.has_header('iniparser.h',\
 125       args : sysroot_inc_cflags_iniparser)
 126     iniparser_dep = declare_dependency(
 127       compile_args : sysroot_inc_cflags_iniparser,
 128       dependencies: libiniparser,
 129     )
 130   else
 131     error('Failed to resovle dependency on libiniparser')
 132   endif
 133 endif
 134 libdrm_dep = dependency('libdrm')
 135
 136 if get_option('enable_data_manip')
 137   add_project_arguments('-DENABLE_MANIP', language: ['c', 'cpp'])
 138 endif
 139 if get_option('enable_buffering')
 140   add_project_arguments('-DENABLE_BUFFERING', language: ['c', 'cpp'])
 141 endif
 142
 143 subdir('src')
 144 subdir('utils')
 145 subdir('plugins')
 146 subdir('tests')
 147
 148 # Set configuration to install .ini
 149 ne_install_conf = configuration_data()
 150
 151 ne_install_conf.set('VERSION', meson.project_version())
 152 ne_install_conf.set('PREFIX', ne_prefix)
 153 ne_install_conf.set('EXEC_PREFIX', ne_bindir)
 154 ne_install_conf.set('LIB_INSTALL_DIR', ne_libdir)
 155 ne_install_conf.set('INCLUDE_INSTALL_DIR', ne_includedir)
 156
 157 ne_install_conf.set('RESV_MEM_SIZE', get_option('resv_mem_size'))
 158 ne_install_conf.set('NUM_THREADS', get_option('num_threads'))
 159 ne_install_conf.set('PREFIX_SHARE', ne_prefix + get_option('prefix_share'))
 160 ne_install_conf.set('PREFIX_PROFILE', get_option('prefix_profile'))
 161 ne_install_conf.set('LOG_DIR', get_option('log_dir'))
 162 ne_install_conf.set('LOG_LEVEL', get_option('log_level'))
 163 ne_install_conf.set('MUTE_STDOUT', get_option('mute_stdout'))
 164
 165 # Install .ini
 166 configure_file(input: 'npu-engine.ini.in', output: 'npu-engine.ini',
 167   install_dir: ne_inidir,
 168   configuration: ne_install_conf)
 169
 170 # Install .pc
 171 configure_file(input: 'npu-engine.pc.in', output: 'npu-engine.pc',
 172   install_dir: join_paths(ne_libdir, 'pkgconfig'),
 173   configuration: ne_install_conf)
 174
 175 # Install headers
 176 ne_install_headers = [
 177   'include/common/npubinfmt.h',
 178   'include/common/typedef.h',
 179   'include/host/libnpuhost.h',
 180 ]
 181
 182 install_headers(ne_install_headers, subdir: 'npu-engine')