arch/arm/cpu/arm926ejs/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *  Copyright (c) 2010  Albert Aribaud <albert.aribaud@free.fr>
  14  *
  15  * See file CREDITS for list of people who contributed to this
  16  * project.
  17  *
  18  * This program is free software; you can redistribute it and/or
  19  * modify it under the terms of the GNU General Public License as
  20  * published by the Free Software Foundation; either version 2 of
  21  * the License, or (at your option) any later version.
  22  *
  23  * This program is distributed in the hope that it will be useful,
  24  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  25  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26  * GNU General Public License for more details.
  27  *
  28  * You should have received a copy of the GNU General Public License
  29  * along with this program; if not, write to the Free Software
  30  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  31  * MA 02111-1307 USA
  32  */
  33
  34 #include <asm-offsets.h>
  35 #include <config.h>
  36 #include <common.h>
  37 #include <version.h>
  38
  39 #if defined(CONFIG_OMAP1610)
  40 #include <./configs/omap1510.h>
  41 #elif defined(CONFIG_OMAP730)
  42 #include <./configs/omap730.h>
  43 #endif
  44
  45 /*
  46  *************************************************************************
  47  *
  48  * Jump vector table as in table 3.1 in [1]
  49  *
  50  *************************************************************************
  51  */
  52
  53
  54 .globl cpu_spec
  55 .globl MMU_Init
  56 .globl _start
  57 _start:
  58         b       reset
  59 #ifdef CONFIG_PRELOADER
  60 /* No exception handlers in preloader */
  61         ldr     pc, _hang
  62         ldr     pc, _hang
  63         ldr     pc, _hang
  64         ldr     pc, _hang
  65         ldr     pc, _hang
  66         ldr     pc, _hang
  67         ldr     pc, _hang
  68
  69 _hang:
  70         .word   do_hang
  71 /* pad to 64 byte boundary */
  72         .word   0x12345678
  73         .word   0x12345678
  74         .word   0x12345678
  75         .word   0x12345678
  76         .word   0x12345678
  77         .word   0x12345678
  78         .word   0x12345678
  79 #else
  80         ldr     pc, _undefined_instruction
  81         ldr     pc, _software_interrupt
  82         ldr     pc, _prefetch_abort
  83         ldr     pc, _data_abort
  84         ldr     pc, _not_used
  85         ldr     pc, _irq
  86         ldr     pc, _fiq
  87
  88 _undefined_instruction:
  89         .word undefined_instruction
  90 _software_interrupt:
  91         .word software_interrupt
  92 _prefetch_abort:
  93         .word prefetch_abort
  94 _data_abort:
  95         .word data_abort
  96 _not_used:
  97         .word not_used
  98 _irq:
  99         .word irq
 100 _fiq:
 101         .word fiq
 102
 103 #endif  /* CONFIG_PRELOADER */
 104         .balignl 16,0xdeadbeef
 105
 106
 107 /*
 108  *************************************************************************
 109  *
 110  * Startup Code (reset vector)
 111  *
 112  * do important init only if we don't start from memory!
 113  * setup Memory and board specific bits prior to relocation.
 114  * relocate armboot to ram
 115  * setup stack
 116  *
 117  *************************************************************************
 118  */
 119
 120 .globl _TEXT_BASE
 121 _TEXT_BASE:
 122         .word   CONFIG_SYS_TEXT_BASE
 123
 124 /*
 125  * These are defined in the board-specific linker script.
 126  * Subtracting _start from them lets the linker put their
 127  * relative position in the executable instead of leaving
 128  * them null.
 129  */
 130 .globl _bss_start_ofs
 131 _bss_start_ofs:
 132         .word __bss_start - _start
 133
 134 .globl _bss_end_ofs
 135 _bss_end_ofs:
 136         .word _end - _start
 137
 138 #ifdef CONFIG_USE_IRQ
 139 /* IRQ stack memory (calculated at run-time) */
 140 .globl IRQ_STACK_START
 141 IRQ_STACK_START:
 142         .word   0x0badc0de
 143
 144 /* IRQ stack memory (calculated at run-time) */
 145 .globl FIQ_STACK_START
 146 FIQ_STACK_START:
 147         .word 0x0badc0de
 148 #endif
 149
 150 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 151 .globl IRQ_STACK_START_IN
 152 IRQ_STACK_START_IN:
 153         .word   0x0badc0de
 154
 155 /*
 156  * the actual reset code
 157  */
 158
 159 reset:
 160         /*
 161          * set the cpu to SVC32 mode
 162          */
 163 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 164 #ifdef SPRD_EVM_TAG_ON
 165         ldr r0,=SPRD_EVM_ADDR_START
 166         ldr r1,=0x87003004
 167         ldr r2,[r1]
 168         str r2,[r0]
 169 #endif
 170         mrs     r0,cpsr
 171         bic     r0,r0,#0x1f
 172         orr     r0,r0,#0xd3
 173         msr     cpsr,r0
 174 #endif
 175
 176 #if 0
 177         ldr     r1, =0x3fffffff
 178 time:   subs    r1,r1,#0x1
 179         bne     time
 180 #endif
 181
 182         /*
 183          * we do sys-critical inits only at reboot,
 184          * not when booting from ram!
 185          */
 186 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 187         bl      cpu_init_crit
 188         bl cpu_spec
 189         @bl MMU_Init
 190 #endif
 191
 192 /* Set stackpointer in internal RAM to call board_init_f */
 193 call_board_init_f:
 194         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 195         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 196 #ifndef CONFIG_NAND_SPL
 197         ldr     r0,=0x00000000
 198         bl      board_init_f
 199 #else
 200         ldr r0, =(CONFIG_SYS_INIT_SP_ADDR)
 201         ldr r1, =0x00000000
 202         ldr r2, =(CONFIG_SYS_TEXT_BASE)
 203         bl relocate_code
 204 #endif
 205
 206 /*------------------------------------------------------------------------------*/
 207
 208 /*
 209  * void relocate_code (addr_sp, gd, addr_moni)
 210  *
 211  * This "function" does not return, instead it continues in RAM
 212  * after relocating the monitor code.
 213  *
 214  */
 215         .globl  relocate_code
 216 relocate_code:
 217         mov     r4, r0  /* save addr_sp */
 218         mov     r5, r1  /* save addr of gd */
 219         mov     r6, r2  /* save addr of destination */
 220
 221         /* Set up the stack                                                 */
 222 stack_setup:
 223         mov     sp, r4
 224
 225         adr     r0, _start
 226         ldr r6, =(CONFIG_SYS_TEXT_BASE)
 227         cmp     r0, r6
 228         mov r9, #0x0
 229         beq     clear_bss               /* skip relocation */
 230         mov     r1, r6                  /* r1 <- scratch for copy loop */
 231         ldr     r2, _TEXT_BASE
 232         ldr     r3, _bss_start_ofs
 233         add     r2, r0, r3              /* r2 <- source end address         */
 234
 235 copy_loop:
 236         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 237         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 238         cmp     r0, r2                  /* until source end address [r2]    */
 239         blo     copy_loop
 240
 241 #ifndef CONFIG_PRELOADER
 242         /*
 243          * fix .rel.dyn relocations
 244          */
 245         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 246         sub     r9, r6, r0              /* r9 <- relocation offset */
 247         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 248         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 249         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 250         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 251         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 252         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 253 fixloop:
 254         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 255         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 256         ldr     r1, [r2, #4]
 257         and     r7, r1, #0xff
 258         cmp     r7, #23                 /* relative fixup? */
 259         beq     fixrel
 260         cmp     r7, #2                  /* absolute fixup? */
 261         beq     fixabs
 262         /* ignore unknown type of fixup */
 263         b       fixnext
 264 fixabs:
 265         /* absolute fix: set location to (offset) symbol value */
 266         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 267         add     r1, r10, r1             /* r1 <- address of symbol in table */
 268         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 269         add     r1, r1, r9              /* r1 <- relocated sym addr */
 270         b       fixnext
 271 fixrel:
 272         /* relative fix: increase location by offset */
 273         ldr     r1, [r0]
 274         add     r1, r1, r9
 275 fixnext:
 276         str     r1, [r0]
 277         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 278         cmp     r2, r3
 279         blo     fixloop
 280 #endif
 281
 282 clear_bss:
 283 #ifndef CONFIG_PRELOADER
 284         ldr     r0, _bss_start_ofs
 285         ldr     r1, _bss_end_ofs
 286         ldr     r3, _TEXT_BASE          /* Text base */
 287         mov     r4, r6                  /* reloc addr */
 288         add     r0, r0, r4
 289         add     r1, r1, r4
 290         mov     r2, #0x00000000         /* clear                            */
 291
 292 clbss_l:str     r2, [r0]                /* clear loop...                    */
 293         add     r0, r0, #4
 294         cmp     r0, r1
 295         bne     clbss_l
 296
 297         bl coloured_LED_init
 298         bl red_LED_on
 299 #endif
 300
 301 /*
 302  * We are done. Do not return, instead branch to second part of board
 303  * initialization, now running from RAM.
 304  */
 305 #ifdef CONFIG_NAND_SPL
 306         ldr     r0, _nand_boot_ofs
 307         mov     pc, r0
 308
 309 _nand_boot_ofs:
 310         .word nand_boot
 311 #else
 312         ldr     r0, _board_init_r_ofs
 313         adr     r1, _start
 314         add     lr, r0, r1
 315         add     lr, lr, r9
 316         /* setup parameters for board_init_r */
 317         mov     r0, r5          /* gd_t */
 318         mov     r1, r6          /* dest_addr */
 319         /* jump to it ... */
 320         mov     pc, lr
 321
 322 _board_init_r_ofs:
 323         .word board_init_r - _start
 324 #endif
 325
 326 _rel_dyn_start_ofs:
 327         .word __rel_dyn_start - _start
 328 _rel_dyn_end_ofs:
 329         .word __rel_dyn_end - _start
 330 _dynsym_start_ofs:
 331         .word __dynsym_start - _start
 332
 333 /*
 334  *************************************************************************
 335  *
 336  * CPU_init_critical registers
 337  *
 338  * setup important registers
 339  * setup memory timing
 340  *
 341  *************************************************************************
 342  */
 343 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 344 cpu_init_crit:
 345         /*
 346          * flush v4 I/D caches
 347          */
 348         mov     r0, #0
 349         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 350         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 351
 352         /*
 353          * disable MMU stuff and caches
 354          */
 355         mrc     p15, 0, r0, c1, c0, 0
 356         bic     r0, r0, #0x00002300     /* clear bits 13, 9:8 (--V- --RS) */
 357         bic     r0, r0, #0x00000087     /* clear bits 7, 2:0 (B--- -CAM) */
 358         ;orr    r0, r0, #0x00000002     /* set bit 2 (A) Align */
 359         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache */
 360         mcr     p15, 0, r0, c1, c0, 0
 361
 362         /*
 363          * Go setup Memory and board specific bits prior to relocation.
 364          */
 365         mov     ip, lr          /* perserve link reg across call */
 366 @       bl      lowlevel_init   /* go setup pll,mux,memory */
 367         mov     lr, ip          /* restore link */
 368         mov     pc, lr          /* back to my caller */
 369 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 370
 371 #ifndef CONFIG_PRELOADER
 372 /*
 373  *************************************************************************
 374  *
 375  * Interrupt handling
 376  *
 377  *************************************************************************
 378  */
 379
 380 @
 381 @ IRQ stack frame.
 382 @
 383 #define S_FRAME_SIZE    72
 384
 385 #define S_OLD_R0        68
 386 #define S_PSR           64
 387 #define S_PC            60
 388 #define S_LR            56
 389 #define S_SP            52
 390
 391 #define S_IP            48
 392 #define S_FP            44
 393 #define S_R10           40
 394 #define S_R9            36
 395 #define S_R8            32
 396 #define S_R7            28
 397 #define S_R6            24
 398 #define S_R5            20
 399 #define S_R4            16
 400 #define S_R3            12
 401 #define S_R2            8
 402 #define S_R1            4
 403 #define S_R0            0
 404
 405 #define MODE_SVC 0x13
 406 #define I_BIT    0x80
 407
 408 /*
 409  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 410  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 411  */
 412
 413         .macro  bad_save_user_regs
 414         @ carve out a frame on current user stack
 415         sub     sp, sp, #S_FRAME_SIZE
 416         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 417         ldr     r2, IRQ_STACK_START_IN
 418         @ get values for "aborted" pc and cpsr (into parm regs)
 419         ldmia   r2, {r2 - r3}
 420         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 421         add     r5, sp, #S_SP
 422         mov     r1, lr
 423         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 424         mov     r0, sp          @ save current stack into r0 (param register)
 425         .endm
 426
 427         .macro  irq_save_user_regs
 428         sub     sp, sp, #S_FRAME_SIZE
 429         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 430         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 431         add     r8, sp, #S_PC
 432         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 433         str     lr, [r8, #0]            @ Save calling PC
 434         mrs     r6, spsr
 435         str     r6, [r8, #4]            @ Save CPSR
 436         str     r0, [r8, #8]            @ Save OLD_R0
 437         mov     r0, sp
 438         .endm
 439
 440         .macro  irq_restore_user_regs
 441         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 442         mov     r0, r0
 443         ldr     lr, [sp, #S_PC]                 @ Get PC
 444         add     sp, sp, #S_FRAME_SIZE
 445         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 446         .endm
 447
 448         .macro get_bad_stack
 449         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 450
 451         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 452         mrs     lr, spsr        @ get the spsr
 453         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 454         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 455         @ msr   spsr_c, r13
 456         msr     spsr, r13       @ switch modes, make sure moves will execute
 457         mov     lr, pc          @ capture return pc
 458         movs    pc, lr          @ jump to next instruction & switch modes.
 459         .endm
 460
 461         .macro get_irq_stack                    @ setup IRQ stack
 462         ldr     sp, IRQ_STACK_START
 463         .endm
 464
 465         .macro get_fiq_stack                    @ setup FIQ stack
 466         ldr     sp, FIQ_STACK_START
 467         .endm
 468 #endif  /* CONFIG_PRELOADER */
 469
 470 /*
 471  * exception handlers
 472  */
 473 #ifdef CONFIG_PRELOADER
 474         .align  5
 475 do_hang:
 476         ldr     sp, _TEXT_BASE                  /* switch to abort stack */
 477 1:
 478         bl      1b                              /* hang and never return */
 479 #else   /* !CONFIG_PRELOADER */
 480         .align  5
 481 undefined_instruction:
 482         get_bad_stack
 483         bad_save_user_regs
 484         bl      do_undefined_instruction
 485
 486         .align  5
 487 software_interrupt:
 488         get_bad_stack
 489         bad_save_user_regs
 490         bl      do_software_interrupt
 491
 492         .align  5
 493 prefetch_abort:
 494         get_bad_stack
 495         bad_save_user_regs
 496         bl      do_prefetch_abort
 497
 498         .align  5
 499 data_abort:
 500         get_bad_stack
 501         bad_save_user_regs
 502         bl      do_data_abort
 503
 504         .align  5
 505 not_used:
 506         get_bad_stack
 507         bad_save_user_regs
 508         bl      do_not_used
 509
 510 #ifdef CONFIG_USE_IRQ
 511
 512         .align  5
 513 irq:
 514         get_irq_stack
 515         irq_save_user_regs
 516         bl      do_irq
 517         irq_restore_user_regs
 518
 519         .align  5
 520 fiq:
 521         get_fiq_stack
 522         /* someone ought to write a more effiction fiq_save_user_regs */
 523         irq_save_user_regs
 524         bl      do_fiq
 525         irq_restore_user_regs
 526
 527 #else
 528
 529         .align  5
 530 irq:
 531         get_bad_stack
 532         bad_save_user_regs
 533         bl      do_irq
 534
 535         .align  5
 536 fiq:
 537         get_bad_stack
 538         bad_save_user_regs
 539         bl      do_fiq
 540
 541 #endif
 542 #endif  /* CONFIG_PRELOADER */