configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([eet], [1.2.2], [enlightenment-devel@lists.sourceforge.net])
   5 AC_PREREQ([2.52])
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_CANONICAL_BUILD
   9 AC_CANONICAL_HOST
  10 AC_ISC_POSIX
  11
  12 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  13 AM_CONFIG_HEADER([config.h])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 AC_LIBTOOL_WIN32_DLL
  17 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  18 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  19 AC_PROG_LIBTOOL
  20
  21 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  22 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  23 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  24 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  25 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  26 #release="ver-pre-svn-00"
  27 #release_info="-release $release"
  28 release_info=""
  29 AC_SUBST(version_info)
  30 AC_SUBST(release_info)
  31
  32 ### Default options with respect to host
  33
  34 case "$host_os" in
  35    mingw* | cegcc*)
  36       want_gnutls="no"
  37       want_openssl="no"
  38       want_cipher="no"
  39       want_signature="no"
  40       ;;
  41    *)
  42       want_gnutls="auto"
  43       want_openssl="auto"
  44       want_cipher="yes"
  45       want_signature="yes"
  46       ;;
  47 esac
  48
  49 requirement_eet=""
  50
  51
  52 ### Additional options to configure
  53
  54 AC_ARG_ENABLE([amalgamation],
  55    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  56    [if test "x${enableval}" = "xyes"; then
  57        do_amalgamation="yes"
  58     else
  59        do_amalgamation="no"
  60     fi
  61    ],
  62    [do_amalgamation="no"]
  63 )
  64 AM_CONDITIONAL(EET_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
  65
  66 # Old eet file format support
  67
  68 old_eet_file_format="yes"
  69 AC_ARG_ENABLE(old-eet-file-format,
  70    [AC_HELP_STRING(
  71       [--disable-old-eet-file-format],
  72       [disable old eet file format support. [[default=enabled]]]
  73     )],
  74    [old_eet_file_format=$enableval]
  75 )
  76 AC_MSG_CHECKING([whether to support old eet file format])
  77 AC_MSG_RESULT([${old_eet_file_format}])
  78
  79 if test "x${old_eet_file_format}" = "xyes" ; then
  80    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
  81 else
  82    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
  83 fi
  84
  85 # Gnutls support
  86
  87 AC_ARG_ENABLE([gnutls],
  88    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support])],
  89    [want_gnutls=$enableval]
  90 )
  91 AC_MSG_CHECKING([whether to use Gnutls])
  92 AC_MSG_RESULT([${want_gnutls}])
  93
  94 # Specific GNUTLS improvement
  95
  96 new_gnutls_api="no"
  97 AC_ARG_ENABLE(new-gnutls-api,
  98    [AC_HELP_STRING(
  99       [--enable-new-gnutls-api],
 100       [enable use of gnutls_x509_crt_verify_hash. [[default=disable]]]
 101     )],
 102    [new_gnutls_api=$enableval]
 103 )
 104 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 105 AC_MSG_RESULT([${new_gnutls_api}])
 106
 107 if test "x${new_gnutls_api}" = "xyes" ; then
 108    AC_DEFINE(EET_USE_NEW_GNUTLS_API, 1, [use gnutls_x509_crt_verify_hash])
 109 else
 110    AC_DEFINE(EET_USE_NEW_GNUTLS_API, 0, [don't use gnutls_x509_crt_verify_hash])
 111 fi
 112
 113 # Openssl support
 114
 115 AC_ARG_ENABLE([openssl],
 116    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support])],
 117    [want_openssl=$enableval]
 118 )
 119 AC_MSG_CHECKING([whether to use OpenSSL])
 120 AC_MSG_RESULT([${want_openssl}])
 121
 122 # Cryptography support
 123
 124 AC_ARG_ENABLE([cipher],
 125    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API])],
 126    [want_cipher=$enableval]
 127 )
 128 AC_MSG_CHECKING([whether to use cipher])
 129 AC_MSG_RESULT([${want_cipher}])
 130
 131 AC_ARG_ENABLE([signature],
 132    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet])],
 133    [want_signature=$enableval]
 134 )
 135 AC_MSG_CHECKING([whether to use signature])
 136 AC_MSG_RESULT([${want_signature}])
 137
 138 # Assert or fail.
 139 prefer_assert="no"
 140 AC_ARG_ENABLE([assert],
 141    [AC_HELP_STRING([--enable-assert], [enable assert, [[default=disabled]]])],
 142    [prefer_assert=$enableval]
 143 )
 144
 145 # Unit tests, coverage and benchmarking
 146
 147 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 148 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 149
 150 if test "x${prefer_assert}" = "xno"; then
 151    DEBUG_CFLAGS="-DNDEBUG"
 152 else
 153 # use debug symbols and set DEBUG if coverage support is enabled
 154    DEBUG_CFLAGS="${EFL_DEBUG_CFLAGS}"
 155 fi
 156 AC_SUBST(DEBUG_CFLAGS)
 157
 158
 159 ### Checks for programs
 160 AC_PROG_CC
 161
 162 # pkg-config
 163 PKG_PROG_PKG_CONFIG
 164
 165 # Check whether pkg-config supports Requires.private
 166 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 167    pkgconfig_requires_private="Requires.private"
 168 else
 169    pkgconfig_requires_private="Requires"
 170 fi
 171 AC_SUBST(pkgconfig_requires_private)
 172
 173
 174 # doxygen program for documentation building
 175
 176 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 177
 178
 179 ### Checks for libraries
 180
 181 # Evil library for compilation on Windows
 182
 183 EFL_EET_BUILD=""
 184 case "$host_os" in
 185    mingw* | cegcc*)
 186       PKG_CHECK_MODULES([EVIL], [evil])
 187       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 188       requirement_eet="evil ${requirement_eet}"
 189       EFL_EET_BUILD="-DEFL_EET_BUILD"
 190    ;;
 191 esac
 192 AC_SUBST(EFL_EET_BUILD)
 193
 194 EET_LIBS=""
 195 case "$host_os" in
 196    mingw32ce*)
 197       EET_LIBS="-lws2"
 198       ;;
 199    cegcc*)
 200       EET_LIBS="-lws2"
 201       ;;
 202    mingw*)
 203       EET_LIBS="-lws2_32"
 204       ;;
 205 esac
 206 AC_SUBST(EET_LIBS)
 207
 208 # Eina library
 209
 210 PKG_CHECK_MODULES(EINA, [eina-0])
 211 requirement_eet="eina-0 ${requirement_eet}"
 212
 213 # Gnutls library
 214 have_gnutls="no"
 215 if test "x${want_gnutls}" = "xyes" -o "x${want_gnutls}" = "xauto" ; then
 216    PKG_CHECK_MODULES(GNUTLS, [gnutls >= 1.7.6],
 217       [
 218        have_gnutls="yes"
 219        want_openssl="no"
 220        AC_DEFINE(HAVE_GNUTLS, 1, [Have Gnutls support])
 221        requirement_eet="gnutls ${requirement_eet}"
 222       ],
 223       [have_gnutls="no"])
 224    if test "x${have_gnutls}" = "xyes" ; then
 225       AC_PATH_GENERIC([libgcrypt], [], [have_gnutls="yes"], [have_gnutls="no"])
 226       if test "x${have_gnutls}" = "xyes" ; then
 227          GNUTLS_CFLAGS="${GNUTLS_CFLAGS} ${LIBGCRYPT_CFLAGS}"
 228          GNUTLS_LIBS="${GNUTLS_LIBS} ${LIBGCRYPT_LIBS}"
 229       fi
 230    fi
 231 fi
 232
 233 # Openssl library
 234 have_openssl="no"
 235 if test "x${want_openssl}" = "xyes" -o "x${want_openssl}" = "xauto" ; then
 236    PKG_CHECK_MODULES(OPENSSL, openssl,
 237       [
 238        have_openssl="yes"
 239        AC_DEFINE(HAVE_OPENSSL, 1, [Have Openssl support])
 240        requirement_eet="openssl ${requirement_eet}"
 241       ],
 242       [have_openssl="no"])
 243 fi
 244
 245 have_cipher="no"
 246 if test "x${have_gnutls}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 247    have_cipher="yes"
 248    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 249 elif test "x${have_openssl}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 250    have_cipher="yes"
 251    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 252 fi
 253
 254 AC_MSG_CHECKING(whether to activate cipher support in eet)
 255 AC_MSG_RESULT(${have_cipher})
 256
 257 have_signature="no"
 258 if test "x${have_gnutls}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 259    have_signature="yes"
 260    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 261 elif test "x${have_openssl}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 262    have_signature="yes"
 263    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 264 fi
 265
 266 AC_MSG_CHECKING(whether to activate signature support in eet)
 267 AC_MSG_RESULT(${have_signature})
 268
 269
 270 ### Checks for header files
 271
 272 AC_CHECK_HEADER([zlib.h],
 273    [dummy="yes"],
 274    [AC_MSG_ERROR("Cannot find zlib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 275
 276 AC_CHECK_HEADER([jpeglib.h],
 277    [dummy="yes"],
 278    [AC_MSG_ERROR("Cannot find jpeglib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 279
 280 AC_CHECK_HEADERS(netinet/in.h)
 281
 282 AC_CHECK_HEADER([fnmatch.h],
 283    [dummy="yes"],
 284    [AC_MSG_ERROR([Cannot find fnmatch.h. Make sure your CFLAGS environment variable contains include lines for the location of this file. MinGW users: see the INSTALL file])])
 285
 286
 287 ### Checks for types
 288
 289
 290 ### Checks for structures
 291
 292
 293 ### Checks for compiler characteristics
 294 AM_PROG_CC_C_O
 295 AC_C_CONST
 296 AC_C_INLINE
 297 AC_PROG_CC_STDC
 298 AC_C___ATTRIBUTE__
 299
 300 # Check whether the null pointer is zero on this arch
 301 AC_TRY_RUN(
 302    [
 303 #include <stdlib.h>
 304 int main (int argc, char **argv) {
 305   void *foo = NULL;
 306   int bar = (int)foo;
 307   return (int)foo;
 308 }
 309    ],
 310    [have_null="yes"],
 311    [have_null="no"],
 312    [
 313     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 314     have_null="yes"
 315    ])
 316 AC_MSG_CHECKING([value of the null pointer])
 317 AC_MSG_RESULT([${have_null}])
 318
 319 if test ! "x${have_null}" = "xyes" ; then
 320    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 321 fi
 322
 323 # These are needed for fmemopen/open_memstream
 324 AC_DEFINE(_GNU_SOURCE, , [Enable GNU extensions])
 325
 326 EET_CPPFLAGS=""
 327 EET_CFLAGS=""
 328 case "$host_os" in
 329    mingw32ce*)
 330       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 331       ;;
 332    cegcc*)
 333       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 334       EET_CFLAGS="-mwin32"
 335       ;;
 336 esac
 337 AC_SUBST(EET_CPPFLAGS)
 338 AC_SUBST(EET_CFLAGS)
 339
 340
 341 ### Checks for linker characteristics
 342
 343 # use --enable-auto-import on Windows
 344
 345 lt_enable_auto_import=""
 346 case "$host_os" in
 347    mingw* | cegcc*)
 348       lt_enable_auto_import="-Wl,--enable-auto-import"
 349       ;;
 350 esac
 351 AC_SUBST(lt_enable_auto_import)
 352
 353 # use --as-needed if supported
 354
 355 LDFLAGS_SAVE=${LDFLAGS}
 356 LDFLAGS="${LDFLAGS} -Wl,--as-needed"
 357
 358 AC_LINK_IFELSE(
 359    [AC_LANG_PROGRAM([[]], [])],
 360    [ld_as_needed="-Wl,--as-needed"],
 361    [ld_as_needed=""]
 362 )
 363
 364 LDFLAGS=${LDFLAGS_SAVE}
 365 AC_SUBST(ld_as_needed)
 366
 367
 368 ### Checks for library functions
 369 AC_FUNC_ALLOCA
 370
 371 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 372
 373 fnmatch_libs=""
 374 AC_CHECK_FUNCS([fnmatch], [res="yes"], [res="no"])
 375 if test "x$res" = "xno"; then
 376    AC_SEARCH_LIBS([fnmatch],
 377       [fnmatch evil iberty],
 378       [res="yes"],
 379       [res="no"])
 380    if test "x$res" = "xno"; then
 381       AC_MSG_ERROR([Cannot find fnmatch() in neither libc nor libfnmatch, nor libiberty, nor libevil])
 382    fi
 383    fnmatch_libs="${ac_cv_search_fnmatch}"
 384 fi
 385 AC_SUBST(fnmatch_libs)
 386
 387
 388 AC_SUBST(requirement_eet)
 389
 390 AC_OUTPUT([
 391 Makefile
 392 eet.pc
 393 doc/Makefile
 394 doc/eet.dox
 395 src/Makefile
 396 src/lib/Makefile
 397 src/bin/Makefile
 398 src/tests/Makefile
 399 README
 400 eet.spec
 401 ])
 402
 403
 404 #####################################################################
 405 ## Info
 406
 407 echo
 408 echo
 409 echo
 410 echo "------------------------------------------------------------------------"
 411 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 412 echo "------------------------------------------------------------------------"
 413 echo
 414 echo "Configuration Options Summary:"
 415 echo
 416 echo "  Gnutls...............: ${have_gnutls}"
 417 echo "  Openssl..............: ${have_openssl}"
 418 echo "    Cipher support.....: ${have_cipher}"
 419 echo "    Signature..........: ${have_signature}"
 420 echo
 421 echo "  Amalgamation.........: ${do_amalgamation}"
 422 echo "  Documentation........: ${build_doc}"
 423 echo "  Tests................: ${enable_tests}"
 424 echo "  Coverage.............: ${enable_coverage}"
 425 echo
 426 echo "  Old eet file format..: ${old_eet_file_format}"
 427 echo
 428 echo "  Compilation..........: make"
 429 echo
 430 echo "  Installation.........: make install"
 431 echo
 432 echo "    prefix.............: $prefix"
 433 echo