configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [6])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release ver-pre-svn-07])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([embryo], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_LIBTOOL_WIN32_DLL
  39 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  40 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  41 AC_PROG_LIBTOOL
  42
  43 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  46 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  47 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  48 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  49 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  50 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  51 version_info="lt_cur:lt_rev:lt_age"
  52 release_info="v_rel"
  53 AC_SUBST(version_info)
  54 AC_SUBST(release_info)
  55 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 VMAJ=v_maj
  58 AC_SUBST(VMAJ)
  59
  60 ### Default options with respect to host
  61
  62 AC_CANONICAL_BUILD
  63 AC_CANONICAL_HOST
  64
  65 requirement_embryo=""
  66 embryoincludedir="${datadir}/include"
  67
  68
  69 ### Additional options to configure
  70
  71 EFL_ENABLE_BIN([embryo-cc])
  72
  73
  74 ### Checks for programs
  75 AC_PROG_CC
  76
  77 # doxygen program for documentation building
  78
  79 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
  80
  81 # pkg-config
  82
  83 PKG_PROG_PKG_CONFIG
  84
  85 # Check whether pkg-config supports Requires.private
  86 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
  87    pkgconfig_requires_private="Requires.private"
  88 else
  89    pkgconfig_requires_private="Requires"
  90 fi
  91 AC_SUBST(pkgconfig_requires_private)
  92
  93
  94 ### Checks for libraries
  95
  96 # Evil library for compilation on Windows
  97
  98 EFL_EMBRYO_BUILD=""
  99 case "$host_os" in
 100    mingw*)
 101    PKG_CHECK_MODULES([EVIL], [evil >= 1.6.99])
 102    AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 103    requirement_embryo="evil ${requirement_embryo}"
 104    EFL_EMBRYO_BUILD="-DEFL_EMBRYO_BUILD"
 105    ;;
 106 esac
 107 AC_SUBST(EFL_EMBRYO_BUILD)
 108
 109 # For embryo_cc_prefix.c
 110 PKG_CHECK_MODULES([EINA], [eina >= 1.6.99])
 111
 112 ### Checks for portability layer
 113
 114 PKG_CHECK_MODULES([EXOTIC],
 115    [exotic],
 116    [enable_exotic="yes"],
 117    [enable_exotic="no"])
 118
 119 if test "x${enable_exotic}" = "xyes"; then
 120     requirement_embryo="exotic ${requirement_embryo}"
 121
 122     AC_DEFINE([HAVE_EXOTIC], [1], [Define to 1 if you have Exotic.])
 123 fi
 124
 125 ### Checks for header files
 126
 127 AC_CHECK_HEADERS([unistd.h])
 128 EFL_CHECK_PATH_MAX
 129
 130
 131 ### Checks for types
 132
 133
 134 ### Checks for structures
 135
 136
 137 ### Checks for compiler characteristics
 138 AC_C_BIGENDIAN
 139 AM_PROG_CC_C_O
 140 AC_C_CONST
 141 AC_C_INLINE
 142 AC_PROG_CC_STDC
 143 AC_HEADER_STDC
 144 AC_C___ATTRIBUTE__
 145
 146 EMBRYO_CPPFLAGS=""
 147 EMBRYO_CFLAGS=""
 148 case "$host_os" in
 149    mingw32ce*)
 150       EMBRYO_CPPFLAGS="-D_WIN32_WCE=0x0420"
 151       ;;
 152 esac
 153 AC_SUBST(EMBRYO_CPPFLAGS)
 154 AC_SUBST(EMBRYO_CFLAGS)
 155
 156
 157 ### Checks for linker characteristics
 158
 159 lt_enable_auto_import=""
 160 case "$host_os" in
 161    mingw*)
 162       lt_enable_auto_import="-Wl,--enable-auto-import"
 163       ;;
 164 esac
 165 AC_SUBST(lt_enable_auto_import)
 166
 167
 168 ### Checks for library functions
 169
 170 AC_ISC_POSIX
 171
 172 # alloca
 173 AC_FUNC_ALLOCA
 174
 175 # fnmatch
 176 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 177
 178 # gettimeofday
 179 EFL_CHECK_GETTIMEOFDAY([], [AC_MSG_ERROR([Cannot find gettimeofday()])])
 180
 181
 182 AC_SUBST(requirement_embryo)
 183 AC_SUBST(embryoincludedir)
 184
 185 AC_OUTPUT([
 186 Makefile
 187 doc/Makefile
 188 doc/Doxyfile
 189 doc/embryo.dox
 190 embryo.pc
 191 include/Makefile
 192 src/Makefile
 193 src/lib/Makefile
 194 src/bin/Makefile
 195 embryo.spec
 196 ])
 197
 198
 199 #####################################################################
 200 ## Info
 201
 202 echo
 203 echo
 204 echo
 205 echo "------------------------------------------------------------------------"
 206 echo "$PACKAGE $VERSION"
 207 echo "------------------------------------------------------------------------"
 208 echo
 209 echo "Configuration Options Summary:"
 210 echo
 211 echo "  Build embryo_cc......: $have_embryo_cc"
 212 echo
 213 echo "  Documentation........: ${build_doc}"
 214 echo
 215 echo "Compilation............: make (or gmake)"
 216 echo "  CPPFLAGS.............: $CPPFLAGS"
 217 echo "  CFLAGS...............: $CFLAGS"
 218 echo "  LDFLAGS..............: $LDFLAGS"
 219 echo
 220 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 221 echo "  prefix...............: $prefix"
 222 echo