common/m4/gst-libxml2.m4

   1 dnl call this macro with the minimum required version as an argument
   2 dnl this macro sets and AC_SUBSTs XML_CFLAGS and XML_LIBS
   3 dnl it also sets LIBXML_PKG, used for the pkg-config file
   4
   5 AC_DEFUN([AG_GST_LIBXML2_CHECK],
   6 [
   7   dnl Minimum required version of libxml2
   8   dnl default to 2.4.9 if not specified
   9   LIBXML2_REQ=ifelse([$1],,2.4.9,[$1])
  10   AC_SUBST(LIBXML2_REQ)
  11
  12   dnl check for libxml2
  13   PKG_CHECK_MODULES(XML, libxml-2.0 >= $LIBXML2_REQ,
  14                     HAVE_LIBXML2=yes, [
  15                       AC_MSG_RESULT(no)
  16                       HAVE_LIBXML2=no
  17                     ])
  18   if test "x$HAVE_LIBXML2" = "xyes"; then
  19     AC_DEFINE(HAVE_LIBXML2, 1, [Define if libxml2 is available])
  20   else
  21     AC_MSG_ERROR([Need libxml2 for glib2 builds -- you should be able to do without it -- this needs fixing])
  22   fi
  23   dnl this is for the .pc file
  24   LIBXML_PKG=', libxml-2.0'
  25   AC_SUBST(LIBXML_PKG)
  26   AC_SUBST(XML_LIBS)
  27   AC_SUBST(XML_CFLAGS)
  28
  29   dnl XML_LIBS might pull in -lz without zlib actually being on the system, so
  30   dnl try linking with these LIBS and CFLAGS
  31   ac_save_CFLAGS=$CFLAGS
  32   ac_save_LIBS=$LIBS
  33   CFLAGS="$CFLAGS $XML_CFLAGS"
  34   LIBS="$LIBS $XML_LIBS"
  35   AC_TRY_LINK([
  36 #include <libxml/tree.h>
  37 #include <stdio.h>
  38 ],[
  39 /* function body */
  40 ],
  41     AC_MSG_NOTICE([Test xml2 program linked]),
  42     AC_MSG_ERROR([Could not link libxml2 test program.  Check if you have the necessary dependencies.])
  43   )
  44   CFLAGS="$ac_save_CFLAGS"
  45   LIBS="$ac_save_LIBS"
  46 ])