arch/i386/cpu/start16.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002, 2003 Omicron Ceti AB, Daniel Engström <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <asm/global_data.h>
  26
  27 #define BOOT_SEG        0xffff0000      /* linear segment of boot code */
  28 #define a32             .byte 0x67;
  29 #define o32             .byte 0x66;
  30
  31 .section .start16, "ax"
  32 .code16
  33 .globl start16
  34 start16:
  35         /* Set the Cold Boot / Hard Reset flag */
  36         movl    $GD_FLG_COLD_BOOT, %ebx
  37
  38         /*
  39          * First we let the BSP do some early initialization
  40          * this code have to map the flash to its final position
  41          */
  42         jmp     board_init16
  43 .globl board_init16_ret
  44 board_init16_ret:
  45
  46         /* Turn of cache (this might require a 486-class CPU) */
  47         movl    %cr0, %eax
  48         orl     $0x60000000, %eax
  49         movl    %eax, %cr0
  50         wbinvd
  51
  52         /* load the temporary Global Descriptor Table */
  53 o32 cs  lidt    idt_ptr
  54 o32 cs  lgdt    gdt_ptr
  55
  56         /* Now, we enter protected mode */
  57         movl    %cr0, %eax
  58         orl     $1, %eax
  59         movl    %eax, %cr0
  60
  61         /* Flush the prefetch queue */
  62         jmp     ff
  63 ff:
  64         /* Finally jump to the 32bit initialization code */
  65         movw    $code32start, %ax
  66         movw    %ax, %bp
  67 o32 cs  ljmp    *(%bp)
  68
  69         /* 48-bit far pointer */
  70 code32start:
  71         .long   _start          /* offset */
  72         .word   0x10            /* segment */
  73
  74 idt_ptr:
  75         .word   0               /* limit */
  76         .long   0               /* base */
  77
  78 /*
  79  * The following Global Descriptor Table is just enough to get us into
  80  * 'Flat Protected Mode' - It will be discarded as soon as the final
  81  * GDT is setup in a safe location in RAM
  82  */
  83 gdt_ptr:
  84         .word   0x20            /* limit (32 bytes = 4 GDT entries) */
  85         .long   BOOT_SEG + gdt  /* base */
  86
  87         /* The GDT table ...
  88          *
  89          *       Selector       Type
  90          *       0x00           NULL
  91          *       0x08           Unused
  92          *       0x10           32bit code
  93          *       0x18           32bit data/stack
  94          */
  95
  96 gdt:
  97         .word   0, 0, 0, 0      /* NULL  */
  98         .word   0, 0, 0, 0      /* unused */
  99
 100         .word   0xFFFF          /* 4Gb - (0x100000*0x1000 = 4Gb) */
 101         .word   0               /* base address = 0 */
 102         .word   0x9B00          /* code read/exec */
 103         .word   0x00CF          /* granularity = 4096, 386 (+5th nibble of limit) */
 104
 105         .word   0xFFFF          /* 4Gb - (0x100000*0x1000 = 4Gb) */
 106         .word   0x0             /* base address = 0 */
 107         .word   0x9300          /* data read/write */
 108         .word   0x00CF          /* granularity = 4096, 386 (+5th nibble of limit) */