src/CMakeLists.txt

   1 set (mraa_LIB_INCLUDE_DIRS
   2   ${PROJECT_SOURCE_DIR}/api
   3   ${PROJECT_SOURCE_DIR}/api/mraa
   4   ${PROJECT_SOURCE_DIR}/include
   5 )
   6
   7 include_directories(
   8   ${mraa_LIB_INCLUDE_DIRS}
   9 )
  10
  11 set (mraa_LIB_SRCS_NOAUTO
  12   ${PROJECT_SOURCE_DIR}/src/mraa.c
  13   ${PROJECT_SOURCE_DIR}/src/gpio/gpio.c
  14   ${PROJECT_SOURCE_DIR}/src/i2c/i2c.c
  15   ${PROJECT_SOURCE_DIR}/src/pwm/pwm.c
  16   ${PROJECT_SOURCE_DIR}/src/spi/spi.c
  17   ${PROJECT_SOURCE_DIR}/src/aio/aio.c
  18   ${PROJECT_SOURCE_DIR}/src/uart/uart.c
  19 )
  20
  21 set (mraa_LIB_X86_SRCS_NOAUTO
  22   ${PROJECT_SOURCE_DIR}/src/x86/x86.c
  23   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_d.c
  24   ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_g.c
  25   ${PROJECT_SOURCE_DIR}/src/x86/intel_edison_fab_c.c
  26   ${PROJECT_SOURCE_DIR}/src/x86/intel_de3815.c
  27   ${PROJECT_SOURCE_DIR}/src/x86/intel_nuc5.c
  28   ${PROJECT_SOURCE_DIR}/src/x86/intel_minnow_byt_compatible.c
  29 )
  30
  31 message (INFO " - Adding support for platform ${MRAAPLATFORMFORCE}")
  32
  33 #keywords in if statements are case sensitive
  34 if (NOT ${MRAAPLATFORMFORCE} STREQUAL "ALL")
  35   set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Dx${MRAAPLATFORMFORCE} -DMRAA_PLATFORM_FORCE=${MRAAPLATFORMFORCE}")
  36   if (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_GALILEO_GEN2")
  37     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_g.c)
  38   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_GALILEO_GEN1")
  39     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_galileo_rev_d.c)
  40   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_DE3815")
  41     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_de3815.c)
  42   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_EDISON_FAB_C")
  43     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_edison_fab_c.c)
  44   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_MINNOWBOARD_MAX")
  45     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_minnow_byt_compatible.c)
  46   elseif (${MRAAPLATFORMFORCE} STREQUAL "MRAA_INTEL_NUC5")
  47     set (mraa_LIB_X86_SRCS_NOAUTO ${PROJECT_SOURCE_DIR}/src/x86/x86.c ${PROJECT_SOURCE_DIR}/src/x86/intel_nuc5.c)
  48   else ()
  49     message (ERROR " - Unknown x86 platform enabled!")
  50   endif ()
  51 else ()
  52     message (INFO " - Adding support for all platforms")
  53 endif ()
  54
  55 set (mraa_LIB_ARM_SRCS_NOAUTO
  56   ${PROJECT_SOURCE_DIR}/src/arm/arm.c
  57   ${PROJECT_SOURCE_DIR}/src/arm/raspberry_pi.c
  58   ${PROJECT_SOURCE_DIR}/src/arm/beaglebone.c
  59   ${PROJECT_SOURCE_DIR}/src/arm/banana.c
  60 )
  61
  62 set (mraa_LIBS ${CMAKE_THREAD_LIBS_INIT})
  63
  64 if (X86PLAT)
  65   add_subdirectory(x86)
  66   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DX86PLAT=1")
  67 endif()
  68
  69 if (ARMPLAT)
  70   add_subdirectory(arm)
  71   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DARMPLAT=1")
  72 endif()
  73
  74 if (USBPLAT)
  75   message (INFO " - Adding USB platforms")
  76   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DUSBPLAT=1")
  77   if (FTDID2xx)
  78     find_package (Ftd2xx)
  79     if (${LIBFTD2XX_FOUND})
  80       set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DFTDID2XX=1")
  81       set (mraa_LIBS ${mraa_LIBS} ${LIBFTD2XX_LIBRARIES})
  82     else ()
  83       message (WARNING " - Enabled FTDID2xx support but library not found")
  84     endif ()
  85   endif ()
  86   if (FTDI4222)
  87     find_package (Ftd4222)
  88     if (${LIBFT4222_FOUND})
  89       set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DFTDI4222=1")
  90       set (mraa_LIBS ${mraa_LIBS} ${LIBFT4222_LIBRARIES})
  91     else ()
  92       message (WARNING " - Enabled FTDI4222 support but library not found")
  93     endif ()
  94   endif ()
  95   add_subdirectory(usb)
  96 endif ()
  97
  98 set (mraa_LIB_SRCS
  99   ${mraa_LIB_PLAT_SRCS_NOAUTO}
 100 # autogenerated version file
 101   ${CMAKE_CURRENT_BINARY_DIR}/version.c
 102 )
 103
 104 set (mraa_LIB_GLOB_HEADERS
 105   ${PROJECT_SOURCE_DIR}/api/mraa.h
 106   ${PROJECT_SOURCE_DIR}/api/mraa.hpp
 107 )
 108
 109 add_library (mraa SHARED ${mraa_LIB_SRCS})
 110
 111
 112 target_link_libraries (mraa ${mraa_LIBS})
 113
 114 set_target_properties(
 115    mraa
 116    PROPERTIES
 117    SOVERSION ${mraa_VERSION_MAJOR}
 118    VERSION ${mraa_VERSION_STRING}
 119 )
 120 install (FILES ${mraa_LIB_GLOB_HEADERS} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 121 install (DIRECTORY ${PROJECT_SOURCE_DIR}/api/mraa/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mraa)
 122
 123 macro (mraa_CREATE_INSTALL_PKGCONFIG generated_file install_location)
 124   configure_file (${generated_file}.cmake ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} @ONLY)
 125   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/${generated_file} DESTINATION ${install_location})
 126 endmacro (mraa_CREATE_INSTALL_PKGCONFIG)
 127 mraa_create_install_pkgconfig (mraa.pc ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 128
 129 install(TARGETS mraa DESTINATION ${CMAKE_INSTALL_LIBDIR})
 130
 131 if (DOXYGEN_FOUND)
 132   set (CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
 133   set (DOCCLASSES aio gpio i2c pwm spi uart)
 134   # CPP class headers
 135   foreach (_file ${DOCCLASSES})
 136     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
 137       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 138         ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
 139         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i
 140       DEPENDS ${CMAKE_BINARY_DIR}/xml/classmraa_1_1_${_file}.xml
 141     )
 142     add_custom_target (${_file}class_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_class_doc.i)
 143     add_dependencies (${_file}class_doc_i doc)
 144   endforeach ()
 145   # C header files
 146   set (DOCFILES common ${DOCCLASSES})
 147   foreach (_file ${DOCFILES})
 148     add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
 149       COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 150         ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
 151         ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i
 152       DEPENDS ${CMAKE_BINARY_DIR}/xml/${_file}_8h.xml
 153     )
 154     add_custom_target (${_file}doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_file}_doc.i)
 155     add_dependencies (${_file}doc_i doc)
 156   endforeach ()
 157   # CPP common header
 158   add_custom_command (OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i
 159     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
 160       ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 161       ${CMAKE_CURRENT_BINARY_DIR}//common_hpp_doc.i
 162     DEPENDS ${CMAKE_BINARY_DIR}/xml/common_8hpp.xml
 163   )
 164   add_custom_target (common_hpp_doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/common_hpp_doc.i)
 165   add_dependencies (common_hpp_doc_i doc)
 166 endif ()
 167
 168 if (BUILDSWIG)
 169   find_package (SWIG)
 170   if (SWIG_FOUND)
 171     include (${SWIG_USE_FILE})
 172     set_source_files_properties (mraa.i PROPERTIES SWIG_FLAGS "-I${CMAKE_BINARY_DIR}/src")
 173
 174     if (BUILDSWIGPYTHON)
 175       add_subdirectory (python)
 176     endif ()
 177     if (BUILDSWIGJAVA)
 178       add_subdirectory (java)
 179     endif ()
 180     if (BUILDSWIGNODE)
 181       if (SWIG_VERSION VERSION_GREATER 3.0.4)
 182         add_subdirectory (javascript)
 183       else ()
 184         message ("WARN - SWIG is ${SWIG_VERSION}. Please upgrade to 3.0.5+ to build nodejs addon")
 185       endif ()
 186     endif ()
 187   endif ()
 188 endif ()