configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([harfbuzz],
   3         [0.9.0],
   4         [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
   5         [harfbuzz],
   6         [http://harfbuzz.org/])
   7
   8 AC_CONFIG_SRCDIR([harfbuzz.pc.in])
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
  12 AM_SILENT_RULES([yes])
  13
  14 # Initialize libtool
  15 LT_PREREQ([2.2])
  16 LT_INIT([disable-static])
  17
  18 # Check for programs
  19 AC_PROG_CC
  20 AM_PROG_CC_C_O
  21 AC_PROG_CXX
  22
  23 # Version
  24 m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  25 m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
  26 m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
  27 m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
  28 HB_VERSION_MAJOR=hb_version_major
  29 HB_VERSION_MINOR=hb_version_minor
  30 HB_VERSION_MICRO=hb_version_micro
  31 HB_VERSION=AC_PACKAGE_VERSION
  32 AC_SUBST(HB_VERSION_MAJOR)
  33 AC_SUBST(HB_VERSION_MINOR)
  34 AC_SUBST(HB_VERSION_MICRO)
  35 AC_SUBST(HB_VERSION)
  36
  37 # Libtool version
  38 m4_define([hb_version_int],
  39           m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
  40 m4_if(m4_eval(hb_version_minor % 2), [1],
  41       dnl for unstable releases
  42       [m4_define([hb_libtool_revision], 0)],
  43       dnl for stable releases
  44       [m4_define([hb_libtool_revision], hb_version_micro)])
  45 m4_define([hb_libtool_age],
  46           m4_eval(hb_version_int - hb_libtool_revision))
  47 m4_define([hb_libtool_current],
  48           m4_eval(hb_version_major + hb_libtool_age))
  49 HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
  50 AC_SUBST(HB_LIBTOOL_VERSION_INFO)
  51
  52 dnl GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
  53
  54 # Functions and headers
  55 AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize sched_yield mmap _setmode isatty)
  56 AC_CHECK_HEADERS(unistd.h sys/mman.h sched.h io.h)
  57
  58 # Compiler flags
  59 AC_CANONICAL_HOST
  60 if test "x$GCC" = "xyes"; then
  61
  62         # Make symbols link locally
  63         LDFLAGS="$LDFLAGS -Bsymbolic-functions"
  64
  65         # Make sure we don't link to libstdc++
  66         CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
  67
  68         case "$host" in
  69                 arm-*-*)
  70                         # Request byte alignment on arm
  71                         CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
  72                 ;;
  73         esac
  74 fi
  75
  76 dnl ==========================================================================
  77
  78 have_ot=true
  79 if $have_ot; then
  80         AC_DEFINE(HAVE_OT, 1, [Have native OpenType Layout backend])
  81 fi
  82 AM_CONDITIONAL(HAVE_OT, $have_ot)
  83
  84 dnl ===========================================================================
  85
  86 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
  87 if $have_glib; then
  88         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
  89 fi
  90 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
  91
  92 PKG_CHECK_MODULES(GTHREAD, gthread-2.0, have_gthread=true, have_gthread=false)
  93 if $have_gthread; then
  94         AC_DEFINE(HAVE_GTHREAD, 1, [Have gthread2 library])
  95 fi
  96 AM_CONDITIONAL(HAVE_GTHREAD, $have_gthread)
  97
  98 PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0 >= 2.16, have_gobject=true, have_gobject=false)
  99 if $have_gobject; then
 100         AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
 101         GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 102         AC_SUBST(GLIB_MKENUMS)
 103 fi
 104 AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
 105
 106 dnl ==========================================================================
 107
 108 PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
 109 if $have_cairo; then
 110         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
 111 fi
 112 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
 113
 114 PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
 115 if $have_cairo_ft; then
 116         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
 117 fi
 118 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
 119
 120 dnl ==========================================================================
 121
 122 PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
 123         have_icu=true
 124         AC_CHECK_HEADERS(unicode/uchar.h,, have_icu=false)
 125         AC_MSG_CHECKING([for libicuuc])
 126         LIBS_old=$LIBS
 127         LIBS="$LIBS -licuuc"
 128         AC_TRY_LINK([#include <unicode/uchar.h>],
 129                     [u_getIntPropertyValue (0, (UProperty)0);],
 130                     AC_MSG_RESULT(yes),
 131                     AC_MSG_RESULT(no);have_icu=false)
 132         LIBS=$LIBS_old
 133         if $have_icu; then
 134                 ICU_CFLAGS=-D_REENTRANT
 135                 ICU_LIBS="-licuuc"
 136                 AC_SUBST(ICU_CFLAGS)
 137                 AC_SUBST(ICU_LIBS)
 138         fi
 139 ])
 140 if $have_icu; then
 141         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
 142 fi
 143 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 144
 145 dnl ==========================================================================
 146
 147 PKG_CHECK_MODULES(GRAPHITE2, graphite2, have_graphite=true, have_graphite=false)
 148 if $have_graphite; then
 149     AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite library])
 150 fi
 151 AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite)
 152
 153 dnl ==========================================================================
 154
 155 PKG_CHECK_MODULES(FREETYPE, freetype2 >= 2.3.8, have_freetype=true, have_freetype=false)
 156 if $have_freetype; then
 157         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 158         _save_libs="$LIBS"
 159         _save_cflags="$CFLAGS"
 160         LIBS="$LIBS $FREETYPE_LIBS"
 161         CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 162         AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
 163         LIBS="$_save_libs"
 164         CFLAGS="$_save_cflags"
 165 fi
 166 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 167
 168 dnl ===========================================================================
 169
 170 AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true, have_uniscribe=false)
 171 if $have_uniscribe; then
 172         UNISCRIBE_CFLAGS=
 173         UNISCRIBE_LIBS="-lusp10 -lgdi32"
 174         AC_SUBST(UNISCRIBE_CFLAGS)
 175         AC_SUBST(UNISCRIBE_LIBS)
 176         AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe backend])
 177 fi
 178 AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
 179
 180 dnl ===========================================================================
 181
 182 AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
 183         hb_cv_have_intel_atomic_primitives=false
 184         AC_TRY_LINK([], [
 185                 void memory_barrier (void) { __sync_synchronize (); }
 186                 int atomic_add (int i) { return __sync_fetch_and_add (&i, 1); }
 187                 int atomic_cmpxchg (int *i, int *j, int *k) { return __sync_bool_compare_and_swap (&i, j, k); }
 188                 ], hb_cv_have_intel_atomic_primitives=true
 189         )
 190 ])
 191 if $hb_cv_have_intel_atomic_primitives; then
 192         AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
 193 fi
 194
 195 dnl ===========================================================================
 196
 197 AC_CONFIG_FILES([
 198 Makefile
 199 harfbuzz.pc
 200 src/Makefile
 201 src/hb-version.h
 202 util/Makefile
 203 test/Makefile
 204 test/api/Makefile
 205 test/shaping/Makefile
 206 ])
 207
 208 AC_OUTPUT