acinclude.m4

   1 # ===========================================================================
   2 #          http://www.nongnu.org/autoconf-archive/ax_define_dir.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro sets VARNAME to the expansion of the DIR variable, taking
  12 #   care of fixing up ${prefix} and such.
  13 #
  14 #   VARNAME is then offered as both an output variable and a C preprocessor
  15 #   symbol.
  16 #
  17 #   Example:
  18 #
  19 #      AX_DEFINE_DIR([DATADIR], [datadir], [Where data are placed to.])
  20 #
  21 # LICENSE
  22 #
  23 #   Copyright (c) 2008 Stepan Kasal <kasal@ucw.cz>
  24 #   Copyright (c) 2008 Andreas Schwab <schwab@suse.de>
  25 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  26 #   Copyright (c) 2008 Alexandre Oliva
  27 #
  28 #   Copying and distribution of this file, with or without modification, are
  29 #   permitted in any medium without royalty provided the copyright notice
  30 #   and this notice are preserved.
  31
  32 AU_ALIAS([AC_DEFINE_DIR], [AX_DEFINE_DIR])
  33 AC_DEFUN([AX_DEFINE_DIR], [
  34   prefix_NONE=
  35   exec_prefix_NONE=
  36   test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
  37   test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
  38 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
  39 dnl refers to ${prefix}.  Thus we have to use `eval' twice.
  40   eval ax_define_dir="\"[$]$2\""
  41   eval ax_define_dir="\"$ax_define_dir\""
  42   AC_SUBST($1, "$ax_define_dir")
  43   AC_DEFINE_UNQUOTED($1, "$ax_define_dir", [$3])
  44   test "$prefix_NONE" && prefix=NONE
  45   test "$exec_prefix_NONE" && exec_prefix=NONE
  46 ])