configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [6])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-05])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eet], [v_ver]-alpha, [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_LIBTOOL_WIN32_DLL
  39 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  40 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  41 AC_PROG_LIBTOOL
  42
  43 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  46 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  47 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  48 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  49 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  50 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  51 version_info="lt_cur:lt_rev:lt_age"
  52 release_info="v_rel"
  53 AC_SUBST(version_info)
  54 AC_SUBST(release_info)
  55 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 VMAJ=v_maj
  58 AC_SUBST(VMAJ)
  59
  60
  61 ### Needed information
  62
  63 AC_CANONICAL_BUILD
  64 AC_CANONICAL_HOST
  65
  66 ### Default options with respect to host
  67
  68 want_gnutls="auto"
  69 want_openssl="auto"
  70 want_cipher="yes"
  71 want_signature="yes"
  72
  73 requirement_eet=""
  74
  75
  76 ### Additional options to configure
  77
  78 # Amalgamation
  79
  80 AC_ARG_ENABLE([amalgamation],
  81    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  82    [if test "x${enableval}" = "xyes"; then
  83        do_amalgamation="yes"
  84     else
  85        do_amalgamation="no"
  86     fi
  87    ],
  88    [do_amalgamation="no"]
  89 )
  90 AM_CONDITIONAL(EET_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
  91
  92 EFL_ENABLE_BIN([eet])
  93
  94 # Old eet file format support
  95
  96 old_eet_file_format="yes"
  97 AC_ARG_ENABLE(old-eet-file-format,
  98    [AC_HELP_STRING(
  99       [--disable-old-eet-file-format],
 100       [disable old eet file format support. [[default=enabled]]]
 101     )],
 102    [old_eet_file_format=$enableval]
 103 )
 104 AC_MSG_CHECKING([whether to support old eet file format])
 105 AC_MSG_RESULT([${old_eet_file_format}])
 106
 107 if test "x${old_eet_file_format}" = "xyes" ; then
 108    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
 109 else
 110    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
 111 fi
 112
 113 # Openssl support
 114
 115 AC_ARG_ENABLE([openssl],
 116    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support])],
 117    [want_openssl=$enableval]
 118 )
 119 AC_MSG_CHECKING([whether to use OpenSSL])
 120 AC_MSG_RESULT([${want_openssl}])
 121
 122 # Cryptography support
 123
 124 AC_ARG_ENABLE([cipher],
 125    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API])],
 126    [want_cipher=$enableval]
 127 )
 128 AC_MSG_CHECKING([whether to use cipher])
 129 AC_MSG_RESULT([${want_cipher}])
 130
 131 AC_ARG_ENABLE([signature],
 132    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet])],
 133    [want_signature=$enableval]
 134 )
 135 AC_MSG_CHECKING([whether to use signature])
 136 AC_MSG_RESULT([${want_signature}])
 137
 138 # Assert or fail.
 139 prefer_assert="no"
 140 AC_ARG_ENABLE([assert],
 141    [AC_HELP_STRING([--enable-assert], [enable assert, [[default=disabled]]])],
 142    [prefer_assert=$enableval]
 143 )
 144
 145 # Examples
 146
 147 AC_ARG_ENABLE([install-examples],
 148    [AC_HELP_STRING([--disable-install-examples],
 149        [disable installing examples (compiled or just source). @<:@default==enabled@:>@])],
 150    [
 151     if test "x${enableval}" = "xyes" ; then
 152        install_examples="yes"
 153     else
 154        install_examples="no"
 155     fi
 156    ],
 157    [install_examples="yes"])
 158 AM_CONDITIONAL([INSTALL_EXAMPLES], [test "x${install_examples}" = "xyes"])
 159
 160 AC_ARG_ENABLE([build-examples],
 161    [AC_HELP_STRING([--enable-build-examples],
 162        [enable building examples. @<:@default==disabled@:>@])],
 163    [
 164     if test "x${enableval}" = "xyes" ; then
 165        build_examples="yes"
 166     else
 167        build_examples="no"
 168     fi
 169    ],
 170    [build_examples="no"])
 171 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x${build_examples}" = "xyes"])
 172
 173 # Unit tests, coverage and benchmarking
 174
 175 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 176 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 177
 178 if test "x${prefer_assert}" = "xno"; then
 179    DEBUG_CFLAGS="-DNDEBUG"
 180 else
 181 # use debug symbols and set DEBUG if coverage support is enabled
 182    DEBUG_CFLAGS="${EFL_DEBUG_CFLAGS}"
 183 fi
 184 AC_SUBST(DEBUG_CFLAGS)
 185
 186
 187 ### Checks for programs
 188 AC_PROG_CC
 189
 190 # pkg-config
 191 PKG_PROG_PKG_CONFIG
 192
 193 # Check whether pkg-config supports Requires.private
 194 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 195    pkgconfig_requires_private="Requires.private"
 196 else
 197    pkgconfig_requires_private="Requires"
 198 fi
 199 AC_SUBST(pkgconfig_requires_private)
 200
 201
 202 # doxygen program for documentation building
 203
 204 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 205
 206 ### Checks for libraries
 207
 208 # Evil library for compilation on Windows
 209
 210 EFL_EET_BUILD=""
 211 case "$host_os" in
 212    mingw*)
 213       PKG_CHECK_MODULES([EVIL], [evil >= 1.0.0])
 214       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 215       requirement_eet="evil ${requirement_eet}"
 216       EFL_EET_BUILD="-DEFL_EET_BUILD"
 217    ;;
 218 esac
 219 AC_SUBST(EFL_EET_BUILD)
 220
 221 EET_LIBS=""
 222 case "$host_os" in
 223    mingw32ce*)
 224       EET_LIBS="-lws2"
 225       ;;
 226    mingw*)
 227       EET_LIBS="-lws2_32"
 228       ;;
 229 esac
 230 AC_SUBST(EET_LIBS)
 231
 232 # Eina library
 233
 234 PKG_CHECK_MODULES(EINA, [eina >= 1.1.0])
 235 requirement_eet="eina >= 1.1.0 ${requirement_eet}"
 236
 237 ### Checks for portability layer
 238
 239 PKG_CHECK_MODULES([EXOTIC],
 240    [exotic],
 241    [enable_exotic="yes"],
 242    [enable_exotic="no"])
 243
 244 if test "x${enable_exotic}" = "xyes"; then
 245     requirement_eet="exotic ${requirement_eet}"
 246
 247     AC_DEFINE([HAVE_EXOTIC_H], [1], [Define to 1 if you have Exotic.])
 248 fi
 249
 250 # Gnutls support
 251
 252 AC_ARG_ENABLE([gnutls],
 253    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support])],
 254    [want_gnutls=$enableval]
 255 )
 256 AC_MSG_CHECKING([whether to use Gnutls])
 257 AC_MSG_RESULT([${want_gnutls}])
 258
 259 # Gnutls library
 260 have_gnutls="no"
 261 if test "x${want_gnutls}" = "xyes" || test "x${want_gnutls}" = "xauto" ; then
 262    PKG_CHECK_MODULES(GNUTLS, [gnutls >= 1.7.6],
 263       [
 264        have_gnutls="yes"
 265        want_openssl="no"
 266        AC_DEFINE(HAVE_GNUTLS, 1, [Have Gnutls support])
 267        requirement_eet="gnutls ${requirement_eet}"
 268       ],
 269       [have_gnutls="no"])
 270    if test "x${have_gnutls}" = "xyes" ; then
 271       AC_PATH_GENERIC([libgcrypt], [], [have_gnutls="yes"], [have_gnutls="no"])
 272       if test "x${have_gnutls}" = "xyes" ; then
 273          GNUTLS_CFLAGS="${GNUTLS_CFLAGS} ${LIBGCRYPT_CFLAGS}"
 274          GNUTLS_LIBS="${GNUTLS_LIBS} ${LIBGCRYPT_LIBS}"
 275       fi
 276    fi
 277 fi
 278
 279 # Specific GNUTLS improvement
 280
 281 new_gnutls_api="yes"
 282 AC_ARG_ENABLE(new-gnutls-api,
 283    [AC_HELP_STRING(
 284       [--disable-new-gnutls-api],
 285       [enable use of gnutls_x509_crt_verify_hash. [[default=enable]]]
 286     )],
 287    [new_gnutls_api=$enableval]
 288 )
 289 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 290 AC_MSG_RESULT([${new_gnutls_api}])
 291
 292 if test "x${new_gnutls_api}" = "xyes" ; then
 293    tmp_CFLAGS="${CFLAGS}"
 294    tmp_LIBS="${LIBS}"
 295    CFLAGS="${GNUTLS_CFLAGS}"
 296    LIBS="${GNUTLS_LIBS}"
 297    AC_CHECK_LIB(gnutls, gnutls_x509_crt_verify_hash,
 298                 [ new_gnutls_api="yes" ],
 299                 [ new_gnutls_api="no" ]
 300                 )
 301    CFLAGS="${tmp_CFLAGS}"
 302    LIBS="${tmp_LIBS}"
 303
 304    if test "x${new_gnutls_api}" = "xyes"; then
 305       AC_DEFINE(EET_USE_NEW_GNUTLS_API, 1, [use gnutls_x509_crt_verify_hash])
 306    fi
 307 fi
 308
 309 use_gnutls_privkey_sign_data="no"
 310 if test "x${want_gnutls}" = "xyes" -o "x${want_gnutls}" = "xauto"; then
 311    tmp_CFLAGS="${CFLAGS}"
 312    tmp_LIBS="${LIBS}"
 313    CFLAGS="${GNUTLS_CFLAGS}"
 314    LIBS="${GNUTLS_LIBS}"
 315    AC_CHECK_LIB(gnutls, gnutls_privkey_sign_data,
 316                 [ use_gnutls_privkey_sign_data="yes" ],
 317                 [ use_gnutls_privkey_sign_data="no" ]
 318                 )
 319    CFLAGS="${tmp_CFLAGS}"
 320    LIBS="${tmp_LIBS}"
 321
 322    if test "x${use_gnutls_privkey_sign_data}" = "xyes"; then
 323       AC_DEFINE(EET_USE_NEW_PRIVKEY_SIGN_DATA, 1, [use gnutls_privkey_sign_data])
 324    fi
 325 fi
 326 AC_MSG_CHECKING([whether to use gnutls_privkey_sign_data])
 327 AC_MSG_RESULT([${use_gnutls_privkey_sign_data}])
 328
 329 use_gnutls_pubkey_verify_hash="no"
 330 if test "x${want_gnutls}" = "xyes" -o "x${want_gnutls}" = "xauto"; then
 331    tmp_CFLAGS="${CFLAGS}"
 332    tmp_LIBS="${LIBS}"
 333    CFLAGS="${GNUTLS_CFLAGS}"
 334    LIBS="${GNUTLS_LIBS}"
 335    AC_CHECK_LIB(gnutls, gnutls_pubkey_verify_hash,
 336                 [ use_gnutls_pubkey_verify_hash="yes" ],
 337                 [ use_gnutls_pubkey_verify_hash="no" ]
 338                 )
 339    CFLAGS="${tmp_CFLAGS}"
 340    LIBS="${tmp_LIBS}"
 341
 342    if test "x${use_gnutls_pubkey_verify_hash}" = "xyes"; then
 343       AC_DEFINE(EET_USE_NEW_PUBKEY_VERIFY_HASH, 1, [use gnutls_pubkey_verify_hash])
 344    fi
 345 fi
 346 AC_MSG_CHECKING([whether to use gnutls_pubkey_verify_hash])
 347 AC_MSG_RESULT([${use_gnutls_pubkey_verify_hash}])
 348
 349 # Openssl library
 350 have_openssl="no"
 351 if test "x${want_openssl}" = "xyes" || test "x${want_openssl}" = "xauto" ; then
 352    PKG_CHECK_MODULES(OPENSSL, openssl,
 353       [
 354        have_openssl="yes"
 355        AC_DEFINE(HAVE_OPENSSL, 1, [Have Openssl support])
 356        requirement_eet="openssl ${requirement_eet}"
 357       ],
 358       [have_openssl="no"])
 359 fi
 360
 361 if test "x${have_gnutls}" = "xyes" ; then
 362    secure_layer="GnuTLS"
 363 elif test "x${have_openssl}" = "xyes" ; then
 364    secure_layer="OpenSSL"
 365 else
 366    secure_layer="no"
 367 fi
 368
 369 have_cipher="no"
 370 if test "x${have_gnutls}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 371    have_cipher="yes"
 372    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 373 elif test "x${have_openssl}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 374    have_cipher="yes"
 375    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 376 fi
 377
 378 AC_MSG_CHECKING(whether to activate cipher support in eet)
 379 AC_MSG_RESULT(${have_cipher})
 380
 381 have_signature="no"
 382 if test "x${have_gnutls}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 383    have_signature="yes"
 384    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 385 elif test "x${have_openssl}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 386    have_signature="yes"
 387    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 388 fi
 389
 390 AC_MSG_CHECKING(whether to activate signature support in eet)
 391 AC_MSG_RESULT(${have_signature})
 392
 393 ### Checks for header files
 394
 395 AC_CHECK_HEADER([zlib.h],
 396    [dummy="yes"],
 397    [AC_MSG_ERROR("Cannot find zlib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 398
 399 AC_CHECK_HEADER([jpeglib.h],
 400    [dummy="yes"],
 401    [AC_MSG_ERROR("Cannot find jpeglib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 402
 403 AC_CHECK_HEADERS(netinet/in.h unistd.h)
 404 EFL_CHECK_PATH_MAX
 405
 406 ### Checks for types
 407
 408
 409 ### Checks for structures
 410
 411
 412 ### Checks for compiler characteristics
 413 AM_PROG_CC_C_O
 414 AC_C_CONST
 415 AC_C_INLINE
 416 AC_PROG_CC_STDC
 417 AC_C___ATTRIBUTE__
 418
 419 # Check whether the null pointer is zero on this arch
 420 AC_TRY_RUN(
 421    [
 422 #include <stdlib.h>
 423 #include <inttypes.h>
 424 int main (int argc, char **argv) {
 425   void *foo = NULL;
 426   uintptr_t bar = (uintptr_t)foo;
 427   return (uintptr_t)foo;
 428 }
 429    ],
 430    [have_null="yes"],
 431    [have_null="no"],
 432    [
 433     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 434     have_null="yes"
 435    ])
 436 AC_MSG_CHECKING([value of the null pointer])
 437 AC_MSG_RESULT([${have_null}])
 438
 439 if test ! "x${have_null}" = "xyes" ; then
 440    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 441 fi
 442
 443 # These are needed for fmemopen/open_memstream
 444 AC_DEFINE(_GNU_SOURCE, , [Enable GNU extensions])
 445
 446 EET_CPPFLAGS=""
 447 EET_CFLAGS=""
 448 case "$host_os" in
 449    mingw32ce*)
 450       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 451       ;;
 452    mingw*)
 453       EET_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 454       ;;
 455 esac
 456 AC_SUBST(EET_CPPFLAGS)
 457 AC_SUBST(EET_CFLAGS)
 458
 459
 460 ### Checks for linker characteristics
 461
 462 # use --enable-auto-import on Windows
 463
 464 lt_enable_auto_import=""
 465 case "$host_os" in
 466    mingw*)
 467       lt_enable_auto_import="-Wl,--enable-auto-import"
 468       ;;
 469 esac
 470 AC_SUBST(lt_enable_auto_import)
 471
 472 case "${host_os}" in
 473    openbsd*)
 474       ;;
 475    *)
 476       EFL_LINKER_FLAG([-Wl,--as-needed])
 477       ;;
 478 esac
 479
 480
 481 ### Checks for library functions
 482 AC_ISC_POSIX
 483 AC_FUNC_ALLOCA
 484
 485 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 486
 487 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 488
 489
 490 AC_SUBST(requirement_eet)
 491
 492 AC_OUTPUT([
 493 Makefile
 494 eet.pc
 495 doc/Makefile
 496 doc/Doxyfile
 497 doc/eet.dox
 498 src/Makefile
 499 src/lib/Makefile
 500 src/bin/Makefile
 501 src/tests/Makefile
 502 src/examples/Makefile
 503 eet.spec
 504 ])
 505
 506
 507 #####################################################################
 508 ## Info
 509
 510 echo
 511 echo
 512 echo
 513 echo "------------------------------------------------------------------------"
 514 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 515 echo "------------------------------------------------------------------------"
 516 echo
 517 echo "Configuration Options Summary:"
 518 echo
 519 echo "  Amalgamation.........: ${do_amalgamation}"
 520 echo "  Secure layer.........: ${secure_layer}"
 521 if test "x${have_gnutls}" = "xyes" || test "x${have_openssl}" = "xyes" ; then
 522    echo "    Cipher support.....: ${have_cipher}"
 523    echo "    Signature..........: ${have_signature}"
 524 fi
 525 echo
 526 echo "  Old eet file format..: ${old_eet_file_format}"
 527 echo
 528 echo "  Tests................: ${enable_tests}"
 529 echo "  Coverage.............: ${enable_coverage}"
 530 echo
 531 echo "  Build eet............: $have_eet"
 532 echo
 533 echo "  Documentation........: ${build_doc}"
 534 if test "x${build_doc}" = "xyes" ; then
 535    echo "    Building...........: make doc"
 536 fi
 537 echo "  Examples.............: ${build_examples}"
 538 if test "x${build_examples}" = "xyes" ; then
 539    echo "    Install............: ${install_examples}"
 540 fi
 541 echo
 542 echo "Compilation............: make (or gmake)"
 543 echo "  CPPFLAGS.............: $CPPFLAGS"
 544 echo "  CFLAGS...............: $CFLAGS"
 545 echo "  LDFLAGS..............: $LDFLAGS"
 546 echo
 547 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 548 echo "  prefix...............: $prefix"
 549 echo