configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.36,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 25, 0, 25)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.36
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 PKG_CHECK_MODULES(DRM, libdrm)
 122 AC_SUBST(DRM_CFLAGS)
 123 AC_SUBST(DRM_LIBS)
 124
 125 PKG_CHECK_MODULES(DRM, libdrm-devel)
 126 AC_SUBST(DRM_DEVEL_CFLAGS)
 127 AC_SUBST(DRM_DEVEL_LIBS)
 128
 129 dnl *** checks for platform ***
 130 AG_GST_PLATFORM
 131
 132 dnl * hardware/architecture *
 133
 134 dnl common/m4/gst-arch.m4
 135 dnl check CPU type
 136 AG_GST_ARCH
 137
 138 dnl check for large file support
 139 dnl affected plugins must include config.h
 140 AC_SYS_LARGEFILE
 141
 142 dnl *** checks for programs ***
 143
 144 dnl find a compiler
 145 AC_PROG_CC
 146 AC_PROG_CC_STDC
 147
 148 dnl check if the compiler supports '-c' and '-o' options
 149 AM_PROG_CC_C_O
 150
 151 dnl determine if c++ is available on this system
 152 AC_PROG_CXX
 153 dnl CXX may be set to some default even if no c++ compiler is available
 154 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 155 AC_LANG_PUSH([C++])
 156 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 157 AC_LANG_POP([C++])
 158 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 159 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 160
 161 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 162 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 163
 164 dnl check for gobject-introspection
 165 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 166
 167 dnl check for documentation tools
 168 GTK_DOC_CHECK([1.3])
 169 AS_PATH_PYTHON([2.1])
 170 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 171
 172 dnl *** checks for libraries ***
 173
 174 dnl libm, for sin() etc.
 175 AC_CHECK_LIBM
 176 AC_SUBST(LIBM)
 177
 178 dnl *** checks for header files ***
 179
 180 dnl check if we have ANSI C header files
 181 AC_HEADER_STDC
 182
 183 dnl used in gst/ffmpegcolorspace/mem.c
 184 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 185 AC_CHECK_HEADERS([malloc.h])
 186
 187 ac_cppflags_save="$CPPFLAGS"
 188 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 189 AC_COMPILE_IFELSE(
 190   AC_LANG_PROGRAM([
 191 #include <libxml/HTMLparser.h>
 192                      ],[
 193 #ifndef LIBXML_HTML_ENABLED
 194 #error libxml2 has no HTML support
 195 #endif /* LIBXML_HTML_ENABLED */
 196                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 197 CPPFLAGS="$ac_cppflags_save"
 198 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 199
 200 dnl used in gst/tcp
 201 AC_CHECK_HEADERS([sys/socket.h],
 202   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 203 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 204
 205 dnl used in gst-libs/gst/rtsp
 206 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 207 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 208   WIN32_LIBS="-lws2_32"
 209   AC_SUBST(WIN32_LIBS)
 210 fi
 211
 212 dnl check for hstrerror, for gst-libs/gst/rtsp
 213 save_libs="$LIBS"
 214 AC_CHECK_FUNC(hstrerror, ,
 215     AC_CHECK_LIB(resolv, hstrerror, ,
 216         [AC_DEFINE(NO_HSTRERROR, 1,
 217              [Define if you have no native hstrerror() function.])]))
 218 HSTRERROR_LIBS=$LIBS
 219 AC_SUBST(HSTRERROR_LIBS)
 220 LIBS="$save_libs"
 221
 222 dnl used in gst-libs/gst/pbutils and associated unit test
 223 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 224
 225 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 226
 227 dnl ffmpegcolorspace includes _stdint.h
 228 dnl also, Windows does not have long long
 229 AX_CREATE_STDINT_H
 230
 231 dnl *** checks for functions ***
 232 AC_CHECK_FUNCS([localtime_r gmtime_r])
 233
 234 dnl *** checks for math functions ***
 235 LIBS_SAVE=$LIBS
 236 LIBS="$LIBS $LIBM"
 237 AC_CHECK_FUNCS(log2)
 238 LIBS=$LIBS_SAVE
 239
 240 dnl *** checks for types/defines ***
 241
 242 dnl Check for FIONREAD ioctl declaration
 243 dnl used in gst/tcp
 244 GST_CHECK_FIONREAD
 245
 246 dnl *** checks for structures ***
 247
 248 dnl *** checks for compiler characteristics ***
 249
 250 dnl *** checks for library functions ***
 251
 252 dnl check for fseeko()
 253 AC_FUNC_FSEEKO
 254
 255 dnl Check for fast float to int casting as defined in C99
 256 dnl used in gst-libs/gst/floatcast/floatcast.h
 257 save_libs=$LIBS
 258 LIBS="$LIBS $LIBM"
 259 AC_C99_FUNC_LRINT
 260 AC_C99_FUNC_LRINTF
 261 LIBS=$save_libs
 262
 263 dnl Check for a way to display the function name in debug output
 264 AG_GST_CHECK_FUNCTION
 265
 266 dnl *** checks for socket and nsl libraries ***
 267 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 268 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 269
 270 dnl *** checks for dependency libraries ***
 271
 272 dnl GLib is required
 273 AG_GST_GLIB_CHECK([2.24])
 274
 275 ORC_CHECK([0.4.11])
 276
 277 dnl checks for gstreamer
 278 dnl uninstalled is selected preferentially -- see pkg-config(1)
 279 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 280 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 281 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 282 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 283 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 284 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 285
 286 dnl Check for documentation xrefs
 287 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 288 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 289 AC_SUBST(GLIB_PREFIX)
 290 AC_SUBST(GST_PREFIX)
 291
 292 dnl GTK is optional and only used in examples
 293 HAVE_GTK=no
 294 HAVE_GTK_X11=no
 295 GTK_REQ=3.0.0
 296 if test "x$BUILD_EXAMPLES" = "xyes"; then
 297   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 298   dnl some examples need gtk+-x11
 299   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 300   AC_SUBST(GTK_LIBS)
 301   AC_SUBST(GTK_CFLAGS)
 302 fi
 303 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 304 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 305
 306 dnl QT is optional and only used in examples
 307 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 308   HAVE_QT_GV=yes
 309   HAVE_QT=yes
 310 ], [
 311   HAVE_QT_GV=no
 312   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 313 ])
 314 if test "x$HAVE_QT" = "xyes"; then
 315   AC_MSG_CHECKING([Qt moc])
 316   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 317   AC_MSG_RESULT($QT4_MOC)
 318   AC_SUBST(QT4_MOC)
 319 fi
 320 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 321 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 322
 323 dnl chck for linux headers needed by the joystick seek example
 324 AC_COMPILE_IFELSE(
 325 [
 326   AC_LANG_PROGRAM([
 327     #include <linux/input.h>
 328     #include <linux/joystick.h>
 329   ],[
 330     struct js_event js;
 331     js.type = JS_EVENT_AXIS;
 332   ])
 333 ], [
 334   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 335 ], [
 336   HAVE_LINUX_JOYSTICK_HEADERS="no"
 337 ])
 338 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 339
 340 dnl Check for -Bsymbolic-functions linker flag used to avoid
 341 dnl intra-library PLT jumps, if available.
 342 AC_ARG_ENABLE(Bsymbolic,
 343               [AC_HELP_STRING([--disable-Bsymbolic],
 344                               [avoid linking with -Bsymbolic])],,
 345               [SAVED_LDFLAGS="${LDFLAGS}"
 346                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 347                LDFLAGS=-Wl,-Bsymbolic-functions
 348                AC_TRY_LINK([], [int main (void) { return 0; }],
 349                            AC_MSG_RESULT(yes)
 350                            enable_Bsymbolic=yes,
 351                            AC_MSG_RESULT(no)
 352                            enable_Bsymbolic=no)
 353                LDFLAGS="${SAVED_LDFLAGS}"])
 354
 355
 356 dnl *** set variables based on configure arguments ***
 357
 358 dnl set license and copyright notice
 359 GST_LICENSE="LGPL"
 360 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 361 AC_SUBST(GST_LICENSE)
 362
 363 dnl set location of plugin directory
 364 AG_GST_SET_PLUGINDIR
 365
 366 dnl set release date/time
 367 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 368   ["${srcdir}/gst-plugins-base.doap"],
 369   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 370
 371 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 372 dnl make sure it doesn't complain about unused variables if debugging is disabled
 373 NO_WARNINGS=""
 374 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 375
 376 dnl define an ERROR_CFLAGS Makefile variable
 377 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 378 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 379     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 380     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 381     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 382     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 383
 384 dnl define an ERROR_CXXFLAGS Makefile variable
 385 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 386     -Wmissing-declarations -Wredundant-decls -Wundef
 387     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 388     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 389     -Wno-multichar $NO_WARNINGS])
 390
 391 dnl define correct level for debugging messages
 392 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 393
 394 dnl used in examples
 395 AG_GST_DEFAULT_ELEMENTS
 396
 397 dnl needed for encoding-target
 398 GST_DATADIR="$GST_PREFIX/share"
 399 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 400 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 401
 402 dnl behaviour of speex based audio resampler
 403 AC_MSG_CHECKING(which audio resample format to use for integer)
 404 AC_ARG_WITH([audioresample_format],
 405         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 406         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 407 AC_MSG_RESULT($ac_cv_audioresample_format)
 408 case $ac_cv_audioresample_format in
 409   int)
 410     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 411     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 412   ;;
 413   float)
 414     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 415     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 416   ;;
 417   auto)
 418     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 419     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 420 esac
 421
 422 dnl *** plug-ins to include ***
 423
 424 dnl these are all the gst plug-ins, compilable without additional libs
 425 AG_GST_CHECK_PLUGIN(adder)
 426 AG_GST_CHECK_PLUGIN(app)
 427 AG_GST_CHECK_PLUGIN(audioconvert)
 428 AG_GST_CHECK_PLUGIN(audiorate)
 429 AG_GST_CHECK_PLUGIN(audiotestsrc)
 430 AG_GST_CHECK_PLUGIN(encoding)
 431 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 432 AG_GST_CHECK_PLUGIN(gdp)
 433 AG_GST_CHECK_PLUGIN(playback)
 434 AG_GST_CHECK_PLUGIN(audioresample)
 435 AG_GST_CHECK_PLUGIN(subparse)
 436 AG_GST_CHECK_PLUGIN(tcp)
 437 AG_GST_CHECK_PLUGIN(typefind)
 438 AG_GST_CHECK_PLUGIN(videotestsrc)
 439 AG_GST_CHECK_PLUGIN(videorate)
 440 AG_GST_CHECK_PLUGIN(videoscale)
 441 AG_GST_CHECK_PLUGIN(volume)
 442
 443 dnl check for gstreamer core features (subsystems)
 444 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 445 dnl YeJin Cho : subparse needs xml for parsing smi, enalbe USE_XML
 446 dnl GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 447 dnl AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 448 dnl AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 449
 450 AM_CONDITIONAL(USE_XML, true)
 451 PKG_CHECK_MODULES(XML, libxml-2.0)
 452 AC_SUBST(XML_CFLAGS)
 453 AC_SUBST(XML_LIBS)
 454
 455 dnl disable plug-ins that require libxml2's HTML support if it is not available
 456 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 457   AG_GST_DISABLE_PLUGIN(subparse)
 458 fi
 459
 460 dnl disable plug-ins that require sys/socket.h if it is not available
 461 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 462   AG_GST_DISABLE_PLUGIN(tcp)
 463 fi
 464
 465 dnl iso-codes is optional, used by libgsttag
 466 AC_ARG_ENABLE(iso-codes,
 467 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 468 [case "${enableval}" in
 469   yes) enable_iso_codes=yes ;;
 470   no)  enable_iso_codes=no ;;
 471   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 472 esac
 473 ],
 474 [enable_iso_codes=yes]) dnl Default value
 475
 476 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 477 if test "x$enable_iso_codes" = "xyes"; then
 478   AC_MSG_RESULT([yes])
 479   have_iso_codes=no
 480   AC_MSG_CHECKING([whether iso-codes are available on this system])
 481   if $PKG_CONFIG iso-codes; then
 482     AC_MSG_RESULT([yes])
 483     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 484     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 485       AC_MSG_RESULT([yes])
 486       AC_MSG_CHECKING([for iso-codes prefix])
 487       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 488       if test -d "$ISO_CODES_PREFIX"; then
 489         AC_MSG_RESULT([yes])
 490         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 491         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 492         ISO_639_DOMAIN="iso_639"
 493         AC_MSG_CHECKING([ISO_639_DOMAIN])
 494         AC_MSG_RESULT([$ISO_639_DOMAIN])
 495         have_iso_codes=yes
 496         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 497         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 498         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 499         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 500       else
 501         AC_MSG_RESULT([no])
 502       fi
 503     else
 504       AC_MSG_RESULT([no])
 505     fi
 506   else
 507     AC_MSG_RESULT([no])
 508   fi
 509   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 510 else
 511   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 512   AM_CONDITIONAL(USE_ISO_CODES, false)
 513 fi
 514
 515 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 517 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 518   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 519       HAVE_ZLIB="yes"
 520     ], [
 521       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 522         HAVE_ZLIB="yes"
 523         ZLIB_LIBS="-lz"
 524         AC_SUBST(ZLIB_LIBS)
 525       ])
 526     ])
 527 ])
 528
 529 dnl *** sys plug-ins ***
 530
 531 echo
 532 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 533 echo
 534
 535 dnl *** X11 ***
 536 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 537 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 538                   [ximagesink], [
 539   AC_PATH_XTRA
 540   ac_cflags_save="$CFLAGS"
 541   ac_cppflags_save="$CPPFLAGS"
 542   CFLAGS="$CFLAGS $X_CFLAGS"
 543   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 544
 545   dnl now try to find the HEADER
 546   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 547
 548   if test "x$HAVE_X" = "xno"
 549   then
 550     AC_MSG_NOTICE([cannot find X11 development files])
 551   else
 552     dnl this is much more than we want
 553     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 554     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 555     dnl it does not add the libs; therefore we add them here
 556     X_LIBS="$X_LIBS -lX11"
 557     AC_SUBST(X_CFLAGS)
 558     AC_SUBST(X_LIBS)
 559   fi
 560   AC_SUBST(HAVE_X)
 561   CFLAGS="$ac_cflags_save"
 562   CPPFLAGS="$ac_cppflags_save"
 563 ])
 564
 565 dnl Check for Xv extension
 566 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 567 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 568                   [xvimagesink], [
 569   AG_GST_CHECK_XV
 570 ])
 571
 572 dnl check for X Shm
 573 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 574 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 575   if test x$HAVE_X = xyes; then
 576     AC_CHECK_LIB(Xext, XShmAttach,
 577                  HAVE_XSHM="yes", HAVE_XSHM="no",
 578                  $X_LIBS)
 579     if test "x$HAVE_XSHM" = "xyes"; then
 580       XSHM_LIBS="-lXext"
 581     else
 582       dnl On AIX, it is in XextSam instead, but we still need -lXext
 583       AC_CHECK_LIB(XextSam, XShmAttach,
 584                    HAVE_XSHM="yes", HAVE_XSHM="no",
 585                    $X_LIBS)
 586       if test "x$HAVE_XSHM" = "xyes"; then
 587         XSHM_LIBS="-lXext -lXextSam"
 588       fi
 589     fi
 590   fi
 591 ], , [
 592   AC_SUBST(HAVE_XSHM)
 593   AC_SUBST(XSHM_LIBS)
 594 ])
 595
 596 dnl v4l/v4l2 checks have been moved down because they require X
 597
 598 dnl *** Video 4 Linux ***
 599 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 600 dnl renamed to GST_V4L in accordance with V4L2 below
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 602 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 603   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 604 #include <sys/types.h>
 605 #define _LINUX_TIME_H
 606 #define __user
 607 #include <linux/videodev.h>
 608   ])
 609
 610   dnl we can build v4l without Xv, but then we won't have XOverlay support
 611   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 612   then
 613     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 614     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 615   fi
 616 ])
 617
 618 # Optional gudev for device probing
 619 AC_ARG_WITH([gudev],
 620   AC_HELP_STRING([--with-gudev],
 621     [device detection with gudev]),
 622   [],
 623   [with_gudev=check])
 624 if test x$HAVE_GST_V4L = xyes; then
 625   if test x$with_gudev != xno; then
 626       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 627           [ have_gudev=yes
 628             AC_DEFINE(HAVE_GUDEV, 1,
 629                [Whether gudev is available for device detection])
 630             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 631           ], [
 632           have_gudev=no
 633           ])
 634   else
 635     have_gudev=no
 636   fi
 637 fi
 638 AC_SUBST(GUDEV_CFLAGS)
 639 AC_SUBST(GUDEV_LIBS)
 640
 641 dnl *** ext plug-ins ***
 642 dnl keep this list sorted alphabetically !
 643
 644 if test "x$BUILD_EXTERNAL" = "xyes"; then
 645
 646 echo
 647 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 648 echo
 649
 650 dnl *** alsa ***
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 652 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 653   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 654     HAVE_ALSA="yes"
 655     AC_SUBST(ALSA_CFLAGS)
 656     AC_SUBST(ALSA_LIBS)
 657   ], [
 658     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 659   ])
 660 ])
 661
 662 dnl *** CDParanoia ***
 663 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 665 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 666   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 667     HAVE_CDPARANOIA="yes"
 668   ], [
 669     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 670                         cdda_open, -lm,
 671                         cdda_interface.h,
 672                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 673                         HEADER_DIR="no"
 674                         FOUND_CDPARANOIA="yes")
 675     if test "x$FOUND_CDPARANOIA" != "xyes";
 676     then
 677       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 678                           cdda_open, -lm,
 679                           cdda/cdda_interface.h,
 680                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 681                           HEADER_DIR="yes"
 682                           FOUND_CDPARANOIA="yes")
 683     fi
 684     if test "x$HEADER_DIR" = "xyes";
 685     then
 686       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 687                          defined if cdda headers are in a cdda/ directory)
 688     fi
 689     if test "x$FOUND_CDPARANOIA" = "xyes";
 690     then
 691       AC_CHECK_LIB(cdda_paranoia,
 692                    paranoia_cachemodel_size,
 693                    : ,
 694                    HAVE_CDPARANOIA=no,
 695                  [-lcdda_interface])
 696     fi
 697
 698     AC_SUBST(CDPARANOIA_LIBS)
 699   ])
 700 ])
 701 dnl FIXME : add second check somehow if that is necessary
 702 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 703 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 704
 705 dnl *** GNOME VFS ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 707 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 708   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 709       HAVE_GNOME_VFS="yes"
 710       AC_SUBST(GNOME_VFS_CFLAGS)
 711       AC_SUBST(GNOME_VFS_LIBS)
 712       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 713       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 714              [The GnomeVFS modules directory.])
 715     ],[
 716       HAVE_GNOME_VFS="no"
 717     ]
 718     )
 719 ])
 720
 721 dnl *** ivorbis ***
 722 dnl AM_PATH_IVORBIS only takes two options
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 724 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 725   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 726   if test $HAVE_IVORBIS = no
 727   then
 728     IVORBIS_LIBS=
 729     IVORBIS_CFLAGS=
 730     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 731       [IVORBIS_LIBS=-lvorbisidec
 732       HAVE_IVORBIS=yes
 733       case $host in
 734       arm-*-*)
 735         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 736       esac
 737       ],
 738       HAVE_IVORBIS=no)
 739     AC_SUBST(IVORBIS_LIBS)
 740     AC_SUBST(IVORBIS_CFLAGS)
 741   else
 742     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 743       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 744       USE_TREMOLO=no)
 745   fi
 746 ])
 747
 748 dnl *** libgio ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 750 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 751   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 752     HAVE_GIO="yes"
 753     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 754     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 755            [The GIO modules directory.])
 756     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 757     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 758            [The GIO library directory.])
 759   ], [
 760     HAVE_GIO="no"
 761   ])
 762   AC_SUBST(GIO_CFLAGS)
 763   AC_SUBST(GIO_LIBS)
 764   AC_SUBST(GIO_LDFLAGS)
 765 ])
 766
 767 dnl *** libvisual ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 769 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 770   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 771   if test $HAVE_LIBVISUAL = no
 772   then
 773     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 774     if test x$HAVE_LIBVISUAL = xyes; then
 775       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 776     fi
 777   else
 778     if test x$HAVE_LIBVISUAL = xyes; then
 779       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 780     fi
 781   fi
 782   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 783   if test x$LIBVIS_PLUGINSDIR != x; then
 784     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 785         "$LIBVIS_PLUGINSDIR",
 786         [directory in which the detected libvisual's plugins are located])
 787   fi
 788 ])
 789
 790 dnl *** ogg ***
 791 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 792 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 793   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 794   if test $HAVE_OGG = no
 795   then
 796     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 797     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 798   fi
 799 ])
 800
 801 dnl *** pango ***
 802 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 803 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 804   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 805 ])
 806
 807 dnl *** theora ***
 808 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 809 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 810   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 811 ])
 812
 813 dnl *** vorbis ***
 814 dnl AM_PATH_VORBIS only takes two options
 815 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 816 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 817   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 818   if test $HAVE_VORBIS = no
 819   then
 820     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 821     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 822   fi
 823 ])
 824
 825 if test "x$HAVE_VORBIS" = "xyes"; then
 826   ac_cflags_save="$CFLAGS"
 827   AC_COMPILE_IFELSE(
 828     AC_LANG_PROGRAM([
 829 #include <vorbis/codec.h>
 830                      ],[
 831 vorbis_dsp_state *v;
 832
 833 vorbis_synthesis_restart (v);
 834                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 835   if test "x$HAVE_VSR" = "xyes"; then
 836     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 837                        [defined if vorbis_synthesis_restart is present])
 838   fi
 839   CFLAGS="$ac_cflags_save"
 840 fi
 841
 842 else
 843
 844 dnl not building plugins with external dependencies,
 845 dnl but we still need to set the conditionals
 846 AM_CONDITIONAL(USE_ALSA, false)
 847 AM_CONDITIONAL(USE_CDPARANOIA, false)
 848 AM_CONDITIONAL(USE_GIO, false)
 849 AM_CONDITIONAL(USE_GNOME_VFS, false)
 850 AM_CONDITIONAL(USE_IVORBIS, false)
 851 AM_CONDITIONAL(USE_LIBVISUAL, false)
 852 AM_CONDITIONAL(USE_OGG, false)
 853 AM_CONDITIONAL(USE_PANGO, false)
 854 AM_CONDITIONAL(USE_THEORA, false)
 855 AM_CONDITIONAL(USE_VORBIS, false)
 856
 857 fi dnl of EXT plugins
 858
 859 dnl seeking needs freetype, so check for it here
 860 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 861   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 862 ])
 863 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 864 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 865 AC_SUBST(FT2_CFLAGS)
 866 AC_SUBST(FT2_LIBS)
 867
 868 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 869
 870 dnl Overview:
 871 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 872 dnl GST_*:              flags shared by built objects to link against GStreamer
 873 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 874 dnl                          (compare to other modules) or for i18n
 875 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 876 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 877 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 878 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 879
 880 dnl GST_OPTION_CFLAGS
 881 if test "x$USE_DEBUG" = xyes; then
 882    PROFILE_CFLAGS="-g"
 883 fi
 884 AC_SUBST(PROFILE_CFLAGS)
 885
 886 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 887   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 888   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 889 else
 890   DEPRECATED_CFLAGS=""
 891 fi
 892 AC_SUBST(DEPRECATED_CFLAGS)
 893
 894 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 895 dnl at make time with e.g. make ERROR_CFLAGS=""
 896 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 897 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 898 AC_SUBST(GST_OPTION_CFLAGS)
 899 AC_SUBST(GST_OPTION_CXXFLAGS)
 900
 901 dnl our libraries need to be versioned correctly
 902 AC_SUBST(GST_LT_LDFLAGS)
 903
 904 dnl GST_PLUGINS_BASE_CFLAGS
 905 dnl prefer internal headers to already installed ones
 906 dnl also add builddir include for enumtypes and marshal
 907 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 908 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 909
 910 dnl FIXME: do we want to rename to GST_ALL_* ?
 911 dnl add GST_OPTION_CFLAGS, but overridable
 912 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 913 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 914 AC_SUBST(GST_CFLAGS)
 915 AC_SUBST(GST_CXXFLAGS)
 916 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 917 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 918 AC_SUBST(GST_LIBS)
 919
 920 dnl LDFLAGS really should only contain flags, not libs - they get added before
 921 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 922 GST_ALL_LDFLAGS="-no-undefined"
 923 if test "x${enable_Bsymbolic}" = "xyes"; then
 924   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 925 fi
 926 AC_SUBST(GST_ALL_LDFLAGS)
 927
 928 dnl GST_LIB_LDFLAGS
 929 dnl linker flags shared by all libraries
 930 dnl LDFLAGS modifier defining exported symbols from built libraries
 931 dnl (export _gst_foo but not __gst_foo)
 932 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 933 AC_SUBST(GST_LIB_LDFLAGS)
 934
 935 dnl this really should only contain flags, not libs - they get added before
 936 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 937 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 938 AC_SUBST(GST_PLUGIN_LDFLAGS)
 939
 940 dnl use xfixes
 941 PKG_CHECK_MODULES(XFIXES, xfixes)
 942 AC_SUBST(XFIXES_CFLAGS)
 943 AC_SUBST(XFIXES_LIBS)
 944
 945 dnl use dri2proto
 946 PKG_CHECK_MODULES(DRI2PROTO, dri2proto)
 947 AC_SUBST(DRI2PROTO_CFLAGS)
 948 AC_SUBST(DRI2PROTO_LIBS)
 949
 950 dnl use dri2
 951 PKG_CHECK_MODULES(DRI2, libdri2)
 952 AC_SUBST(DRI2_CFLAGS)
 953 AC_SUBST(DRI2_LIBS)
 954
 955 dnl use tbm
 956 PKG_CHECK_MODULES(TBM, libtbm)
 957 AC_SUBST(TBM_CFLAGS)
 958 AC_SUBST(TBM_LIBS)
 959
 960 dnl Check Savs Codec Packages
 961 #PKG_CHECK_MODULES(SAVSCODEC_HEVC, libsavscodec-neon-hevc)
 962 #AC_SUBST(SAVSCODEC_HEVC_LDFLAGS)
 963 #AC_SUBST(SAVSCODEC_HEVC_CFLAGS)
 964 #AC_SUBST(SAVSCODEC_HEVC_LIBS)
 965
 966 dnl use utilX
 967 PKG_CHECK_MODULES(UTILX, utilX)
 968 AC_SUBST(UTILX_CFLAGS)
 969 AC_SUBST(UTILX_LIBS)
 970
 971 dnl use vconf
 972 PKG_CHECK_MODULES(VCONF, vconf)
 973 AC_SUBST(VCONF_CFLAGS)
 974 AC_SUBST(VCONF_LIBS)
 975
 976 dnl *** output files ***
 977
 978 AC_CONFIG_FILES(
 979 Makefile
 980 gst-plugins-base.spec
 981 gst/Makefile
 982 gst/adder/Makefile
 983 gst/app/Makefile
 984 gst/audioconvert/Makefile
 985 gst/audiorate/Makefile
 986 gst/audiotestsrc/Makefile
 987 gst/encoding/Makefile
 988 gst/ffmpegcolorspace/Makefile
 989 gst/gdp/Makefile
 990 gst/playback/Makefile
 991 gst/audioresample/Makefile
 992 gst/subparse/Makefile
 993 gst/tcp/Makefile
 994 gst/typefind/Makefile
 995 gst/videotestsrc/Makefile
 996 gst/videorate/Makefile
 997 gst/videoscale/Makefile
 998 gst/volume/Makefile
 999 sys/Makefile
1000 sys/ximage/Makefile
1001 sys/xvimage/Makefile
1002 sys/v4l/Makefile
1003 ext/Makefile
1004 ext/alsa/Makefile
1005 ext/cdparanoia/Makefile
1006 ext/gnomevfs/Makefile
1007 ext/gio/Makefile
1008 ext/libvisual/Makefile
1009 ext/ogg/Makefile
1010 ext/pango/Makefile
1011 ext/theora/Makefile
1012 ext/vorbis/Makefile
1013 gst-libs/Makefile
1014 gst-libs/gst/Makefile
1015 gst-libs/gst/audio/Makefile
1016 gst-libs/gst/app/Makefile
1017 gst-libs/gst/cdda/Makefile
1018 gst-libs/gst/fft/Makefile
1019 gst-libs/gst/floatcast/Makefile
1020 gst-libs/gst/interfaces/Makefile
1021 gst-libs/gst/netbuffer/Makefile
1022 gst-libs/gst/riff/Makefile
1023 gst-libs/gst/rtp/Makefile
1024 gst-libs/gst/rtsp/Makefile
1025 gst-libs/gst/sdp/Makefile
1026 gst-libs/gst/tag/Makefile
1027 gst-libs/gst/pbutils/Makefile
1028 gst-libs/gst/pbutils/gstpluginsbaseversion.h
1029 gst-libs/gst/video/Makefile
1030 tools/Makefile
1031 pkgconfig/Makefile
1032 pkgconfig/gstreamer-audio.pc
1033 pkgconfig/gstreamer-audio-uninstalled.pc
1034 pkgconfig/gstreamer-app.pc
1035 pkgconfig/gstreamer-app-uninstalled.pc
1036 pkgconfig/gstreamer-cdda.pc
1037 pkgconfig/gstreamer-cdda-uninstalled.pc
1038 pkgconfig/gstreamer-fft.pc
1039 pkgconfig/gstreamer-fft-uninstalled.pc
1040 pkgconfig/gstreamer-floatcast.pc
1041 pkgconfig/gstreamer-floatcast-uninstalled.pc
1042 pkgconfig/gstreamer-interfaces.pc
1043 pkgconfig/gstreamer-interfaces-uninstalled.pc
1044 pkgconfig/gstreamer-netbuffer.pc
1045 pkgconfig/gstreamer-netbuffer-uninstalled.pc
1046 pkgconfig/gstreamer-pbutils.pc
1047 pkgconfig/gstreamer-pbutils-uninstalled.pc
1048 pkgconfig/gstreamer-riff.pc
1049 pkgconfig/gstreamer-riff-uninstalled.pc
1050 pkgconfig/gstreamer-rtp.pc
1051 pkgconfig/gstreamer-rtp-uninstalled.pc
1052 pkgconfig/gstreamer-rtsp.pc
1053 pkgconfig/gstreamer-rtsp-uninstalled.pc
1054 pkgconfig/gstreamer-sdp.pc
1055 pkgconfig/gstreamer-sdp-uninstalled.pc
1056 pkgconfig/gstreamer-tag.pc
1057 pkgconfig/gstreamer-tag-uninstalled.pc
1058 pkgconfig/gstreamer-video.pc
1059 pkgconfig/gstreamer-video-uninstalled.pc
1060 pkgconfig/gstreamer-plugins-base.pc
1061 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1062 tests/Makefile
1063 tests/check/Makefile
1064 tests/examples/Makefile
1065 tests/examples/app/Makefile
1066 tests/examples/audio/Makefile
1067 tests/examples/dynamic/Makefile
1068 tests/examples/encoding/Makefile
1069 tests/examples/fft/Makefile
1070 tests/examples/gio/Makefile
1071 tests/examples/overlay/Makefile
1072 tests/examples/seek/Makefile
1073 tests/examples/snapshot/Makefile
1074 tests/examples/playrec/Makefile
1075 tests/examples/v4l/Makefile
1076 tests/files/Makefile
1077 tests/icles/Makefile
1078 tests/icles/playback/Makefile
1079 docs/Makefile
1080 docs/design/Makefile
1081 docs/libs/Makefile
1082 docs/plugins/Makefile
1083 docs/version.entities
1084 po/Makefile.in
1085 common/Makefile
1086 common/m4/Makefile
1087 m4/Makefile
1088 )
1089
1090 dnl Create the config.h file for Visual Studio builds
1091 dnl Beware of spaces and /'s in some of the shell variable contents.
1092 sed \
1093     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1094     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1095     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1096     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1097     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1098     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1099     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1100     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1101     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1102     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1103     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1104     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1105     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1106     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1107     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1108     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1109     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1110     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1111     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1112     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1113     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1114     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1115     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1116     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1117     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1118     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1119     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1120     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1121     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1122     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1123     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1124     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1125     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1126     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1127     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1128     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1129     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1130     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1131     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1132     config.h.in >win32/common/config.h-new
1133
1134
1135
1136 AC_OUTPUT
1137
1138 AG_GST_OUTPUT_PLUGINS
1139 ORC_OUTPUT
1140