configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([harfbuzz],
   3         [0.5.0],
   4         [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
   5         [harfbuzz],
   6         [http://freedesktop.org/wiki/Software/harfbuzz])
   7
   8 AC_CONFIG_SRCDIR([harfbuzz.pc.in])
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AM_PROG_CC_C_O
  17 AC_PROG_CXX
  18
  19 # Initialize libtool
  20 LT_PREREQ([2.2])
  21 LT_INIT([disable-static])
  22
  23 # Version
  24 m4_define(version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  25 HB_VERSION_MAJOR=m4_argn(1,version_triplet)
  26 HB_VERSION_MINOR=m4_argn(2,version_triplet)
  27 HB_VERSION_MICRO=m4_argn(3,version_triplet)
  28 HB_VERSION=AC_PACKAGE_VERSION
  29
  30 AC_SUBST(HB_VERSION_MAJOR)
  31 AC_SUBST(HB_VERSION_MINOR)
  32 AC_SUBST(HB_VERSION_MICRO)
  33 AC_SUBST(HB_VERSION)
  34
  35
  36 # Functions and headers
  37 AC_CHECK_FUNCS(mprotect sysconf getpagesize)
  38 AC_CHECK_HEADERS(unistd.h sys/mman.h)
  39
  40 # Compiler flags
  41 AC_CANONICAL_HOST
  42 if test "x$GCC" = "xyes"; then
  43
  44         # Make sure we don't link to libstdc++
  45         CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
  46
  47         case "$host" in
  48                 arm-*-*)
  49                         # Request byte alignment on arm
  50                         CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
  51                 ;;
  52         esac
  53 fi
  54
  55 dnl ==========================================================================
  56
  57 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
  58 if $have_glib; then
  59         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
  60 fi
  61 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
  62
  63 dnl ==========================================================================
  64
  65 PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
  66 if $have_cairo; then
  67         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
  68 fi
  69 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
  70
  71 PKG_CHECK_MODULES(CAIRO_PNG, cairo-png, have_cairo_png=true, have_cairo_png=false)
  72 if $have_cairo_png; then
  73         AC_DEFINE(HAVE_CAIRO_PNG, 1, [Have cairo-png support in cairo graphics library])
  74 fi
  75 AM_CONDITIONAL(HAVE_CAIRO_PNG, $have_cairo_png)
  76
  77 PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
  78 if $have_cairo_ft; then
  79         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
  80 fi
  81 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
  82
  83 dnl ==========================================================================
  84
  85 PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
  86         AC_CHECK_PROG([have_icu], [icu-config], [true], [false])
  87         if $have_icu; then
  88                 icu_cflags=`icu-config --cppflags`
  89                 icu_libs=`icu-config --ldflags-libsonly`
  90                 AC_SUBST(ICU_CFLAGS, [$icu_cflags])
  91                 AC_SUBST(ICU_LIBS, [$icu_libs])
  92         fi
  93 ])
  94 if $have_icu; then
  95         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
  96 fi
  97 AM_CONDITIONAL(HAVE_ICU, $have_icu)
  98
  99 dnl ==========================================================================
 100
 101 PKG_CHECK_MODULES(FREETYPE, freetype2, have_freetype=true, have_freetype=false)
 102 if $have_freetype; then
 103         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 104         _save_libs="$LIBS"
 105         _save_cflags="$CFLAGS"
 106         LIBS="$LIBS $FREETYPE_LIBS"
 107         CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 108         AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
 109         LIBS="$_save_libs"
 110         CFLAGS="$_save_cflags"
 111 fi
 112 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 113
 114 dnl ===========================================================================
 115
 116 AC_CONFIG_FILES([
 117 Makefile
 118 harfbuzz.pc
 119 src/Makefile
 120 src/hb-version.h
 121 test/Makefile
 122 ])
 123
 124 AC_OUTPUT