m4/boottime.m4

   1 # boottime.m4 serial 3
   2 # Determine whether this system has infrastructure for obtaining the boot time.
   3
   4 # Copyright (C) 1996, 2000, 2002, 2003, 2004, 2006 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software Foundation,
  18 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  19
  20 # GNULIB_BOOT_TIME([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  21 * ----------------------------------------------------------
  22 AC_DEFUN([GNULIB_BOOT_TIME],
  23 [
  24   AC_CHECK_FUNCS(sysctl)
  25   AC_CHECK_HEADERS_ONCE(sys/param.h)
  26   AC_CHECK_HEADERS(sys/sysctl.h, [], [],
  27     [AC_INCLUDES_DEFAULT
  28      [#if HAVE_SYS_PARAM_H
  29        #include <sys/param.h>
  30       #endif]])
  31   AC_CHECK_HEADERS_ONCE(utmp.h utmpx.h OS.h)
  32   AC_CACHE_CHECK(
  33     [whether we can get the system boot time],
  34     [gnulib_cv_have_boot_time],
  35     [
  36       AC_COMPILE_IFELSE(
  37        [AC_LANG_PROGRAM(
  38 [AC_INCLUDES_DEFAULT
  39 #if HAVE_SYSCTL && HAVE_SYS_SYSCTL_H
  40 # if HAVE_SYS_PARAM_H
  41 #  include <sys/param.h> /* needed for OpenBSD 3.0 */
  42 # endif
  43 # include <sys/sysctl.h>
  44 #endif
  45 #if HAVE_UTMPX_H
  46 # include <utmpx.h>
  47 #elif HAVE_UTMP_H
  48 # include <utmp.h>
  49 #endif
  50 #if HAVE_OS_H
  51 # include <OS.h>
  52 #endif
  53 ],
  54 [[
  55 #if defined BOOT_TIME || (defined CTL_KERN && defined KERN_BOOTTIME) || HAVE_OS_H
  56 /* your system *does* have the infrastructure to determine boot time */
  57 #else
  58 please_tell_us_how_to_determine_boot_time_on_your_system
  59 #endif
  60 ]])],
  61        gnulib_cv_have_boot_time=yes,
  62        gnulib_cv_have_boot_time=no)
  63     ])
  64   AS_IF([test $gnulib_cv_have_boot_time = yes], [$1], [$2])
  65 ])