src/CMakeLists.txt

   1 set (mraa_LIB_INCLUDE_DIRS
   2   ${PROJECT_SOURCE_DIR}/api
   3   ${PROJECT_SOURCE_DIR}/api/mraa
   4   ${PROJECT_SOURCE_DIR}/include
   5 )
   6
   7 include_directories(
   8   ${mraa_LIB_INCLUDE_DIRS}
   9 )
  10
  11 set (mraa_LIB_SRCS_NOAUTO
  12   ${PROJECT_SOURCE_DIR}/src/mraa.c
  13   ${PROJECT_SOURCE_DIR}/src/gpio/gpio.c
  14   ${PROJECT_SOURCE_DIR}/src/i2c/i2c.c
  15   ${PROJECT_SOURCE_DIR}/src/pwm/pwm.c
  16   ${PROJECT_SOURCE_DIR}/src/spi/spi.c
  17   ${PROJECT_SOURCE_DIR}/src/aio/aio.c
  18   ${PROJECT_SOURCE_DIR}/src/uart/uart.c
  19 )
  20
  21 set (mraa_LIB_X86_SRCS_NOAUTO
  22   ${PROJECT_SOURCE_DIR}/src/x86/x86.c
  23   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_d.c
  24   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_g.c
  25   ${PROJECT_SOURCE_DIR}/src/x86/intel_edison_fab_c.c
  26   ${PROJECT_SOURCE_DIR}/src/x86/intel_de3815.c
  27   ${PROJECT_SOURCE_DIR}/src/x86/intel_nuc5.c
  28   ${PROJECT_SOURCE_DIR}/src/x86/intel_minnow_byt_compatible.c
  29 )
  30
  31 message (INFO " - Adding support for platform ${MRAAPLATFORMFORCE}")
  32
  33 #keywords in if statements are case sensitive
  34 if (NOT ${MRAAPLATFORMFORCE} STREQUAL "ALL")
  35   set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Dx${MRAAPLATFORMFORCE} -DMRAA_PLATFORM_FORCE=${MRAAPLATFORMFORCE}")
  36   if (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_GALILEO_GEN2")
  37     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_g.c)
  38   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_GALILEO_GEN1")
  39     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_d.c)
  40   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_DE3815")
  41     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_de3815.c)
  42   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_EDISON_FAB_C")
  43     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_edison_fab_c.c)
  44   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_MINNOWBOARD_MAX")
  45     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_minnow_byt_compatible.c)
  46   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_NUC5")
  47     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_nuc5.c)
  48   else ()
  49     message (ERROR " - Unknown x86 platform enabled!")
  50   endif ()
  51 else ()
  52     message (INFO " - Adding support for all platforms")
  53 endif ()
  54
  55 set (mraa_LIB_ARM_SRCS_NOAUTO
  56   ${PROJECT_SOURCE_DIR}/src/arm/arm.c
  57   ${PROJECT_SOURCE_DIR}/src/arm/96boards.c
  58   ${PROJECT_SOURCE_DIR}/src/arm/raspberry_pi.c
  59   ${PROJECT_SOURCE_DIR}/src/arm/beaglebone.c
  60   ${PROJECT_SOURCE_DIR}/src/arm/banana.c
  61 )
  62
  63 set (mraa_LIBS ${CMAKE_THREAD_LIBS_INIT})
  64
  65 if (X86PLAT)
  66   add_subdirectory(x86)
  67   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DX86PLAT=1")
  68 endif()
  69
  70 if (ARMPLAT)
  71   add_subdirectory(arm)
  72   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DARMPLAT=1")
  73 endif()
  74
  75 if (USBPLAT)
  76   message (INFO " - Adding USB platforms")
  77   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DUSBPLAT=1")
  78   if (FTDID2xx)
  79     find_package (Ftd2xx)
  80     if (${LIBFTD2XX_FOUND})
  81       set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DFTDID2XX=1")
  82       set (mraa_LIBS ${mraa_LIBS} ${LIBFTD2XX_LIBRARIES})
  83     else ()
  84       message (WARNING " - Enabled FTDID2xx support but library not found")
  85     endif ()
  86   endif ()
  87   if (FTDI4222)
  88     find_package (Ftd4222)
  89     if (${LIBFT4222_FOUND})
  90       set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DFTDI4222=1")
  91       set (mraa_LIBS ${mraa_LIBS} ${LIBFT4222_LIBRARIES})
  92     else ()
  93       message (WARNING " - Enabled FTDI4222 support but library not found")
  94     endif ()
  95   endif ()
  96   add_subdirectory(usb)
  97 endif ()
  98
  99 set (mraa_LIB_SRCS
 100   ${mraa_LIB_PLAT_SRCS_NOAUTO}
 101 # autogenerated version file
 102   ${CMAKE_CURRENT_BINARY_DIR}/version.c
 103 )
 104
 105 set (mraa_LIB_GLOB_HEADERS
 106   ${PROJECT_SOURCE_DIR}/api/mraa.h
 107   ${PROJECT_SOURCE_DIR}/api/mraa.hpp
 108 )
 109
 110 add_library (mraa SHARED ${mraa_LIB_SRCS})
 111
 112
 113 target_link_libraries (mraa ${mraa_LIBS})
 114
 115 set_target_properties(
 116    mraa
 117    PROPERTIES
 118    SOVERSION ${mraa_VERSION_MAJOR}
 119    VERSION ${mraa_VERSION_STRING}
 120 )
 121 install (FILES ${mraa_LIB_GLOB_HEADERS} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 122 install (DIRECTORY ${PROJECT_SOURCE_DIR}/api/mraa/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mraa)
 123
 124 macro (mraa_CREATE_INSTALL_PKGCONFIG generated_file install_location)
 125   configure_file (${generated_file}.cmake ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} @ONLY)
 126   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} DESTINATION ${install_location})
 127 endmacro (mraa_CREATE_INSTALL_PKGCONFIG)
 128 mraa_create_install_pkgconfig (mraa.pc ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 129
 130 install(TARGETS mraa DESTINATION ${CMAKE_INSTALL_LIBDIR})
 131
 132 if (DOXYGEN_FOUND)
 133   set (CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
 134   set (DOCCLASSES aio gpio i2c pwm spi uart)
 135   # CPP class headers
 136   foreach (_file ${DOCCLASSES})
 137     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
 138       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 139         ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
 140         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
 141       DEPENDS ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
 142     )
 143     add_custom_target (${_file}class_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i)
 144     add_dependencies (${_file}class_doc_i doc)
 145   endforeach ()
 146   # C header files
 147   set (DOCFILES common ${DOCCLASSES})
 148   foreach (_file ${DOCFILES})
 149     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
 150       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 151         ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
 152         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
 153       DEPENDS ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
 154     )
 155     add_custom_target (${_file}doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i)
 156     add_dependencies (${_file}doc_i doc)
 157   endforeach ()
 158   # CPP common header
 159   add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i
 160     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 161       ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 162       ${CMAKE_CURRENT_BINARY_DIR}//common_hpp_doc.i
 163     DEPENDS ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 164   )
 165   add_custom_target (common_hpp_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i)
 166   add_dependencies (common_hpp_doc_i doc)
 167 endif ()
 168
 169 if (BUILDSWIG)
 170   find_package (SWIG)
 171   if (SWIG_FOUND)
 172     include (${SWIG_USE_FILE})
 173     set_source_files_properties (mraa.i PROPERTIES SWIG_FLAGS "-I${CMAKE_BINARY_DIR}/src")
 174
 175     if (BUILDSWIGPYTHON)
 176       add_subdirectory (python)
 177     endif ()
 178     if (BUILDSWIGJAVA)
 179       add_subdirectory (java)
 180     endif ()
 181     if (BUILDSWIGNODE)
 182       if (SWIG_VERSION VERSION_GREATER 3.0.4)
 183         add_subdirectory (javascript)
 184       else ()
 185         message ("WARN - SWIG is ${SWIG_VERSION}. Please upgrade to 3.0.5+ to build nodejs addon")
 186       endif ()
 187     endif ()
 188   endif ()
 189 endif ()