src/CMakeLists.txt

   1 set (mraa_LIB_INCLUDE_DIRS
   2   ${PROJECT_SOURCE_DIR}/api
   3   ${PROJECT_SOURCE_DIR}/api/mraa
   4   ${PROJECT_SOURCE_DIR}/include
   5 )
   6
   7 include_directories(
   8   ${mraa_LIB_INCLUDE_DIRS}
   9 )
  10
  11 set (mraa_LIB_SRCS_NOAUTO
  12   ${PROJECT_SOURCE_DIR}/src/mraa.c
  13   ${PROJECT_SOURCE_DIR}/src/gpio/gpio.c
  14   ${PROJECT_SOURCE_DIR}/src/i2c/i2c.c
  15   ${PROJECT_SOURCE_DIR}/src/pwm/pwm.c
  16   ${PROJECT_SOURCE_DIR}/src/spi/spi.c
  17   ${PROJECT_SOURCE_DIR}/src/aio/aio.c
  18   ${PROJECT_SOURCE_DIR}/src/uart/uart.c
  19 )
  20
  21 set (mraa_LIB_X86_SRCS_NOAUTO
  22   ${PROJECT_SOURCE_DIR}/src/x86/x86.c
  23   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_d.c
  24   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_g.c
  25   ${PROJECT_SOURCE_DIR}/src/x86/intel_edison_fab_c.c
  26   ${PROJECT_SOURCE_DIR}/src/x86/intel_de3815.c
  27   ${PROJECT_SOURCE_DIR}/src/x86/intel_nuc5.c
  28   ${PROJECT_SOURCE_DIR}/src/x86/intel_minnow_byt_compatible.c
  29 )
  30
  31 set (mraa_LIB_ARM_SRCS_NOAUTO
  32   ${PROJECT_SOURCE_DIR}/src/arm/arm.c
  33   ${PROJECT_SOURCE_DIR}/src/arm/raspberry_pi.c
  34   ${PROJECT_SOURCE_DIR}/src/arm/beaglebone.c
  35   ${PROJECT_SOURCE_DIR}/src/arm/banana.c
  36 )
  37
  38 set (mraa_LIBS ${CMAKE_THREAD_LIBS_INIT})
  39
  40 if (X86PLAT)
  41   add_subdirectory(x86)
  42   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DX86PLAT=1")
  43 endif()
  44
  45 if (ARMPLAT)
  46   add_subdirectory(arm)
  47   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DARMPLAT=1")
  48 endif()
  49
  50 if (USBPLAT)
  51   message (INFO " - Adding USB platforms")
  52   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DUSBPLAT=1")
  53   if (FTDID2xx)
  54     find_package (Ftd2xx)
  55     if (${LIBFTD2XX_FOUND})
  56       set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DFTDID2XX=1")
  57       set (mraa_LIBS ${mraa_LIBS} ${LIBFTD2XX_LIBRARIES})
  58     else ()
  59       message (WARNING " - Enabled FTDID2xx support but library not found")
  60     endif ()
  61   endif ()
  62   if (FTDI4222)
  63     find_package (Ftd4222)
  64     if (${LIBFT4222_FOUND})
  65       set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DFTDI4222=1")
  66       set (mraa_LIBS ${mraa_LIBS} ${LIBFT4222_LIBRARIES})
  67     else ()
  68       message (WARNING " - Enabled FTDI4222 support but library not found")
  69     endif ()
  70   endif ()
  71   add_subdirectory(usb)
  72 endif ()
  73
  74 set (mraa_LIB_SRCS
  75   ${mraa_LIB_PLAT_SRCS_NOAUTO}
  76 # autogenerated version file
  77   ${CMAKE_CURRENT_BINARY_DIR}/version.c
  78 )
  79
  80 set (mraa_LIB_GLOB_HEADERS
  81   ${PROJECT_SOURCE_DIR}/api/mraa.h
  82   ${PROJECT_SOURCE_DIR}/api/mraa.hpp
  83 )
  84
  85 add_library (mraa SHARED ${mraa_LIB_SRCS})
  86
  87
  88 target_link_libraries (mraa ${mraa_LIBS})
  89
  90 set_target_properties(
  91    mraa
  92    PROPERTIES
  93    SOVERSION ${mraa_VERSION_MAJOR}
  94    VERSION ${mraa_VERSION_STRING}
  95 )
  96 install (FILES ${mraa_LIB_GLOB_HEADERS} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
  97 install (DIRECTORY ${PROJECT_SOURCE_DIR}/api/mraa/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mraa)
  98
  99 macro (mraa_CREATE_INSTALL_PKGCONFIG generated_file install_location)
 100   configure_file (${generated_file}.cmake ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} @ONLY)
 101   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} DESTINATION ${install_location})
 102 endmacro (mraa_CREATE_INSTALL_PKGCONFIG)
 103 mraa_create_install_pkgconfig (mraa.pc ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 104
 105 install(TARGETS mraa DESTINATION ${CMAKE_INSTALL_LIBDIR})
 106
 107 if (DOXYGEN_FOUND)
 108   set (CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
 109   set (DOCCLASSES aio gpio i2c pwm spi uart)
 110   # CPP class headers
 111   foreach (_file ${DOCCLASSES})
 112     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
 113       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 114         ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
 115         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
 116       DEPENDS ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
 117     )
 118     add_custom_target (${_file}class_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i)
 119     add_dependencies (${_file}class_doc_i doc)
 120   endforeach ()
 121   # C header files
 122   set (DOCFILES common ${DOCCLASSES})
 123   foreach (_file ${DOCFILES})
 124     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
 125       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 126         ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
 127         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
 128       DEPENDS ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
 129     )
 130     add_custom_target (${_file}doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i)
 131     add_dependencies (${_file}doc_i doc)
 132   endforeach ()
 133   # CPP common header
 134   add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i
 135     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 136       ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 137       ${CMAKE_CURRENT_BINARY_DIR}//common_hpp_doc.i
 138     DEPENDS ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 139   )
 140   add_custom_target (common_hpp_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i)
 141   add_dependencies (common_hpp_doc_i doc)
 142 endif ()
 143
 144 if (BUILDSWIG)
 145   find_package (SWIG)
 146   if (SWIG_FOUND)
 147     include (${SWIG_USE_FILE})
 148     set_source_files_properties (mraa.i PROPERTIES SWIG_FLAGS "-I${CMAKE_BINARY_DIR}/src")
 149
 150     if (BUILDSWIGPYTHON)
 151       add_subdirectory (python)
 152     endif ()
 153     if (BUILDSWIGJAVA)
 154       add_subdirectory (java)
 155     endif ()
 156     if (BUILDSWIGNODE)
 157       if (SWIG_VERSION VERSION_GREATER 3.0.4)
 158         add_subdirectory (javascript)
 159       else ()
 160         message ("WARN - SWIG is ${SWIG_VERSION}. Please upgrade to 3.0.5+ to build nodejs addon")
 161       endif ()
 162     endif ()
 163   endif ()
 164 endif ()