libavcodec/arm/dcadsp_neon.S

   1 /*
   2  * Copyright (c) 2010 Mans Rullgard <mans@mansr.com>
   3  *
   4  * This file is part of FFmpeg.
   5  *
   6  * FFmpeg is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU Lesser General Public
   8  * License as published by the Free Software Foundation; either
   9  * version 2.1 of the License, or (at your option) any later version.
  10  *
  11  * FFmpeg is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14  * Lesser General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU Lesser General Public
  17  * License along with FFmpeg; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  19  */
  20
  21 #include "asm.S"
  22
  23 function ff_dca_lfe_fir_neon, export=1
  24         push            {r4-r6,lr}
  25
  26         add             r4,  r0,  r3,  lsl #2   @ out2
  27         add             r5,  r2,  #256*4-16     @ cf1
  28         sub             r1,  r1,  #12
  29         cmp             r3,  #32
  30         moveq           r6,  #256/32
  31         movne           r6,  #256/64
  32 NOVFP   vldr            s0,  [sp, #16]          @ scale
  33         mov             lr,  #-16
  34 1:
  35         vmov.f32        q2,  #0.0               @ v0
  36         vmov.f32        q3,  #0.0               @ v1
  37         mov             r12, r6
  38 2:
  39         vld1.32         {q8},     [r2,:128]!    @ cf0
  40         vld1.32         {q9},     [r5,:128], lr @ cf1
  41         vld1.32         {q1},     [r1], lr      @ in
  42         subs            r12, r12, #4
  43         vrev64.32       q10, q8
  44         vmla.f32        q3,  q1,  q9
  45         vmla.f32        d4,  d2,  d21
  46         vmla.f32        d5,  d3,  d20
  47         bne             2b
  48
  49         add             r1,  r1,  r6,  lsl #2
  50         subs            r3,  r3,  #1
  51         vadd.f32        d4,  d4,  d5
  52         vadd.f32        d6,  d6,  d7
  53         vpadd.f32       d4,  d4,  d6
  54         vmul.f32        d5,  d4,  d0[0]
  55         vst1.32         {d5[0]},  [r0,:32]!
  56         vst1.32         {d5[1]},  [r4,:32]!
  57         bne             1b
  58
  59         pop             {r4-r6,pc}
  60 endfunc