configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [6])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-05])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eet], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 AC_LIBTOOL_WIN32_DLL
  41 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  42 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  43 AC_PROG_LIBTOOL
  44
  45 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  48 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  49 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  50 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  51 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  52 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  53 version_info="lt_cur:lt_rev:lt_age"
  54 release_info="v_rel"
  55 AC_SUBST(version_info)
  56 AC_SUBST(release_info)
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 VMAJ=v_maj
  60 AC_SUBST(VMAJ)
  61
  62
  63 ### Needed information
  64
  65 AC_CANONICAL_BUILD
  66 AC_CANONICAL_HOST
  67
  68 ### Default options with respect to host
  69
  70 requirements_pc_eet=""
  71 requirements_libs_eet=""
  72
  73 ### Additional options to configure
  74
  75 EFL_ENABLE_BIN([eet])
  76
  77 # Old eet file format support
  78
  79 AC_ARG_ENABLE(old-eet-file-format,
  80    [AC_HELP_STRING(
  81       [--disable-old-eet-file-format],
  82       [disable old eet file format support @<:@default=enabled@:>@])],
  83    [
  84     if test "x${enableval}" = "xyes" ; then
  85        old_eet_file_format="yes"
  86     else
  87        old_eet_file_format="no"
  88     fi
  89    ],
  90    [old_eet_file_format="yes"])
  91
  92 AC_MSG_CHECKING([whether to support old eet file format])
  93 AC_MSG_RESULT([${old_eet_file_format}])
  94
  95 if test "x${old_eet_file_format}" = "xyes" ; then
  96    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
  97 else
  98    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
  99 fi
 100
 101 # Openssl support
 102
 103 AC_ARG_ENABLE([openssl],
 104    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support @<:@default=auto@:>@])],
 105    [
 106     if test "x${enableval}" = "xyes" ; then
 107        want_openssl="yes"
 108     else
 109        want_openssl="no"
 110     fi
 111    ],
 112    [want_openssl="auto"])
 113
 114 AC_MSG_CHECKING([whether to use OpenSSL])
 115 AC_MSG_RESULT([${want_openssl}])
 116
 117 # Cryptography support
 118
 119 AC_ARG_ENABLE([cipher],
 120    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API @<:@default=yes@:>@])],
 121    [
 122     if test "x${enableval}" = "xyes" ; then
 123        want_cipher="yes"
 124     else
 125        want_cipher="no"
 126     fi
 127    ],
 128    [want_cipher="yes"])
 129
 130 AC_MSG_CHECKING([whether to use cipher])
 131 AC_MSG_RESULT([${want_cipher}])
 132
 133 AC_ARG_ENABLE([signature],
 134    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet @<:@default=yes@:>@])],
 135    [
 136     if test "x${enableval}" = "xyes" ; then
 137        want_signature="yes"
 138     else
 139        want_signature="no"
 140     fi
 141    ],
 142    [want_signature="yes"])
 143
 144 AC_MSG_CHECKING([whether to use signature])
 145 AC_MSG_RESULT([${want_signature}])
 146
 147 # Assert or fail.
 148
 149 AC_ARG_ENABLE([assert],
 150    [AC_HELP_STRING([--enable-assert], [enable assert, @<:@default=no@:>@])],
 151    [
 152     if test "x${enableval}" = "xyes" ; then
 153        prefer_assert="yes"
 154     else
 155        prefer_assert="no"
 156     fi
 157    ],
 158    [prefer_assert="no"])
 159
 160 # Examples
 161
 162 AC_ARG_ENABLE([install-examples],
 163    [AC_HELP_STRING([--disable-install-examples],
 164        [disable installing examples (compiled or just source). @<:@default=yes@:>@])],
 165    [
 166     if test "x${enableval}" = "xyes" ; then
 167        install_examples="yes"
 168     else
 169        install_examples="no"
 170     fi
 171    ],
 172    [install_examples="yes"])
 173
 174 AM_CONDITIONAL([INSTALL_EXAMPLES], [test "x${install_examples}" = "xyes"])
 175
 176 AC_ARG_ENABLE([build-examples],
 177    [AC_HELP_STRING([--enable-build-examples],
 178        [enable building examples @<:@default=yes@:>@])],
 179    [
 180     if test "x${enableval}" = "xyes" ; then
 181        build_examples="yes"
 182     else
 183        build_examples="no"
 184     fi
 185    ],
 186    [build_examples="no"])
 187 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x${build_examples}" = "xyes"])
 188
 189 # Unit tests, coverage and benchmarking
 190
 191 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 192 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 193
 194 if test "x${prefer_assert}" = "xno"; then
 195    DEBUG_CFLAGS="-DNDEBUG"
 196 else
 197 # use debug symbols and set DEBUG if coverage support is enabled
 198    DEBUG_CFLAGS="${EFL_DEBUG_CFLAGS}"
 199 fi
 200 AC_SUBST(DEBUG_CFLAGS)
 201
 202
 203 ### Checks for programs
 204 AC_PROG_CC
 205
 206 # pkg-config
 207 PKG_PROG_PKG_CONFIG
 208
 209 # Check whether pkg-config supports Requires.private
 210 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 211    pkgconfig_requires_private="Requires.private"
 212 else
 213    pkgconfig_requires_private="Requires"
 214 fi
 215 AC_SUBST(pkgconfig_requires_private)
 216
 217
 218 # doxygen program for documentation building
 219
 220 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 221
 222 ### Checks for libraries
 223
 224 ## Compatibility layers
 225
 226 # Evil library for compilation on Windows
 227
 228 EFL_EET_BUILD=""
 229 case "$host_os" in
 230    mingw*)
 231       PKG_CHECK_EXISTS([evil >= 1.1.0])
 232       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil package is installed])
 233       requirements_pc_eet="evil ${requirements_pc_eet}"
 234       EFL_EET_BUILD="-DEFL_EET_BUILD"
 235    ;;
 236 esac
 237 AC_SUBST(EFL_EET_BUILD)
 238
 239 # Exotic library for copilation on Coyote
 240
 241 PKG_CHECK_EXISTS([exotic],
 242    [
 243     enable_exotic="yes"
 244     AC_DEFINE([HAVE_EXOTIC_H], [1], [Define to 1 if you have Exotic.])
 245     EINA_CONFIGURE_HAVE_EXOTIC="#define EINA_HAVE_EXOTIC"
 246     requirements_pc_eina="exotic ${requirements_pc_eina}"
 247    ],
 248    [enable_exotic="no"])
 249
 250 ## Secure layer
 251
 252 # Gnutls library
 253
 254 AC_ARG_ENABLE([gnutls],
 255    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support @<:@default=auto@:>@])],
 256    [
 257     if test "x${enableval}" = "xyes" ; then
 258        want_gnutls="yes"
 259     else
 260        want_gnutls="no"
 261     fi
 262    ],
 263    [want_gnutls="auto"])
 264
 265 AC_MSG_CHECKING([whether to use Gnutls])
 266 AC_MSG_RESULT([${want_gnutls}])
 267
 268 have_gnutls="no"
 269 if test "x${want_gnutls}" = "xyes" || test "x${want_gnutls}" = "xauto" ; then
 270    PKG_CHECK_MODULES([GNUTLS], [gnutls >= 1.7.6],
 271       [
 272        have_gnutls="yes"
 273        want_openssl="no"
 274        AC_DEFINE([HAVE_GNUTLS], [1], [Have Gnutls support])
 275        requirements_pc_eet="gnutls >= 1.7.6 ${requirements_pc_eet}"
 276       ],
 277       [have_gnutls="no"])
 278 fi
 279
 280 # libgcrypt
 281
 282 if test "x${have_gnutls}" = "xyes" ; then
 283    AC_PATH_GENERIC([libgcrypt], [], [have_gnutls="yes"], [have_gnutls="no"])
 284    if test "x${have_gnutls}" = "xyes" ; then
 285       requirements_libs_eet="${LIBGCRYPT_LIBS} ${requirements_libs_eet}"
 286    fi
 287 fi
 288
 289 # Specific GNUTLS improvement
 290
 291 AC_ARG_ENABLE(new-gnutls-api,
 292    [AC_HELP_STRING(
 293       [--disable-new-gnutls-api],
 294       [enable use of gnutls_x509_crt_verify_hash. @<:@default=yes@:>@])],
 295    [
 296     if test "x${enableval}" = "xyes" ; then
 297        new_gnutls_api="yes"
 298     else
 299        new_gnutls_api="no"
 300     fi
 301    ],
 302    [new_gnutls_api="yes"])
 303
 304 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 305 AC_MSG_RESULT([${new_gnutls_api}])
 306
 307 if test "x${have_gnutls}" = "xyes" && test "x${new_gnutls_api}" = "xyes" ; then
 308    CFLAGS_save="${CFLAGS}"
 309    LIBS_save="${LIBS}"
 310    CFLAGS="${GNUTLS_CFLAGS}"
 311    LIBS="${GNUTLS_LIBS}"
 312    AC_CHECK_LIB([gnutls], [gnutls_x509_crt_verify_hash],
 313       [
 314        AC_DEFINE([EET_USE_NEW_GNUTLS_API], [1], [use gnutls_x509_crt_verify_hash])
 315        new_gnutls_api="yes"
 316       ],
 317       [new_gnutls_api="no"])
 318    CFLAGS="${CFLAGS_save}"
 319    LIBS="${LIBS_save}"
 320 fi
 321
 322 use_gnutls_privkey_sign_data="no"
 323 if test "x${have_gnutls}" = "xyes" ; then
 324    CFLAGS_save="${CFLAGS}"
 325    LIBS_save="${LIBS}"
 326    CFLAGS="${GNUTLS_CFLAGS}"
 327    LIBS="${GNUTLS_LIBS}"
 328    AC_CHECK_LIB([gnutls], [gnutls_privkey_sign_data],
 329       [
 330        AC_DEFINE([EET_USE_NEW_PRIVKEY_SIGN_DATA], [1], [use gnutls_privkey_sign_data])
 331        use_gnutls_privkey_sign_data="yes"
 332       ],
 333       [use_gnutls_privkey_sign_data="no"])
 334    CFLAGS="${CFLAGS_save}"
 335    LIBS="${LIBS_save}"
 336 fi
 337
 338 AC_MSG_CHECKING([whether to use gnutls_privkey_sign_data])
 339 AC_MSG_RESULT([${use_gnutls_privkey_sign_data}])
 340
 341 use_gnutls_pubkey_verify_hash="no"
 342 if test "x${have_gnutls}" = "xyes" ; then
 343    CFLAGS_save="${CFLAGS}"
 344    LIBS_save="${LIBS}"
 345    CFLAGS="${GNUTLS_CFLAGS}"
 346    LIBS="${GNUTLS_LIBS}"
 347    AC_CHECK_LIB([gnutls], [gnutls_pubkey_verify_hash],
 348       [
 349        AC_DEFINE([EET_USE_NEW_PUBKEY_VERIFY_HASH], [1], [use gnutls_pubkey_verify_hash])
 350        use_gnutls_pubkey_verify_hash="yes"
 351       ],
 352       [use_gnutls_pubkey_verify_hash="no"])
 353    CFLAGS="${CFLAGS_save}"
 354    LIBS="${LIBS_save}"
 355 fi
 356
 357 AC_MSG_CHECKING([whether to use gnutls_pubkey_verify_hash])
 358 AC_MSG_RESULT([${use_gnutls_pubkey_verify_hash}])
 359
 360 # Openssl library
 361 have_openssl="no"
 362 if test "x${want_openssl}" = "xyes" || test "x${want_openssl}" = "xauto" ; then
 363    PKG_CHECK_EXISTS([openssl],
 364       [
 365        have_openssl="yes"
 366        AC_DEFINE([HAVE_OPENSSL], [1], [Have Openssl support])
 367        requirements_pc_eet="openssl ${requirements_pc_eet}"
 368       ],
 369       [have_openssl="no"])
 370 fi
 371
 372 if test "x${have_gnutls}" = "xyes" ; then
 373    secure_layer="GnuTLS"
 374 elif test "x${have_openssl}" = "xyes" ; then
 375    secure_layer="OpenSSL"
 376 else
 377    secure_layer="no"
 378 fi
 379
 380 have_cipher="no"
 381 if test "x${have_gnutls}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 382    have_cipher="yes"
 383    AC_DEFINE([HAVE_CIPHER], [1], [Have cipher support built in eet])
 384 elif test "x${have_openssl}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 385    have_cipher="yes"
 386    AC_DEFINE([HAVE_CIPHER], [1], [Have cipher support built in eet])
 387 fi
 388
 389 AC_MSG_CHECKING([whether to activate cipher support in eet])
 390 AC_MSG_RESULT([${have_cipher}])
 391
 392 have_signature="no"
 393 if test "x${have_gnutls}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 394    have_signature="yes"
 395    AC_DEFINE([HAVE_SIGNATURE], [1], [Have signature support for eet file])
 396 elif test "x${have_openssl}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 397    have_signature="yes"
 398    AC_DEFINE([HAVE_SIGNATURE], [1], [Have signature support for eet file])
 399 fi
 400
 401 AC_MSG_CHECKING([whether to activate signature support in eet])
 402 AC_MSG_RESULT([${have_signature}])
 403
 404 # libjpeg and zlib
 405 EFL_CHECK_LIBS([eet], [libjpeg zlib])
 406
 407 # Eina library
 408
 409 requirements_pc_eet="eina >= 1.2.0 ${requirements_pc_eet}"
 410 PKG_CHECK_MODULES([EET], [${requirements_pc_eet}])
 411
 412 case "$host_os" in
 413    mingw32ce*)
 414       requirements_libs_eet="${requirements_libs_eet} -lws2"
 415       ;;
 416    mingw*)
 417       requirements_libs_eet="${requirements_libs_eet} -lws2_32"
 418       ;;
 419 esac
 420
 421 EET_LIBS="${EET_LIBS} ${requirements_libs_eet}"
 422
 423 ### Checks for header files
 424
 425 AC_CHECK_HEADERS(netinet/in.h unistd.h)
 426 EFL_CHECK_PATH_MAX
 427
 428 ### Checks for types
 429
 430
 431 ### Checks for structures
 432
 433
 434 ### Checks for compiler characteristics
 435 AM_PROG_CC_C_O
 436 AC_C_INLINE
 437 AC_PROG_CC_STDC
 438 AC_C___ATTRIBUTE__
 439
 440 # Check whether the null pointer is zero on this arch
 441 AC_TRY_RUN(
 442    [
 443 #include <stdlib.h>
 444 #include <inttypes.h>
 445 int main (int argc, char **argv) {
 446   void *foo = NULL;
 447   uintptr_t bar = (uintptr_t)foo;
 448   return (uintptr_t)foo;
 449 }
 450    ],
 451    [have_null="yes"],
 452    [have_null="no"],
 453    [
 454     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 455     have_null="yes"
 456    ])
 457 AC_MSG_CHECKING([value of the null pointer])
 458 AC_MSG_RESULT([${have_null}])
 459
 460 if test ! "x${have_null}" = "xyes" ; then
 461    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 462 fi
 463
 464
 465 ### Checks for linker characteristics
 466
 467 # use --enable-auto-import on Windows
 468
 469 lt_enable_auto_import=""
 470 case "$host_os" in
 471    mingw*)
 472       lt_enable_auto_import="-Wl,--enable-auto-import"
 473       ;;
 474 esac
 475 AC_SUBST([lt_enable_auto_import])
 476
 477 case "${host_os}" in
 478    openbsd*)
 479       ;;
 480    *)
 481       EFL_LINKER_FLAG([-Wl,--as-needed])
 482       ;;
 483 esac
 484
 485
 486 ### Checks for library functions
 487 AC_ISC_POSIX
 488 AC_FUNC_ALLOCA
 489
 490 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 491
 492 EFL_CHECK_FUNCS([eet], [fnmatch])
 493
 494
 495 AC_SUBST([requirements_pc_eet])
 496 AC_SUBST([requirements_libs_eet])
 497
 498 AC_OUTPUT([
 499 Makefile
 500 eet.pc
 501 doc/Makefile
 502 doc/Doxyfile
 503 doc/eet.dox
 504 src/Makefile
 505 src/lib/Makefile
 506 src/bin/Makefile
 507 src/tests/Makefile
 508 src/examples/Makefile
 509 eet.spec
 510 ])
 511
 512
 513 #####################################################################
 514 ## Info
 515
 516 echo
 517 echo
 518 echo
 519 echo "------------------------------------------------------------------------"
 520 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 521 echo "------------------------------------------------------------------------"
 522 echo
 523 echo "Configuration Options Summary:"
 524 echo
 525 echo "  Secure layer.........: ${secure_layer}"
 526 if test "x${have_gnutls}" = "xyes" || test "x${have_openssl}" = "xyes" ; then
 527    echo "    Cipher support.....: ${have_cipher}"
 528    echo "    Signature..........: ${have_signature}"
 529 fi
 530 echo
 531 echo "  Old eet file format..: ${old_eet_file_format}"
 532 echo
 533 echo "  Tests................: ${enable_tests}"
 534 echo "  Coverage.............: ${enable_coverage}"
 535 echo
 536 echo "  Build eet............: $have_eet"
 537 echo
 538 echo "  Documentation........: ${build_doc}"
 539 if test "x${build_doc}" = "xyes" ; then
 540    echo "    Building...........: make doc"
 541 fi
 542 echo "  Examples.............: ${build_examples}"
 543 echo "  Examples installed...: ${install_examples}"
 544 echo
 545 echo "Compilation............: make (or gmake)"
 546 echo "  CPPFLAGS.............: $CPPFLAGS"
 547 echo "  CFLAGS...............: $CFLAGS"
 548 echo "  LDFLAGS..............: $LDFLAGS"
 549 echo
 550 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 551 echo "  prefix...............: $prefix"
 552 echo