configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 # get rid of that stupid cache mechanism
   4 rm -f config.cache
   5
   6 AC_INIT([expedite], [1.6.99], [enlightenment-devel@lists.sourceforge.net])
   7 AC_PREREQ([2.52])
   8 AC_CONFIG_SRCDIR([configure.ac])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12
  13 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 PKG_PROG_PKG_CONFIG
  17
  18
  19 ### Additional options to configure
  20
  21 ## Simple X11 build/link
  22
  23 ## Evas engines
  24
  25 AC_ARG_ENABLE(simple-x11,
  26    [AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking])],
  27    [want_evas_simple_x11=$enableval]
  28 )
  29
  30 # Software X11
  31 have_software_xlib="no"
  32 have_software_xcb="no"
  33 EXPEDITE_CHECK_ENGINE([software-x11], [Software X11], "yes")
  34
  35 if test "x${have_software_x11}" = "xyes" ; then
  36    have_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
  37    if test "x${have_software_xlib}" = "xstatic" ; then
  38       have_software_xlib="yes"
  39    fi
  40    if test "x${have_software_xlib}" = "xyes" ; then
  41       AC_DEFINE(HAVE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
  42    fi
  43    have_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
  44    if test "x${have_software_xcb}" = "xstatic" ; then
  45       have_software_xcb="yes"
  46    fi
  47    if test "x${have_software_xcb}" = "xyes" ; then
  48       AC_DEFINE(HAVE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
  49    fi
  50 fi
  51
  52 AM_CONDITIONAL([BUILD_SOFTWARE_XLIB], [test "x${have_software_xlib}" = "xyes"])
  53 AM_CONDITIONAL([BUILD_SOFTWARE_XCB], [test "x${have_software_xcb}" = "xyes"])
  54
  55 # XRender X11
  56 EXPEDITE_CHECK_ENGINE([xrender-x11], [XRender X11], "yes")
  57
  58 # OpenGL X11
  59 EXPEDITE_CHECK_ENGINE([opengl-x11], [OpenGL X11], "yes")
  60
  61 # XRender XCB
  62 EXPEDITE_CHECK_ENGINE([xrender-xcb], [XRender XCB], "yes")
  63
  64 # GDI
  65 EXPEDITE_CHECK_ENGINE([software-gdi], [Software GDI], "yes", [gdi_libs="-lgdi32"])
  66 AC_SUBST(gdi_libs)
  67
  68 # DirectDraw
  69 EXPEDITE_CHECK_ENGINE([software-ddraw], [Software DirectDraw], "yes", [ddraw_libs="-lddraw -ldxguid -lgdi32"])
  70 AC_SUBST(ddraw_libs)
  71
  72 # Direct3D
  73 EXPEDITE_CHECK_ENGINE([direct3d], [Direct3D], "yes", [d3d_libs="-ld3d9 -ld3dx9d -lgdi32"])
  74 AC_SUBST(d3d_libs)
  75
  76 # PSL1GHT
  77 EXPEDITE_CHECK_ENGINE([psl1ght], [PSL1GHT], "yes")
  78
  79 # GL SDL
  80 EXPEDITE_CHECK_ENGINE([opengl-sdl], [OpenGL SDL], "yes")
  81
  82 # FB
  83 EXPEDITE_CHECK_ENGINE([fb], [Framebuffer], "yes")
  84
  85 # DIRECTFB
  86 EXPEDITE_CHECK_ENGINE([directfb], [DirectFB], "yes")
  87
  88 # GL Cocoa
  89 EXPEDITE_CHECK_ENGINE([opengl-cocoa], [OpenGL Cocoa], "yes", [gl_cocoa_libs="-framework Cocoa"])
  90 AC_SUBST(gl_cocoa_libs)
  91
  92 # Software 16bit X11
  93 EXPEDITE_CHECK_ENGINE([software-16-x11], [Software 16 bits X11], "yes")
  94
  95 # 16bit DirectDraw
  96 EXPEDITE_CHECK_ENGINE([software-16-ddraw], [Software 16 bits DirectDraw], "yes", [ddraw_16_libs="-lddraw -ldxguid"])
  97 AC_SUBST(ddraw_16_libs)
  98
  99 # 16bit WinCE
 100 EXPEDITE_CHECK_ENGINE([software-16-wince], [Software 16 bits WinCE], "yes", [wince_16_libs="-laygshell"])
 101 AC_SUBST(wince_16_libs)
 102
 103 ### Checks for programs
 104
 105 AC_ISC_POSIX
 106 m4_ifdef([AC_PROG_OBJC],
 107    [
 108     AC_PROG_OBJC
 109     _AM_DEPENDENCIES(OBJC)
 110    ],
 111    [
 112     AC_CHECK_TOOL([OBJC], [gcc])
 113     AC_SUBST([OBJC])
 114     AC_SUBST([OBJCFLAGS])
 115    ]
 116 )
 117 AC_PROG_CXX
 118 AC_PROG_CC
 119
 120 LT_PROG_RC
 121
 122
 123
 124 ### Checks for libraries
 125
 126 # Evil library for compilation on Windows
 127
 128 case "$host_os" in
 129    mingw32*)
 130       PKG_CHECK_MODULES([EVIL], [evil >= 1.6.99])
 131       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 132       ;;
 133 esac
 134
 135 # Eina
 136
 137 PKG_CHECK_MODULES([EINA], eina >= 1.6.99)
 138
 139 # Evas
 140
 141 PKG_CHECK_MODULES([EVAS], evas >= 1.6.99 eet >= 1.6.99)
 142
 143 # Xlib
 144
 145 if test "x$have_software_xlib" = "xyes" -o "x$have_software_16_x11" = "xyes" -o "x$have_xrender_x11" = "xyes" -o "x$have_opengl_x11" = "xyes"; then
 146    AC_PATH_XTRA
 147    AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h],
 148       [have_xlib="yes"],
 149       [have_xlib="no"])
 150    if test "x$want_evas_simple_x11" = "xyes"; then
 151       x_libs="${x_libs} -lX11"
 152    else
 153       x_dir=${x_dir:-/usr/X11R6}
 154       x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 155       x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11"
 156    fi
 157 fi
 158 AM_CONDITIONAL(BUILD_X11, [test "x$have_xlib" = "xyes"])
 159
 160 AC_SUBST(x_cflags)
 161 AC_SUBST(x_libs)
 162
 163 # XCB
 164
 165 if test "x$have_software_xcb" = "xyes"; then
 166    PKG_CHECK_MODULES([XCB], [xcb xcb-keysyms], [have_xcb="yes"], [have_xcb="no"])
 167 fi
 168 AM_CONDITIONAL(BUILD_XCB, test "x$have_xcb" = "xyes")
 169 if test "x$have_xcb" = "xyes"; then
 170    AC_DEFINE(BUILD_XCB, 1, [build xcb support])
 171 fi
 172
 173 # SDL
 174
 175 PKG_CHECK_MODULES([SDL], [sdl], [have_sdl="yes"], [have_sdl="no"])
 176 AM_CONDITIONAL(BUILD_SDL, test "x$have_sdl" = "xyes")
 177 if test "x$have_sdl" = "xyes"; then
 178    AC_DEFINE(BUILD_SDL, 1, [build sdl support])
 179 fi
 180
 181 # PSL1GHT
 182 AM_CONDITIONAL(BUILD_PSL1GHT, test "x$have_psl1ght" = "xyes")
 183
 184 # DirectFB
 185
 186 if test "x$have_directfb" = "xyes"; then
 187    PKG_CHECK_MODULES([DIRECTFB], [directfb], [have_directfb="yes"], [have_directfb="no"])
 188 fi
 189 AM_CONDITIONAL(BUILD_DIRECTFB, test "x$have_directfb" = "xyes")
 190
 191
 192 ### Checks for header files
 193
 194
 195 ### Checks for types
 196
 197
 198 ### Checks for structures
 199
 200
 201 ### Checks for compiler characteristics
 202
 203 AM_PROG_CC_STDC
 204 AC_HEADER_STDC
 205 AC_C_CONST
 206 AM_PROG_CC_C_O
 207 AC_C___ATTRIBUTE__
 208
 209 WIN32_CFLAGS=""
 210 case "$host_os" in
 211    cegcc*)
 212       WIN32_CFLAGS="-mwin32"
 213       ;;
 214 esac
 215 AC_SUBST(WIN32_CFLAGS)
 216
 217 EXPEDITE_CXXFLAGS=""
 218 AC_LANG_PUSH([C++])
 219 CXXFLAGS_save="${CXXFLAGS}"
 220 CXXFLAGS="${CXXFLAGS} -fno-rtti -fno-exceptions"
 221 AC_LINK_IFELSE(
 222    [AC_LANG_PROGRAM([[]])],
 223    [have_cxx_flags="yes"],
 224    [have_cxx_flags="no"])
 225 AC_MSG_CHECKING([whether the compiler supports -fno-rtti -fno-exceptions])
 226 AC_MSG_RESULT([${have_cxx_flags}])
 227 CXXFLAGS="${CXXFLAGS_save}"
 228 if test "x${have_cxx_flags}" = "xyes" ; then
 229    EXPEDITE_CXXFLAGS="-fno-rtti -fno-exceptions"
 230 fi
 231 AC_LANG_POP([C++])
 232 AC_SUBST(EXPEDITE_CXXFLAGS)
 233
 234
 235 ### Checks for linker characteristics
 236
 237 lt_enable_auto_import=""
 238 case "$host_os" in
 239    mingw* | cegcc*)
 240       lt_enable_auto_import="-Wl,--enable-auto-import"
 241       ;;
 242 esac
 243 AC_SUBST(lt_enable_auto_import)
 244
 245
 246 ### Checks for library functions
 247
 248 AC_CHECK_FUNCS([sync])
 249
 250
 251 AC_OUTPUT([
 252 Makefile
 253 src/Makefile
 254 src/bin/Makefile
 255 data/Makefile
 256 ])
 257
 258 echo
 259 echo "  $PACKAGE $VERSION"
 260 echo
 261 echo "  Engines:"
 262 echo "    Software X11.................: ${have_software_x11} (Xlib: ${have_software_xlib}) (XCB: ${have_software_xcb})"
 263 echo "    X Render X11.................: ${have_xrender_x11}"
 264 echo "    Open GL X11..................: ${have_opengl_x11}"
 265 echo "    X Render XCB.................: ${have_xrender_xcb}"
 266 echo "    Software GDI.................: ${have_software_gdi}"
 267 echo "    Software DirectDraw..........: ${have_software_ddraw}"
 268 echo "    Direct3D.....................: ${have_direct3d}"
 269 echo "    Software SDL.................: ${have_software_sdl}"
 270 echo "    Open GL SDL..................: ${have_opengl_sdl}"
 271 echo "    Open GL Cocoa................: ${have_opengl_cocoa}"
 272 echo "    FB...........................: ${have_fb}"
 273 echo "    DirectFB.....................: ${have_directfb}"
 274 echo "    PSL1GHT......................: ${have_psl1ght}"
 275 echo "    Software X11 16 bits.........: ${have_software_16_x11}"
 276 echo "    Software DirectDraw 16 bits..: ${have_software_16_ddraw}"
 277 echo "    Software WinCE 16 bits.......: ${have_software_16_wince}"
 278 echo
 279 echo "  Installation:"
 280 echo "    prefix.......................: ${prefix}"
 281 echo