configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.36,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 25, 0, 25)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.36
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.3])
 161 AS_PATH_PYTHON([2.1])
 162 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 AC_CHECK_LIBM
 168 AC_SUBST(LIBM)
 169
 170 dnl *** checks for header files ***
 171
 172 dnl check if we have ANSI C header files
 173 AC_HEADER_STDC
 174
 175 dnl used in gst/ffmpegcolorspace/mem.c
 176 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 177 AC_CHECK_HEADERS([malloc.h])
 178
 179 ac_cppflags_save="$CPPFLAGS"
 180 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 181 AC_COMPILE_IFELSE(
 182   AC_LANG_PROGRAM([
 183 #include <libxml/HTMLparser.h>
 184                      ],[
 185 #ifndef LIBXML_HTML_ENABLED
 186 #error libxml2 has no HTML support
 187 #endif /* LIBXML_HTML_ENABLED */
 188                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 189 CPPFLAGS="$ac_cppflags_save"
 190 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 191
 192 dnl used in gst/tcp
 193 AC_CHECK_HEADERS([sys/socket.h],
 194   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 195 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 196
 197 dnl used in gst-libs/gst/rtsp
 198 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 199 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 200   WIN32_LIBS="-lws2_32"
 201   AC_SUBST(WIN32_LIBS)
 202 fi
 203
 204 dnl check for hstrerror, for gst-libs/gst/rtsp
 205 save_libs="$LIBS"
 206 AC_CHECK_FUNC(hstrerror, ,
 207     AC_CHECK_LIB(resolv, hstrerror, ,
 208         [AC_DEFINE(NO_HSTRERROR, 1,
 209              [Define if you have no native hstrerror() function.])]))
 210 HSTRERROR_LIBS=$LIBS
 211 AC_SUBST(HSTRERROR_LIBS)
 212 LIBS="$save_libs"
 213
 214 dnl used in gst-libs/gst/pbutils and associated unit test
 215 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 216
 217 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 218
 219 dnl ffmpegcolorspace includes _stdint.h
 220 dnl also, Windows does not have long long
 221 AX_CREATE_STDINT_H
 222
 223 dnl *** checks for functions ***
 224 AC_CHECK_FUNCS([localtime_r gmtime_r])
 225
 226 dnl *** checks for math functions ***
 227 LIBS_SAVE=$LIBS
 228 LIBS="$LIBS $LIBM"
 229 AC_CHECK_FUNCS(log2)
 230 LIBS=$LIBS_SAVE
 231
 232 dnl *** checks for types/defines ***
 233
 234 dnl Check for FIONREAD ioctl declaration
 235 dnl used in gst/tcp
 236 GST_CHECK_FIONREAD
 237
 238 dnl *** checks for structures ***
 239
 240 dnl *** checks for compiler characteristics ***
 241
 242 dnl *** checks for library functions ***
 243
 244 dnl check for fseeko()
 245 AC_FUNC_FSEEKO
 246
 247 dnl Check for fast float to int casting as defined in C99
 248 dnl used in gst-libs/gst/floatcast/floatcast.h
 249 save_libs=$LIBS
 250 LIBS="$LIBS $LIBM"
 251 AC_C99_FUNC_LRINT
 252 AC_C99_FUNC_LRINTF
 253 LIBS=$save_libs
 254
 255 dnl Check for a way to display the function name in debug output
 256 AG_GST_CHECK_FUNCTION
 257
 258 dnl *** checks for socket and nsl libraries ***
 259 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 260 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 261
 262 dnl *** checks for dependency libraries ***
 263
 264 dnl GLib is required
 265 AG_GST_GLIB_CHECK([2.24])
 266
 267 ORC_CHECK([0.4.11])
 268
 269 dnl checks for gstreamer
 270 dnl uninstalled is selected preferentially -- see pkg-config(1)
 271 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 272 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 273 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 274 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 275 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 276 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 277
 278 dnl Check for documentation xrefs
 279 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 280 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 281 AC_SUBST(GLIB_PREFIX)
 282 AC_SUBST(GST_PREFIX)
 283
 284 dnl GTK is optional and only used in examples
 285 HAVE_GTK=no
 286 HAVE_GTK_X11=no
 287 GTK_REQ=3.0.0
 288 if test "x$BUILD_EXAMPLES" = "xyes"; then
 289   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 290   dnl some examples need gtk+-x11
 291   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 292   AC_SUBST(GTK_LIBS)
 293   AC_SUBST(GTK_CFLAGS)
 294 fi
 295 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 296 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 297
 298 dnl QT is optional and only used in examples
 299 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 300   HAVE_QT_GV=yes
 301   HAVE_QT=yes
 302 ], [
 303   HAVE_QT_GV=no
 304   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 305 ])
 306 if test "x$HAVE_QT" = "xyes"; then
 307   AC_MSG_CHECKING([Qt moc])
 308   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 309   AC_MSG_RESULT($QT4_MOC)
 310   AC_SUBST(QT4_MOC)
 311 fi
 312 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 313 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 314
 315 dnl chck for linux headers needed by the joystick seek example
 316 AC_COMPILE_IFELSE(
 317 [
 318   AC_LANG_PROGRAM([
 319     #include <linux/input.h>
 320     #include <linux/joystick.h>
 321   ],[
 322     struct js_event js;
 323     js.type = JS_EVENT_AXIS;
 324   ])
 325 ], [
 326   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 327 ], [
 328   HAVE_LINUX_JOYSTICK_HEADERS="no"
 329 ])
 330 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 331
 332 dnl Check for -Bsymbolic-functions linker flag used to avoid
 333 dnl intra-library PLT jumps, if available.
 334 AC_ARG_ENABLE(Bsymbolic,
 335               [AC_HELP_STRING([--disable-Bsymbolic],
 336                               [avoid linking with -Bsymbolic])],,
 337               [SAVED_LDFLAGS="${LDFLAGS}"
 338                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 339                LDFLAGS=-Wl,-Bsymbolic-functions
 340                AC_TRY_LINK([], [int main (void) { return 0; }],
 341                            AC_MSG_RESULT(yes)
 342                            enable_Bsymbolic=yes,
 343                            AC_MSG_RESULT(no)
 344                            enable_Bsymbolic=no)
 345                LDFLAGS="${SAVED_LDFLAGS}"])
 346
 347
 348 dnl *** set variables based on configure arguments ***
 349
 350 dnl set license and copyright notice
 351 GST_LICENSE="LGPL"
 352 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 353 AC_SUBST(GST_LICENSE)
 354
 355 dnl set location of plugin directory
 356 AG_GST_SET_PLUGINDIR
 357
 358 dnl set release date/time
 359 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 360   ["${srcdir}/gst-plugins-base.doap"],
 361   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 362
 363 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 364 dnl make sure it doesn't complain about unused variables if debugging is disabled
 365 NO_WARNINGS=""
 366 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 367
 368 dnl define an ERROR_CFLAGS Makefile variable
 369 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 370 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 371     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 372     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 373     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 374     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 375
 376 dnl define an ERROR_CXXFLAGS Makefile variable
 377 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 378     -Wmissing-declarations -Wredundant-decls -Wundef
 379     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 380     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 381     -Wno-multichar $NO_WARNINGS])
 382
 383 dnl define correct level for debugging messages
 384 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 385
 386 dnl used in examples
 387 AG_GST_DEFAULT_ELEMENTS
 388
 389 dnl needed for encoding-target
 390 GST_DATADIR="$GST_PREFIX/share"
 391 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 392 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 393
 394 dnl behaviour of speex based audio resampler
 395 AC_MSG_CHECKING(which audio resample format to use for integer)
 396 AC_ARG_WITH([audioresample_format],
 397         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 398         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 399 AC_MSG_RESULT($ac_cv_audioresample_format)
 400 case $ac_cv_audioresample_format in
 401   int)
 402     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 403     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 404   ;;
 405   float)
 406     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 407     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 408   ;;
 409   auto)
 410     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 411     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 412 esac
 413
 414 dnl *** plug-ins to include ***
 415
 416 dnl these are all the gst plug-ins, compilable without additional libs
 417 AG_GST_CHECK_PLUGIN(adder)
 418 AG_GST_CHECK_PLUGIN(app)
 419 AG_GST_CHECK_PLUGIN(audioconvert)
 420 AG_GST_CHECK_PLUGIN(audiorate)
 421 AG_GST_CHECK_PLUGIN(audiotestsrc)
 422 AG_GST_CHECK_PLUGIN(encoding)
 423 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 424 AG_GST_CHECK_PLUGIN(gdp)
 425 AG_GST_CHECK_PLUGIN(playback)
 426 AG_GST_CHECK_PLUGIN(audioresample)
 427 AG_GST_CHECK_PLUGIN(subparse)
 428 AG_GST_CHECK_PLUGIN(tcp)
 429 AG_GST_CHECK_PLUGIN(typefind)
 430 AG_GST_CHECK_PLUGIN(videotestsrc)
 431 AG_GST_CHECK_PLUGIN(videorate)
 432 AG_GST_CHECK_PLUGIN(videoscale)
 433 AG_GST_CHECK_PLUGIN(volume)
 434
 435 dnl check for gstreamer core features (subsystems)
 436 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 437 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 438 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 439 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 440
 441 dnl disable plug-ins that require libxml2's HTML support if it is not available
 442 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 443   AG_GST_DISABLE_PLUGIN(subparse)
 444 fi
 445
 446 dnl disable plug-ins that require sys/socket.h if it is not available
 447 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 448   AG_GST_DISABLE_PLUGIN(tcp)
 449 fi
 450
 451 dnl iso-codes is optional, used by libgsttag
 452 AC_ARG_ENABLE(iso-codes,
 453 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 454 [case "${enableval}" in
 455   yes) enable_iso_codes=yes ;;
 456   no)  enable_iso_codes=no ;;
 457   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 458 esac
 459 ],
 460 [enable_iso_codes=yes]) dnl Default value
 461
 462 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 463 if test "x$enable_iso_codes" = "xyes"; then
 464   AC_MSG_RESULT([yes])
 465   have_iso_codes=no
 466   AC_MSG_CHECKING([whether iso-codes are available on this system])
 467   if $PKG_CONFIG iso-codes; then
 468     AC_MSG_RESULT([yes])
 469     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 470     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 471       AC_MSG_RESULT([yes])
 472       AC_MSG_CHECKING([for iso-codes prefix])
 473       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 474       if test -d "$ISO_CODES_PREFIX"; then
 475         AC_MSG_RESULT([yes])
 476         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 477         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 478         ISO_639_DOMAIN="iso_639"
 479         AC_MSG_CHECKING([ISO_639_DOMAIN])
 480         AC_MSG_RESULT([$ISO_639_DOMAIN])
 481         have_iso_codes=yes
 482         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 483         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 484         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 485         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 486       else
 487         AC_MSG_RESULT([no])
 488       fi
 489     else
 490       AC_MSG_RESULT([no])
 491     fi
 492   else
 493     AC_MSG_RESULT([no])
 494   fi
 495   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 496 else
 497   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 498   AM_CONDITIONAL(USE_ISO_CODES, false)
 499 fi
 500
 501 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 503 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 504   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 505       HAVE_ZLIB="yes"
 506     ], [
 507       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 508         HAVE_ZLIB="yes"
 509         ZLIB_LIBS="-lz"
 510         AC_SUBST(ZLIB_LIBS)
 511       ])
 512     ])
 513 ])
 514
 515 dnl *** sys plug-ins ***
 516
 517 echo
 518 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 519 echo
 520
 521 dnl *** X11 ***
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 523 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 524                   [ximagesink], [
 525   AC_PATH_XTRA
 526   ac_cflags_save="$CFLAGS"
 527   ac_cppflags_save="$CPPFLAGS"
 528   CFLAGS="$CFLAGS $X_CFLAGS"
 529   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 530
 531   dnl now try to find the HEADER
 532   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 533
 534   if test "x$HAVE_X" = "xno"
 535   then
 536     AC_MSG_NOTICE([cannot find X11 development files])
 537   else
 538     dnl this is much more than we want
 539     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 540     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 541     dnl it does not add the libs; therefore we add them here
 542     X_LIBS="$X_LIBS -lX11"
 543     AC_SUBST(X_CFLAGS)
 544     AC_SUBST(X_LIBS)
 545   fi
 546   AC_SUBST(HAVE_X)
 547   CFLAGS="$ac_cflags_save"
 548   CPPFLAGS="$ac_cppflags_save"
 549 ])
 550
 551 dnl Check for Xv extension
 552 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 553 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 554                   [xvimagesink], [
 555   AG_GST_CHECK_XV
 556 ])
 557
 558 dnl check for X Shm
 559 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 560 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 561   if test x$HAVE_X = xyes; then
 562     AC_CHECK_LIB(Xext, XShmAttach,
 563                  HAVE_XSHM="yes", HAVE_XSHM="no",
 564                  $X_LIBS)
 565     if test "x$HAVE_XSHM" = "xyes"; then
 566       XSHM_LIBS="-lXext"
 567     else
 568       dnl On AIX, it is in XextSam instead, but we still need -lXext
 569       AC_CHECK_LIB(XextSam, XShmAttach,
 570                    HAVE_XSHM="yes", HAVE_XSHM="no",
 571                    $X_LIBS)
 572       if test "x$HAVE_XSHM" = "xyes"; then
 573         XSHM_LIBS="-lXext -lXextSam"
 574       fi
 575     fi
 576   fi
 577 ], , [
 578   AC_SUBST(HAVE_XSHM)
 579   AC_SUBST(XSHM_LIBS)
 580 ])
 581
 582 dnl v4l/v4l2 checks have been moved down because they require X
 583
 584 dnl *** Video 4 Linux ***
 585 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 586 dnl renamed to GST_V4L in accordance with V4L2 below
 587 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 588 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 589   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 590 #include <sys/types.h>
 591 #define _LINUX_TIME_H
 592 #define __user
 593 #include <linux/videodev.h>
 594   ])
 595
 596   dnl we can build v4l without Xv, but then we won't have XOverlay support
 597   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 598   then
 599     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 600     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 601   fi
 602 ])
 603
 604 # Optional gudev for device probing
 605 AC_ARG_WITH([gudev],
 606   AC_HELP_STRING([--with-gudev],
 607     [device detection with gudev]),
 608   [],
 609   [with_gudev=check])
 610 if test x$HAVE_GST_V4L = xyes; then
 611   if test x$with_gudev != xno; then
 612       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 613           [ have_gudev=yes
 614             AC_DEFINE(HAVE_GUDEV, 1,
 615                [Whether gudev is available for device detection])
 616             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 617           ], [
 618           have_gudev=no
 619           ])
 620   else
 621     have_gudev=no
 622   fi
 623 fi
 624 AC_SUBST(GUDEV_CFLAGS)
 625 AC_SUBST(GUDEV_LIBS)
 626
 627 dnl *** ext plug-ins ***
 628 dnl keep this list sorted alphabetically !
 629
 630 if test "x$BUILD_EXTERNAL" = "xyes"; then
 631
 632 echo
 633 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 634 echo
 635
 636 dnl *** alsa ***
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 638 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 639   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 640     HAVE_ALSA="yes"
 641     AC_SUBST(ALSA_CFLAGS)
 642     AC_SUBST(ALSA_LIBS)
 643   ], [
 644     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 645   ])
 646 ])
 647
 648 dnl *** CDParanoia ***
 649 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 650 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 651 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 652   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 653     HAVE_CDPARANOIA="yes"
 654   ], [
 655     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 656                         cdda_open, -lm,
 657                         cdda_interface.h,
 658                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 659                         HEADER_DIR="no"
 660                         FOUND_CDPARANOIA="yes")
 661     if test "x$FOUND_CDPARANOIA" != "xyes";
 662     then
 663       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 664                           cdda_open, -lm,
 665                           cdda/cdda_interface.h,
 666                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 667                           HEADER_DIR="yes"
 668                           FOUND_CDPARANOIA="yes")
 669     fi
 670     if test "x$HEADER_DIR" = "xyes";
 671     then
 672       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 673                          defined if cdda headers are in a cdda/ directory)
 674     fi
 675     if test "x$FOUND_CDPARANOIA" = "xyes";
 676     then
 677       AC_CHECK_LIB(cdda_paranoia,
 678                    paranoia_cachemodel_size,
 679                    : ,
 680                    HAVE_CDPARANOIA=no,
 681                  [-lcdda_interface])
 682     fi
 683
 684     AC_SUBST(CDPARANOIA_LIBS)
 685   ])
 686 ])
 687 dnl FIXME : add second check somehow if that is necessary
 688 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 689 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 690
 691 dnl *** GNOME VFS ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 693 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 694   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 695       HAVE_GNOME_VFS="yes"
 696       AC_SUBST(GNOME_VFS_CFLAGS)
 697       AC_SUBST(GNOME_VFS_LIBS)
 698       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 699       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 700              [The GnomeVFS modules directory.])
 701     ],[
 702       HAVE_GNOME_VFS="no"
 703     ]
 704     )
 705 ])
 706
 707 dnl *** ivorbis ***
 708 dnl AM_PATH_IVORBIS only takes two options
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 710 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 711   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 712   if test $HAVE_IVORBIS = no
 713   then
 714     IVORBIS_LIBS=
 715     IVORBIS_CFLAGS=
 716     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 717       [IVORBIS_LIBS=-lvorbisidec
 718       HAVE_IVORBIS=yes
 719       case $host in
 720       arm-*-*)
 721         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 722       esac
 723       ],
 724       HAVE_IVORBIS=no)
 725     AC_SUBST(IVORBIS_LIBS)
 726     AC_SUBST(IVORBIS_CFLAGS)
 727   else
 728     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 729       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 730       USE_TREMOLO=no)
 731   fi
 732 ])
 733
 734 dnl *** libgio ***
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 736 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 737   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 738     HAVE_GIO="yes"
 739     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 740     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 741            [The GIO modules directory.])
 742     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 743     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 744            [The GIO library directory.])
 745   ], [
 746     HAVE_GIO="no"
 747   ])
 748   AC_SUBST(GIO_CFLAGS)
 749   AC_SUBST(GIO_LIBS)
 750   AC_SUBST(GIO_LDFLAGS)
 751 ])
 752
 753 dnl *** libvisual ***
 754 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 755 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 756   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 757   if test $HAVE_LIBVISUAL = no
 758   then
 759     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 760     if test x$HAVE_LIBVISUAL = xyes; then
 761       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 762     fi
 763   else
 764     if test x$HAVE_LIBVISUAL = xyes; then
 765       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 766     fi
 767   fi
 768   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 769   if test x$LIBVIS_PLUGINSDIR != x; then
 770     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 771         "$LIBVIS_PLUGINSDIR",
 772         [directory in which the detected libvisual's plugins are located])
 773   fi
 774 ])
 775
 776 dnl *** ogg ***
 777 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 778 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 779   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 780   if test $HAVE_OGG = no
 781   then
 782     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 783     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 784   fi
 785 ])
 786
 787 dnl *** pango ***
 788 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 789 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 790   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 791 ])
 792
 793 dnl *** theora ***
 794 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 795 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 796   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 797 ])
 798
 799 dnl *** vorbis ***
 800 dnl AM_PATH_VORBIS only takes two options
 801 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 802 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 803   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 804   if test $HAVE_VORBIS = no
 805   then
 806     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 807     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 808   fi
 809 ])
 810
 811 if test "x$HAVE_VORBIS" = "xyes"; then
 812   ac_cflags_save="$CFLAGS"
 813   AC_COMPILE_IFELSE(
 814     AC_LANG_PROGRAM([
 815 #include <vorbis/codec.h>
 816                      ],[
 817 vorbis_dsp_state *v;
 818
 819 vorbis_synthesis_restart (v);
 820                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 821   if test "x$HAVE_VSR" = "xyes"; then
 822     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 823                        [defined if vorbis_synthesis_restart is present])
 824   fi
 825   CFLAGS="$ac_cflags_save"
 826 fi
 827
 828 else
 829
 830 dnl not building plugins with external dependencies,
 831 dnl but we still need to set the conditionals
 832 AM_CONDITIONAL(USE_ALSA, false)
 833 AM_CONDITIONAL(USE_CDPARANOIA, false)
 834 AM_CONDITIONAL(USE_GIO, false)
 835 AM_CONDITIONAL(USE_GNOME_VFS, false)
 836 AM_CONDITIONAL(USE_IVORBIS, false)
 837 AM_CONDITIONAL(USE_LIBVISUAL, false)
 838 AM_CONDITIONAL(USE_OGG, false)
 839 AM_CONDITIONAL(USE_PANGO, false)
 840 AM_CONDITIONAL(USE_THEORA, false)
 841 AM_CONDITIONAL(USE_VORBIS, false)
 842
 843 fi dnl of EXT plugins
 844
 845 dnl seeking needs freetype, so check for it here
 846 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 847   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 848 ])
 849 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 850 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 851 AC_SUBST(FT2_CFLAGS)
 852 AC_SUBST(FT2_LIBS)
 853
 854 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 855
 856 dnl Overview:
 857 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 858 dnl GST_*:              flags shared by built objects to link against GStreamer
 859 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 860 dnl                          (compare to other modules) or for i18n
 861 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 862 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 863 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 864 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 865
 866 dnl GST_OPTION_CFLAGS
 867 if test "x$USE_DEBUG" = xyes; then
 868    PROFILE_CFLAGS="-g"
 869 fi
 870 AC_SUBST(PROFILE_CFLAGS)
 871
 872 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 873   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 874   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 875 else
 876   DEPRECATED_CFLAGS=""
 877 fi
 878 AC_SUBST(DEPRECATED_CFLAGS)
 879
 880 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 881 dnl at make time with e.g. make ERROR_CFLAGS=""
 882 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 883 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 884 AC_SUBST(GST_OPTION_CFLAGS)
 885 AC_SUBST(GST_OPTION_CXXFLAGS)
 886
 887 dnl our libraries need to be versioned correctly
 888 AC_SUBST(GST_LT_LDFLAGS)
 889
 890 dnl GST_PLUGINS_BASE_CFLAGS
 891 dnl prefer internal headers to already installed ones
 892 dnl also add builddir include for enumtypes and marshal
 893 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 894 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 895
 896 dnl FIXME: do we want to rename to GST_ALL_* ?
 897 dnl add GST_OPTION_CFLAGS, but overridable
 898 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 899 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 900 AC_SUBST(GST_CFLAGS)
 901 AC_SUBST(GST_CXXFLAGS)
 902 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 903 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 904 AC_SUBST(GST_LIBS)
 905
 906 dnl LDFLAGS really should only contain flags, not libs - they get added before
 907 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 908 GST_ALL_LDFLAGS="-no-undefined"
 909 if test "x${enable_Bsymbolic}" = "xyes"; then
 910   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 911 fi
 912 AC_SUBST(GST_ALL_LDFLAGS)
 913
 914 dnl GST_LIB_LDFLAGS
 915 dnl linker flags shared by all libraries
 916 dnl LDFLAGS modifier defining exported symbols from built libraries
 917 dnl (export _gst_foo but not __gst_foo)
 918 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 919 AC_SUBST(GST_LIB_LDFLAGS)
 920
 921 dnl this really should only contain flags, not libs - they get added before
 922 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 923 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 924 AC_SUBST(GST_PLUGIN_LDFLAGS)
 925
 926 dnl *** output files ***
 927
 928 AC_CONFIG_FILES(
 929 Makefile
 930 gst-plugins-base.spec
 931 gst/Makefile
 932 gst/adder/Makefile
 933 gst/app/Makefile
 934 gst/audioconvert/Makefile
 935 gst/audiorate/Makefile
 936 gst/audiotestsrc/Makefile
 937 gst/encoding/Makefile
 938 gst/ffmpegcolorspace/Makefile
 939 gst/gdp/Makefile
 940 gst/playback/Makefile
 941 gst/audioresample/Makefile
 942 gst/subparse/Makefile
 943 gst/tcp/Makefile
 944 gst/typefind/Makefile
 945 gst/videotestsrc/Makefile
 946 gst/videorate/Makefile
 947 gst/videoscale/Makefile
 948 gst/volume/Makefile
 949 sys/Makefile
 950 sys/ximage/Makefile
 951 sys/xvimage/Makefile
 952 sys/v4l/Makefile
 953 ext/Makefile
 954 ext/alsa/Makefile
 955 ext/cdparanoia/Makefile
 956 ext/gnomevfs/Makefile
 957 ext/gio/Makefile
 958 ext/libvisual/Makefile
 959 ext/ogg/Makefile
 960 ext/pango/Makefile
 961 ext/theora/Makefile
 962 ext/vorbis/Makefile
 963 gst-libs/Makefile
 964 gst-libs/gst/Makefile
 965 gst-libs/gst/audio/Makefile
 966 gst-libs/gst/app/Makefile
 967 gst-libs/gst/cdda/Makefile
 968 gst-libs/gst/fft/Makefile
 969 gst-libs/gst/floatcast/Makefile
 970 gst-libs/gst/interfaces/Makefile
 971 gst-libs/gst/netbuffer/Makefile
 972 gst-libs/gst/riff/Makefile
 973 gst-libs/gst/rtp/Makefile
 974 gst-libs/gst/rtsp/Makefile
 975 gst-libs/gst/sdp/Makefile
 976 gst-libs/gst/tag/Makefile
 977 gst-libs/gst/pbutils/Makefile
 978 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 979 gst-libs/gst/video/Makefile
 980 tools/Makefile
 981 pkgconfig/Makefile
 982 pkgconfig/gstreamer-audio.pc
 983 pkgconfig/gstreamer-audio-uninstalled.pc
 984 pkgconfig/gstreamer-app.pc
 985 pkgconfig/gstreamer-app-uninstalled.pc
 986 pkgconfig/gstreamer-cdda.pc
 987 pkgconfig/gstreamer-cdda-uninstalled.pc
 988 pkgconfig/gstreamer-fft.pc
 989 pkgconfig/gstreamer-fft-uninstalled.pc
 990 pkgconfig/gstreamer-floatcast.pc
 991 pkgconfig/gstreamer-floatcast-uninstalled.pc
 992 pkgconfig/gstreamer-interfaces.pc
 993 pkgconfig/gstreamer-interfaces-uninstalled.pc
 994 pkgconfig/gstreamer-netbuffer.pc
 995 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 996 pkgconfig/gstreamer-pbutils.pc
 997 pkgconfig/gstreamer-pbutils-uninstalled.pc
 998 pkgconfig/gstreamer-riff.pc
 999 pkgconfig/gstreamer-riff-uninstalled.pc
1000 pkgconfig/gstreamer-rtp.pc
1001 pkgconfig/gstreamer-rtp-uninstalled.pc
1002 pkgconfig/gstreamer-rtsp.pc
1003 pkgconfig/gstreamer-rtsp-uninstalled.pc
1004 pkgconfig/gstreamer-sdp.pc
1005 pkgconfig/gstreamer-sdp-uninstalled.pc
1006 pkgconfig/gstreamer-tag.pc
1007 pkgconfig/gstreamer-tag-uninstalled.pc
1008 pkgconfig/gstreamer-video.pc
1009 pkgconfig/gstreamer-video-uninstalled.pc
1010 pkgconfig/gstreamer-plugins-base.pc
1011 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1012 tests/Makefile
1013 tests/check/Makefile
1014 tests/examples/Makefile
1015 tests/examples/app/Makefile
1016 tests/examples/audio/Makefile
1017 tests/examples/dynamic/Makefile
1018 tests/examples/encoding/Makefile
1019 tests/examples/fft/Makefile
1020 tests/examples/gio/Makefile
1021 tests/examples/overlay/Makefile
1022 tests/examples/seek/Makefile
1023 tests/examples/snapshot/Makefile
1024 tests/examples/playrec/Makefile
1025 tests/examples/v4l/Makefile
1026 tests/files/Makefile
1027 tests/icles/Makefile
1028 tests/icles/playback/Makefile
1029 docs/Makefile
1030 docs/design/Makefile
1031 docs/libs/Makefile
1032 docs/plugins/Makefile
1033 docs/version.entities
1034 po/Makefile.in
1035 common/Makefile
1036 common/m4/Makefile
1037 m4/Makefile
1038 )
1039
1040 dnl Create the config.h file for Visual Studio builds
1041 dnl Beware of spaces and /'s in some of the shell variable contents.
1042 sed \
1043     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1044     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1045     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1046     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1047     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1048     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1049     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1050     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1051     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1052     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1053     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1054     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1055     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1056     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1057     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1058     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1059     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1060     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1061     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1062     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1063     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1064     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1065     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1066     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1067     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1068     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1069     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1070     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1071     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1072     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1073     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1074     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1075     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1076     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1077     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1078     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1079     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1080     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1081     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1082     config.h.in >win32/common/config.h-new
1083
1084
1085
1086 AC_OUTPUT
1087
1088 AG_GST_OUTPUT_PLUGINS
1089 ORC_OUTPUT
1090