gdb/testsuite/gdb.xml/tdesc-regs.exp

   1 # Copyright 2007, 2008, 2009 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 if {[gdb_skip_xml_test]} {
  17     unsupported "tdesc-regs.exp"
  18     return -1
  19 }
  20
  21 gdb_start
  22
  23 # To test adding registers, we need a core set of registers for this
  24 # architecture, or the description will be rejected.
  25
  26 set core-regs ""
  27 set regdir ""
  28 switch -glob -- [istarget] {
  29     "*arm-*-*" {
  30         set core-regs {arm-core.xml}
  31     }
  32     "xscale-*-*" {
  33         set core-regs {arm-core.xml}
  34     }
  35     "mips*-*-*" {
  36         set core-regs {mips-cpu.xml mips-cp0.xml mips-fpu.xml}
  37     }
  38     "powerpc*-*-*" {
  39         set regdir "rs6000/"
  40         set core-regs {power-core.xml}
  41     }
  42     "spu*-*-*" {
  43         # This may be either the spu-linux-nat target, or the Cell/B.E.
  44         # multi-architecture debugger in SPU standalone executable mode.
  45         # We do not support XML register sets on SPU in either case.
  46         # However, the multi-arch debugger will accept XML registers sets
  47         # (on the PowerPC side), hence the test below would fail.
  48         # Simply return unconditionally here.
  49         unsupported "register tests"
  50         return 0
  51     }
  52 }
  53
  54 # If no core registers were specified, assume this target does not
  55 # support target-defined registers.  Verify that we get a warning if
  56 # we try to use them.  This not only tests the warning, but also
  57 # reminds maintainers to add test support when they add the feature.
  58 if {[string equal ${core-regs} ""]} {
  59     gdb_test "set tdesc file $srcdir/$subdir/single-reg.xml" \
  60         "warning: Target-supplied registers are not supported.*" \
  61         "set tdesc file single-reg.xml"
  62     unsupported "register tests"
  63     return 0
  64 }
  65
  66 # Otherwise, we support both XML and target defined registers.
  67
  68 # Make sure we reject a description missing standard registers,
  69 # like the PC.
  70 gdb_test "set tdesc file $srcdir/$subdir/single-reg.xml" \
  71     "warning: Architecture rejected target-supplied description" \
  72     "set tdesc file single-reg.xml"
  73
  74 # Copy the core registers into the objdir if necessary, so that they
  75 # will be found by <xi:include>.
  76 foreach src ${core-regs} {
  77     file delete "$src"
  78     file copy "$srcdir/../features/$regdir$src" "$src"
  79 }
  80
  81 # Similarly, we need to copy files under test into the objdir.
  82 proc load_description { file errmsg } {
  83     global srcdir
  84     global subdir
  85     global gdb_prompt
  86     global core-regs
  87
  88     file delete "regs.xml"
  89     set ifd [open "$srcdir/$subdir/$file" r]
  90     set ofd [open "regs.xml" w]
  91     while {[gets $ifd line] >= 0} {
  92         if {[regexp {<xi:include href="core-regs.xml"/>} $line]} {
  93             foreach src ${core-regs} {
  94                 puts $ofd "  <xi:include href=\"$src\"/>"
  95             }
  96         } else {
  97             puts $ofd $line
  98         }
  99     }
 100     close $ifd
 101     close $ofd
 102
 103     # Anchor the test output, so that error messages are detected.
 104     set cmd "set tdesc filename regs.xml"
 105     set msg "set tdesc filename $file"
 106     set cmd_regex [string_to_regexp $cmd]
 107     gdb_test_multiple $cmd $msg {
 108         -re "^$cmd_regex\r\n$errmsg$gdb_prompt $" {
 109             pass $msg
 110         }
 111     }
 112 }
 113
 114 load_description "extra-regs.xml" ""
 115 gdb_test "ptype \$extrareg" "type = (int|long|long long)"
 116 gdb_test "ptype \$uintreg" "type = uint32_t"
 117 gdb_test "ptype \$vecreg" "type = int8_t \\\[4\\\]"
 118 gdb_test "ptype \$unionreg" \
 119     "type = union {\r\n *v4int8 v4;\r\n *v2int16 v2;\r\n}"
 120 gdb_test "ptype \$unionreg.v4" "type = int8_t \\\[4\\\]"
 121
 122 load_description "core-only.xml" ""
 123 # The extra register from the previous description should be gone.
 124 gdb_test "ptype \$extrareg" "type = void"
 125
 126 foreach src ${core-regs} {
 127     file delete "$src"
 128 }
 129 file delete "regs.xml"