src/CMakeLists.txt

   1 set (mraa_LIB_INCLUDE_DIRS
   2   ${PROJECT_SOURCE_DIR}/api
   3   ${PROJECT_SOURCE_DIR}/api/mraa
   4   ${PROJECT_SOURCE_DIR}/include
   5 )
   6
   7 include_directories(
   8   ${mraa_LIB_INCLUDE_DIRS}
   9 )
  10
  11 set (mraa_LIB_SRCS_NOAUTO
  12   ${PROJECT_SOURCE_DIR}/src/mraa.c
  13   ${PROJECT_SOURCE_DIR}/src/gpio/gpio.c
  14   ${PROJECT_SOURCE_DIR}/src/i2c/i2c.c
  15   ${PROJECT_SOURCE_DIR}/src/pwm/pwm.c
  16   ${PROJECT_SOURCE_DIR}/src/spi/spi.c
  17   ${PROJECT_SOURCE_DIR}/src/aio/aio.c
  18   ${PROJECT_SOURCE_DIR}/src/uart/uart.c
  19 )
  20
  21 set (mraa_LIB_X86_SRCS_NOAUTO
  22   ${PROJECT_SOURCE_DIR}/src/x86/x86.c
  23   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_d.c
  24   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_g.c
  25   ${PROJECT_SOURCE_DIR}/src/x86/intel_edison_fab_c.c
  26   ${PROJECT_SOURCE_DIR}/src/x86/intel_de3815.c
  27   ${PROJECT_SOURCE_DIR}/src/x86/intel_nuc5.c
  28   ${PROJECT_SOURCE_DIR}/src/x86/intel_minnow_max.c
  29 )
  30
  31 set (mraa_LIB_ARM_SRCS_NOAUTO
  32   ${PROJECT_SOURCE_DIR}/src/arm/arm.c
  33   ${PROJECT_SOURCE_DIR}/src/arm/raspberry_pi.c
  34   ${PROJECT_SOURCE_DIR}/src/arm/beaglebone.c
  35   ${PROJECT_SOURCE_DIR}/src/arm/banana.c
  36 )
  37
  38 if (X86PLAT)
  39   add_subdirectory(x86)
  40   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DX86PLAT=1")
  41 endif()
  42
  43 if (ARMPLAT)
  44   add_subdirectory(arm)
  45   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DARMPLAT=1")
  46 endif()
  47
  48 set (mraa_LIB_SRCS
  49   ${mraa_LIB_PLAT_SRCS_NOAUTO}
  50 # autogenerated version file
  51   ${CMAKE_CURRENT_BINARY_DIR}/version.c
  52 )
  53
  54 set (mraa_LIB_GLOB_HEADERS
  55   ${PROJECT_SOURCE_DIR}/api/mraa.h
  56   ${PROJECT_SOURCE_DIR}/api/mraa.hpp
  57 )
  58
  59 add_library (mraa SHARED ${mraa_LIB_SRCS})
  60 target_link_libraries (mraa ${CMAKE_THREAD_LIBS_INIT})
  61
  62 set_target_properties(
  63    mraa
  64    PROPERTIES
  65    SOVERSION ${mraa_VERSION_MAJOR}
  66    VERSION ${mraa_VERSION_STRING}
  67 )
  68 install (FILES ${mraa_LIB_GLOB_HEADERS} DESTINATION include/)
  69 install (DIRECTORY ${PROJECT_SOURCE_DIR}/api/mraa/ DESTINATION include/mraa)
  70
  71 macro (mraa_CREATE_INSTALL_PKGCONFIG generated_file install_location)
  72   configure_file (${generated_file}.cmake ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} @ONLY)
  73   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} DESTINATION ${install_location})
  74 endmacro (mraa_CREATE_INSTALL_PKGCONFIG)
  75 mraa_create_install_pkgconfig (mraa.pc lib${LIB_SUFFIX}/pkgconfig)
  76
  77 install(TARGETS mraa DESTINATION ${CMAKE_INSTALL_LIBDIR})
  78
  79 if (DOXYGEN_FOUND)
  80   set (CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
  81   set (DOCCLASSES aio gpio i2c pwm spi uart)
  82   # CPP class headers
  83   foreach (_file ${DOCCLASSES})
  84     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
  85       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  86         ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
  87         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
  88       DEPENDS ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
  89     )
  90     add_custom_target (${_file}class_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i)
  91     add_dependencies (${_file}class_doc_i doc)
  92   endforeach ()
  93   # C header files
  94   set (DOCFILES common ${DOCCLASSES})
  95   foreach (_file ${DOCFILES})
  96     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
  97       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  98         ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
  99         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
 100       DEPENDS ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
 101     )
 102     add_custom_target (${_file}doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i)
 103     add_dependencies (${_file}doc_i doc)
 104   endforeach ()
 105   # CPP common header
 106   add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i
 107     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 108       ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 109       ${CMAKE_CURRENT_BINARY_DIR}//common_hpp_doc.i
 110     DEPENDS ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 111   )
 112   add_custom_target (common_hpp_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i)
 113   add_dependencies (common_hpp_doc_i doc)
 114 endif ()
 115
 116 if (BUILDSWIG)
 117   find_package (SWIG)
 118   if (SWIG_FOUND)
 119     include (${SWIG_USE_FILE})
 120     set_source_files_properties (mraa.i PROPERTIES SWIG_FLAGS "-I${CMAKE_BINARY_DIR}/src")
 121
 122     if (BUILDSWIGPYTHON)
 123       add_subdirectory (python)
 124     endif ()
 125     if (BUILDSWIGJAVA)
 126       add_subdirectory (java)
 127     endif ()
 128     if (BUILDSWIGNODE)
 129       if (SWIG_VERSION VERSION_GREATER 3.0.4)
 130         add_subdirectory (javascript)
 131       else ()
 132         message ("WARN - SWIG is ${SWIG_VERSION}. Please upgrade to 3.0.5+ to build nodejs addon")
 133       endif ()
 134     endif ()
 135   endif ()
 136 endif ()