m4/perl.m4

   1 #serial 8
   2
   3 dnl From Jim Meyering.
   4 dnl Find a new-enough version of Perl.
   5
   6 # Copyright (C) 1998-2001, 2003, 2004, 2007 Free Software Foundation, Inc.
   7 #
   8 # This file is free software; the Free Software Foundation
   9 # gives unlimited permission to copy and/or distribute it,
  10 # with or without modifications, as long as this notice is preserved.
  11
  12 AC_DEFUN([gl_PERL],
  13 [
  14   dnl FIXME: don't hard-code 5.005
  15   AC_MSG_CHECKING([for perl5.005 or newer])
  16   if test "${PERL+set}" = set; then
  17     # `PERL' is set in the user's environment.
  18     candidate_perl_names="$PERL"
  19     perl_specified=yes
  20   else
  21     candidate_perl_names='perl perl5'
  22     perl_specified=no
  23   fi
  24
  25   found=no
  26   AC_SUBST(PERL)
  27   PERL="$am_missing_run perl"
  28   for perl in $candidate_perl_names; do
  29     # Run test in a subshell; some versions of sh will print an error if
  30     # an executable is not found, even if stderr is redirected.
  31     if ( $perl -e 'require 5.005; use File::Compare' ) > /dev/null 2>&1; then
  32       PERL=$perl
  33       found=yes
  34       break
  35     fi
  36   done
  37
  38   AC_MSG_RESULT($found)
  39   test $found = no && AC_MSG_WARN([
  40 WARNING: You don't seem to have perl5.005 or newer installed, or you lack
  41          a usable version of the Perl File::Compare module.  As a result,
  42          you may be unable to run a few tests or to regenerate certain
  43          files if you modify the sources from which they are derived.
  44 ] )
  45 ])