configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.61)
   3 AC_INIT([psmisc],[22.6])
   4 AC_CONFIG_SRCDIR([src/comm.h])
   5 AC_CONFIG_HEADER([config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AM_INIT_AUTOMAKE([1.10])
   8
   9 dnl Checks for programs.
  10 AC_PROG_CXX
  11 AC_PROG_CC
  12 #AC_PROG_CPP
  13 AC_PROG_MAKE_SET
  14 AC_PROG_LN_S
  15
  16 dnl checks for options
  17 AC_SUBST([WITH_SELINUX])
  18 AC_ARG_ENABLE([selinux],
  19   [AS_HELP_STRING([--enable-selinux], [Enable Security-Enhanced Linux features])],
  20   [enable_selinux=$enableval],
  21   [enable_selinux="no"])
  22 if test "$enable_selinux" = "yes"; then
  23   AC_DEFINE([WITH_SELINUX], [1], [Use Security-Enhanced Linux features])
  24   AC_CHECK_LIB([selinux], [getfilecon], [SELINUX_LIB=-lselinux], [
  25      AC_MSG_ERROR([Cannot find selinux static library]) ])
  26 fi
  27 AC_SUBST([SELINUX_LIB])
  28
  29 dnl ipv4 only option
  30 AC_SUBST([WITH_IPV6])
  31 AC_ARG_ENABLE([ipv6],
  32   [AS_HELP_STRING([--disable-ipv6], [Disable IPv6 checks (for uClibc)])],
  33   [enable_ipv6=$enableval],
  34   [enable_ipv6="yes"])
  35 if test "$enable_ipv6" = "yes"; then
  36   AC_DEFINE([WITH_IPV6], [1], [Use IPv6 checks])
  37 fi
  38
  39 dnl Checks for libraries.
  40 AC_CHECK_LIB([tinfo], [tgetent], [TERMCAP_LIB=-ltinfo],
  41   [ AC_CHECK_LIB([ncurses], [tgetent], [TERMCAP_LIB=-lncurses],
  42     [ AC_CHECK_LIB([termcap], [tgetent], [TERMCAP_LIB=-ltermcap],
  43       [ AC_MSG_ERROR([Cannot find tinfo, ncurses or termcap libraries])
  44           ] )
  45         ] )
  46   ] )
  47 AC_SUBST([TERMCAP_LIB])
  48
  49 dnl Checks for header files.
  50 AC_HEADER_DIRENT
  51 AC_HEADER_STDC
  52 AC_HEADER_SYS_WAIT
  53 AC_CHECK_HEADERS([arpa/inet.h fcntl.h langinfo.h libintl.h limits.h locale.h mntent.h netdb.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h termios.h unistd.h])
  54
  55 dnl Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_CONST
  57 AC_TYPE_PID_T
  58 AC_TYPE_SIZE_T
  59 AC_CHECK_MEMBERS([struct stat.st_rdev])
  60 AC_TYPE_UID_T
  61 AC_CHECK_MEMBERS([struct user_regs_struct.orig_eax,
  62                 struct user_regs_struct.eax,
  63                 struct user_regs_struct.ebx,
  64                 struct user_regs_struct.ecx,
  65                 struct user_regs_struct.edx,
  66                 struct user_regs_struct.orig_rax,
  67                 struct user_regs_struct.rax,
  68                 struct user_regs_struct.rdi,
  69                 struct user_regs_struct.rsi,
  70                 struct user_regs_struct.rdx], [],[], [#include <linux/user.h>])
  71 AC_CHECK_MEMBERS([struct pt_regs.orig_gpr3,
  72                 struct pt_regs.gpr], [],[], [#include <linux/ptrace.h>])
  73 AM_CONDITIONAL(WANT_PEEKFD_I386,
  74  test $ac_cv_member_struct_user_regs_struct_orig_eax = yes &&
  75    test $ac_cv_member_struct_user_regs_struct_eax = yes &&
  76    test $ac_cv_member_struct_user_regs_struct_ebx = yes &&
  77    test $ac_cv_member_struct_user_regs_struct_ecx = yes &&
  78    test $ac_cv_member_struct_user_regs_struct_edx = yes )
  79 AM_CONDITIONAL(WANT_PEEKFD_X86_64,
  80  test $ac_cv_member_struct_user_regs_struct_orig_rax = yes &&
  81    test $ac_cv_member_struct_user_regs_struct_rax = yes &&
  82    test $ac_cv_member_struct_user_regs_struct_rdi = yes &&
  83    test $ac_cv_member_struct_user_regs_struct_rsi = yes &&
  84    test $ac_cv_member_struct_user_regs_struct_rdx = yes )
  85 AM_CONDITIONAL(WANT_PEEKFD_PPC,
  86    test $ac_cv_member_struct_pt_regs_orig_gpr3 = yes &&
  87    test $ac_cv_member_struct_pt_regs_gpr = yes )
  88
  89 dnl Check for language stuff
  90 AM_GNU_GETTEXT([external])
  91 AM_GNU_GETTEXT_VERSION([0.16.1])
  92
  93 dnl Checks for library functions.
  94 AC_FUNC_CLOSEDIR_VOID
  95 AC_FUNC_GETMNTENT
  96 AC_PROG_GCC_TRADITIONAL
  97 AC_FUNC_LSTAT
  98 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
  99 AC_FUNC_MALLOC
 100 AC_FUNC_MEMCMP
 101 AC_FUNC_REALLOC
 102 AC_FUNC_STAT
 103 AC_CHECK_FUNCS([atexit getmntent memset nl_langinfo regcomp rpmatch setlocale socket strcasecmp strchr strdup strerror strpbrk strrchr strtoul])
 104
 105 dnl Checks for Large File System
 106 AC_SYS_LARGEFILE
 107
 108 AC_CONFIG_FILES([Makefile
 109                  doc/Makefile
 110                  src/Makefile
 111                  icons/Makefile
 112                  po/Makefile.in])
 113 AC_OUTPUT