arch/i386/cpu/start.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002  Omicron Ceti AB, Daniel Engstr�m <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/global_data.h>
  29
  30
  31 .section .text
  32 .code32
  33 .globl _start
  34 .type _start, @function
  35 .globl _i386boot_start
  36 _i386boot_start:
  37         /*
  38          * This is the fail safe 32-bit bootstrap entry point. The
  39          * following code is not executed from a cold-reset (actually, a
  40          * lot of it is, but from real-mode after cold reset. It is
  41          * repeated here to put the board into a state as close to cold
  42          * reset as necessary)
  43          */
  44         cli
  45         cld
  46
  47         /* Turn of cache (this might require a 486-class CPU) */
  48         movl    %cr0, %eax
  49         orl     $0x60000000, %eax
  50         movl    %eax, %cr0
  51         wbinvd
  52
  53         /* Tell 32-bit code it is being entered from an in-RAM copy */
  54         movw    $GD_FLG_WARM_BOOT, %bx
  55 _start:
  56         /* This is the 32-bit cold-reset entry point */
  57
  58         movl    $0x18, %eax     /* Load our segement registes, the
  59                                  * gdt have already been loaded by start16.S */
  60         movw    %ax, %fs
  61         movw    %ax, %ds
  62         movw    %ax, %gs
  63         movw    %ax, %es
  64         movw    %ax, %ss
  65
  66         /* Clear the interupt vectors */
  67         lidt    blank_idt_ptr
  68
  69         /* Skip low-level initialization if not starting from cold-reset */
  70         movl    %ebx, %ecx
  71         andl    $GD_FLG_COLD_BOOT, %ecx
  72         jz      skip_mem_init
  73
  74         /* Early platform init (setup gpio, etc ) */
  75         jmp     early_board_init
  76 .globl early_board_init_ret
  77 early_board_init_ret:
  78
  79         /* size memory */
  80         jmp     mem_init
  81 .globl mem_init_ret
  82 mem_init_ret:
  83
  84 skip_mem_init:
  85         /* fetch memory size (into %eax) */
  86         jmp     get_mem_size
  87 .globl get_mem_size_ret
  88 get_mem_size_ret:
  89
  90 #if CONFIG_SYS_SDRAM_ECC_ENABLE
  91         /* Skip ECC initialization if not starting from cold-reset */
  92         movl    %ebx, %ecx
  93         andl    $GD_FLG_COLD_BOOT, %ecx
  94         jz      init_ecc_ret
  95         jmp     init_ecc
  96
  97 .globl init_ecc_ret
  98 init_ecc_ret:
  99 #endif
 100
 101         /* Check we have enough memory for stack */
 102         movl    $CONFIG_SYS_STACK_SIZE, %ecx
 103         cmpl    %ecx, %eax
 104         jb      die
 105 mem_ok:
 106         /* Set stack pointer to upper memory limit*/
 107         movl    %eax, %esp
 108
 109         /* Test the stack */
 110         pushl   $0
 111         popl    %ecx
 112         cmpl    $0, %ecx
 113         jne     die
 114         push    $0x55aa55aa
 115         popl    %ecx
 116         cmpl    $0x55aa55aa, %ecx
 117         jne     die
 118
 119         wbinvd
 120
 121         /* Determine our load offset */
 122         call    1f
 123 1:      popl    %ecx
 124         subl    $1b, %ecx
 125
 126         /* Set the upper memory limit parameter */
 127         subl    $CONFIG_SYS_STACK_SIZE, %eax
 128
 129         /* Reserve space for global data */
 130         subl    $(GD_SIZE * 4), %eax
 131
 132         /* %eax points to the global data structure */
 133         movl    %esp, (GD_RAM_SIZE * 4)(%eax)
 134         movl    %ebx, (GD_FLAGS * 4)(%eax)
 135         movl    %ecx, (GD_LOAD_OFF * 4)(%eax)
 136
 137         call    board_init_f    /* Enter, U-boot! */
 138
 139         /* indicate (lack of) progress */
 140         movw    $0x85, %ax
 141 die:    hlt
 142         jmp     die
 143         hlt
 144
 145 blank_idt_ptr:
 146         .word   0               /* limit */
 147         .long   0               /* base */