configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT(harfbuzz, 0.3, [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz])
   3 AC_CONFIG_SRCDIR([harfbuzz.pc.in])
   4 AC_CONFIG_HEADERS([config.h])
   5 AM_INIT_AUTOMAKE([1.9.6 gnu dist-bzip2 no-dist-gzip -Wall no-define])
   6 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   7
   8 AC_LIBTOOL_WIN32_DLL
   9 AC_PROG_LIBTOOL dnl ([1.4]) Don't remove!
  10
  11 AC_PROG_CC
  12 AM_PROG_CC_C_O
  13 AC_PROG_CXX
  14
  15 AC_CHECK_FUNCS(mprotect sysconf getpagesize)
  16 AC_CHECK_HEADERS(unistd.h sys/mman.h)
  17
  18 # Make sure we don't link to libstdc++
  19 if test "x$GCC" = "xyes"; then
  20         CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
  21 fi
  22
  23 dnl ==========================================================================
  24
  25 PKG_CHECK_MODULES(GLIB, glib-2.0, have_glib=true, have_glib=false)
  26 if $have_glib; then
  27         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
  28 fi
  29 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
  30
  31 PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
  32         AC_CHECK_PROG([have_icu], [icu-config], [have_icu], [true], [false], [$PATH])
  33         if $have_icu; then
  34                 icu_cflags=`icu-config --cppflags`
  35                 icu_libs=`icu-config --ldflags-libsonly`
  36                 AC_SUBST(ICU_CFLAGS, [$icu_cflags])
  37                 AC_SUBST(ICU_LIBS, [$icu_libs])
  38         fi
  39 ])
  40 if $have_icu; then
  41         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
  42 fi
  43 AM_CONDITIONAL(HAVE_ICU, $have_icu)
  44
  45 PKG_CHECK_MODULES(GRAPHITE, silgraphite, have_graphite=true, have_graphite=false)
  46 if $have_graphite; then
  47     AC_DEFINE(HAVE_GRAPHITE, 1, [Have Graphite library])
  48 fi
  49 AM_CONDITIONAL(HAVE_GRAPHITE, $have_graphite)
  50
  51 PKG_CHECK_MODULES(FREETYPE, freetype2, have_freetype=true, have_freetype=false)
  52 if $have_freetype; then
  53         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
  54         _save_libs="$LIBS"
  55         _save_cflags="$CFLAGS"
  56         LIBS="$LIBS $FREETYPE_LIBS"
  57         CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
  58         AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
  59         LIBS="$_save_libs"
  60         CFLAGS="$_save_cflags"
  61 fi
  62 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
  63
  64 dnl ==========================================================================
  65
  66 AC_CONFIG_FILES([
  67 harfbuzz.pc
  68 Makefile
  69 src/Makefile
  70 ])
  71
  72 AC_OUTPUT