tools/xml2text.xsl

   1 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   2
   3  <xsl:output method="text" encoding="us-ascii" omit-xml-declaration="yes" indent="no"/>
   4  <xsl:variable name="padding" select="string('                              ')"/>
   5
   6  <xsl:template match="/element">
   7   <xsl:apply-templates select="name"/>
   8   <xsl:apply-templates select="details"/>
   9   <xsl:apply-templates select="object"/>
  10   <xsl:apply-templates select="pad-templates"/>
  11   <xsl:apply-templates select="element-flags"/>
  12   <xsl:apply-templates select="element-implementation"/>
  13   <xsl:apply-templates select="clocking-interaction"/>
  14   <xsl:apply-templates select="indexing-capabilities"/>
  15   <xsl:apply-templates select="pads"/>
  16   <xsl:apply-templates select="element-properties"/>
  17   <xsl:apply-templates select="dyn-params"/>
  18   <xsl:apply-templates select="element-signals"/>
  19   <xsl:apply-templates select="element-actions"/>
  20  </xsl:template>
  21
  22  <xsl:template match="name">
  23   <xsl:text>Element Name: </xsl:text><xsl:value-of select="."/>
  24   <xsl:text>&#10;&#10;</xsl:text>
  25  </xsl:template>
  26
  27  <xsl:template match="details">
  28   <xsl:text>Factory Details:&#10;</xsl:text>
  29   <xsl:text>  Long Name:&#9;</xsl:text>   <xsl:value-of select="long-name"/>   <xsl:text>&#10;</xsl:text>
  30   <xsl:text>  Class:&#9;</xsl:text>       <xsl:value-of select="class"/>       <xsl:text>&#10;</xsl:text>
  31   <xsl:text>  License:&#9;</xsl:text>     <xsl:value-of select="license"/>     <xsl:text>&#10;</xsl:text>
  32   <xsl:text>  Description:&#9;</xsl:text> <xsl:value-of select="description"/> <xsl:text>&#10;</xsl:text>
  33   <xsl:text>  Version:&#9;</xsl:text>     <xsl:value-of select="version"/>     <xsl:text>&#10;</xsl:text>
  34   <xsl:text>  Author(s):&#9;</xsl:text>   <xsl:value-of select="authors"/>     <xsl:text>&#10;</xsl:text>
  35   <xsl:text>  Copyright:&#9;</xsl:text>   <xsl:value-of select="copyright"/>   <xsl:text>&#10;</xsl:text>
  36   <xsl:text>&#10;</xsl:text>
  37  </xsl:template>
  38
  39  <xsl:template name="object">
  40   <xsl:param name="i"/>
  41   <xsl:param name="j"/>
  42   <xsl:if test="count($i/*) &gt; 0">
  43    <xsl:call-template name="object">
  44     <xsl:with-param name="i" select="$i/object"/>
  45     <xsl:with-param name="j" select="$j - 1"/>
  46    </xsl:call-template>
  47    <xsl:value-of select="substring ($padding, 1, $j * 6)"/>
  48    <xsl:text> +----</xsl:text>
  49   </xsl:if>
  50   <xsl:value-of select="$i/@name"/>
  51   <xsl:text>&#10;</xsl:text>
  52  </xsl:template>
  53
  54  <xsl:template match="object">
  55   <xsl:call-template name="object">
  56    <xsl:with-param name="i" select="."/>
  57    <xsl:with-param name="j" select="count(.//object[(*)])"/>
  58   </xsl:call-template>
  59   <xsl:text>&#10;</xsl:text>
  60  </xsl:template>
  61
  62  <xsl:template match="pad-templates">
  63   <xsl:text>Pad Templates&#10;</xsl:text>
  64   <xsl:apply-templates select="./pad-template"/>
  65  </xsl:template>
  66
  67  <xsl:template match="pad-template">
  68   <xsl:text>  </xsl:text>
  69   <xsl:value-of select="direction"/>
  70   <xsl:text> template: </xsl:text>
  71   <xsl:value-of select="name"/>
  72   <xsl:text>&#10;</xsl:text>
  73   <xsl:text>    Availability: </xsl:text> <xsl:value-of select="presence"/>
  74   <xsl:text>&#10;</xsl:text>
  75   <xsl:text>    Capabilities:&#10; </xsl:text> <xsl:apply-templates select="./capscomp"/>
  76  </xsl:template>
  77
  78  <xsl:template match="capscomp">
  79   <xsl:apply-templates select="./caps"/>
  80   <xsl:text>&#10;</xsl:text>
  81  </xsl:template>
  82
  83  <xsl:template match="caps">
  84   <xsl:text>     '</xsl:text>
  85   <xsl:value-of select="name"/>
  86   <xsl:text>'&#10;</xsl:text>
  87   <xsl:text>        MIME type: </xsl:text>
  88   <xsl:value-of select="type"/>
  89   <xsl:text>'&#10;</xsl:text>
  90   <xsl:apply-templates select="./properties"/>
  91  </xsl:template>
  92
  93  <xsl:template match="properties">
  94   <xsl:apply-templates select="*"/>
  95  </xsl:template>
  96
  97  <xsl:template match="list">
  98   <xsl:text>        </xsl:text>
  99   <xsl:value-of select="@name"/>
 100   <xsl:text>&#9;:List&#10;</xsl:text>
 101   <xsl:apply-templates select="*" mode="list"/>
 102  </xsl:template>
 103
 104  <!-- propety entries in list mode -->
 105  <xsl:template match="string" mode="list">
 106   <xsl:text>         String: '</xsl:text>
 107   <xsl:value-of select="@value"/>
 108   <xsl:text>'&#10;</xsl:text>
 109  </xsl:template>
 110
 111  <xsl:template match="fourcc" mode="list">
 112   <xsl:text>         FourCC: '</xsl:text>
 113   <xsl:value-of select="@hexvalue"/>
 114   <xsl:text>'&#10;</xsl:text>
 115  </xsl:template>
 116
 117  <xsl:template match="int" mode="list">
 118   <xsl:text>         Integer: </xsl:text>
 119   <xsl:value-of select="@value"/>
 120   <xsl:text>&#10;</xsl:text>
 121  </xsl:template>
 122
 123  <xsl:template match="range" mode="list">
 124   <xsl:text>         Integer range: </xsl:text>
 125   <xsl:value-of select="concat(@min, ' - ', @max)"/>
 126   <xsl:text>&#10;</xsl:text>
 127  </xsl:template>
 128
 129  <xsl:template match="float" mode="list">
 130   <xsl:text>         Float: </xsl:text>
 131   <xsl:value-of select="@value"/>
 132   <xsl:text>&#10;</xsl:text>
 133  </xsl:template>
 134
 135  <xsl:template match="floatrange" mode="list">
 136   <xsl:text>         Float range: </xsl:text>
 137   <xsl:value-of select="concat(@min, ' - ', @max)"/>
 138   <xsl:text>&#10;</xsl:text>
 139  </xsl:template>
 140
 141  <!-- propety entries in normal mode -->
 142  <xsl:template match="string">
 143   <xsl:text>         </xsl:text>
 144   <xsl:value-of select="substring (concat (@name, $padding), 1, 15)"/>
 145   <xsl:text>     : String: '</xsl:text>
 146   <xsl:value-of select="@value"/>
 147   <xsl:text>'&#10;</xsl:text>
 148  </xsl:template>
 149
 150  <xsl:template match="fourcc">
 151   <xsl:text>         </xsl:text>
 152   <xsl:value-of select="substring (concat (@name, $padding), 1, 15)"/>
 153   <xsl:text>     : FourCC: '</xsl:text>
 154   <xsl:value-of select="@hexvalue"/>
 155   <xsl:text>'&#10;</xsl:text>
 156  </xsl:template>
 157
 158  <xsl:template match="int">
 159   <xsl:text>         </xsl:text>
 160   <xsl:value-of select="substring (concat (@name, $padding), 1, 15)"/>
 161   <xsl:text>     : Integer: </xsl:text>
 162   <xsl:value-of select="@value"/>
 163   <xsl:text>&#10;</xsl:text>
 164  </xsl:template>
 165
 166  <xsl:template match="range">
 167   <xsl:text>         </xsl:text>
 168   <xsl:value-of select="substring (concat (@name, $padding), 1, 15)"/>
 169   <xsl:text>     : Integer range: </xsl:text>
 170   <xsl:value-of select="concat(@min, ' - ', @max)"/>
 171   <xsl:text>&#10;</xsl:text>
 172  </xsl:template>
 173
 174  <xsl:template match="float">
 175   <xsl:text>         </xsl:text>
 176   <xsl:value-of select="substring (concat (@name, $padding), 1, 15)"/>
 177   <xsl:text>     : Float: </xsl:text>
 178   <xsl:value-of select="@value"/>
 179   <xsl:text>&#10;</xsl:text>
 180  </xsl:template>
 181
 182  <xsl:template match="floatrange">
 183   <xsl:text>         </xsl:text>
 184   <xsl:value-of select="substring (concat (@name, $padding), 1, 15)"/>
 185   <xsl:text>     : Float range: </xsl:text>
 186   <xsl:value-of select="concat(@min, ' - ', @max)"/>
 187   <xsl:text>&#10;</xsl:text>
 188  </xsl:template>
 189
 190  <xsl:template match="flag">
 191   <xsl:text>  </xsl:text>
 192   <xsl:value-of select="."/>
 193   <xsl:text>&#10;</xsl:text>
 194  </xsl:template>
 195
 196  <xsl:template match="element-flags">
 197   <xsl:text>Element Flags:&#10;</xsl:text>
 198   <xsl:apply-templates select="./flag"/>
 199   <xsl:text>&#10;</xsl:text>
 200  </xsl:template>
 201
 202  <xsl:template match="state-change">
 203   <xsl:text>  Has change_state() function: </xsl:text>
 204   <xsl:value-of select="@function"/>
 205   <xsl:text>&#10;</xsl:text>
 206  </xsl:template>
 207
 208  <xsl:template match="load">
 209   <xsl:text>  Has custom restore_thyself() function: </xsl:text>
 210   <xsl:value-of select="@function"/>
 211   <xsl:text>&#10;</xsl:text>
 212  </xsl:template>
 213
 214  <xsl:template match="save">
 215   <xsl:text>  Has custom save_thyself() function: </xsl:text>
 216   <xsl:value-of select="@function"/>
 217   <xsl:text>&#10;</xsl:text>
 218  </xsl:template>
 219
 220  <xsl:template match="element-implementation">
 221   <xsl:text>Element Implementation:&#10;</xsl:text>
 222   <xsl:apply-templates select="*"/>
 223   <xsl:text>&#10;</xsl:text>
 224  </xsl:template>
 225
 226  <xsl:template match="requires-clock">
 227   <xsl:text>   element requires a clock&#10;</xsl:text>
 228  </xsl:template>
 229
 230  <xsl:template match="provides-clock">
 231   <xsl:text>   element provides a clock: </xsl:text>
 232   <xsl:value-of select="@name"/>
 233   <xsl:text>&#10;</xsl:text>
 234  </xsl:template>
 235
 236  <xsl:template match="clocking-interaction">
 237   <xsl:text>Clocking Interaction:&#10;</xsl:text>
 238   <xsl:choose>
 239    <xsl:when test="count(*) = 0">
 240     <xsl:text>  none&#10;</xsl:text>
 241    </xsl:when>
 242    <xsl:otherwise>
 243     <xsl:apply-templates select="*"/>
 244    </xsl:otherwise>
 245   </xsl:choose>
 246   <xsl:text>&#10;</xsl:text>
 247  </xsl:template>
 248
 249  <xsl:template match="indexing-capabilities">
 250   <xsl:text>   element can do indexing</xsl:text>
 251  </xsl:template>
 252
 253  <xsl:template match="dyn-params">
 254   <xsl:text>Dynamic Parameters:&#10;</xsl:text>
 255   <xsl:choose>
 256    <xsl:when test="count(*) = 0">
 257     <xsl:text>  none&#10;</xsl:text>
 258    </xsl:when>
 259    <xsl:otherwise>
 260     <xsl:apply-templates select="dyn-param"/>
 261    </xsl:otherwise>
 262   </xsl:choose>
 263   <xsl:text>&#10;</xsl:text>
 264  </xsl:template>
 265
 266  <xsl:template match="pads">
 267   <xsl:text>Pads:&#10;</xsl:text>
 268   <xsl:apply-templates select="pad"/>
 269   <xsl:text>&#10;</xsl:text>
 270  </xsl:template>
 271
 272  <xsl:template match="pad">
 273   <xsl:text>  </xsl:text>
 274   <xsl:value-of select="direction"/>
 275   <xsl:text>: '</xsl:text>
 276   <xsl:value-of select="name"/>
 277   <xsl:text>'&#10;</xsl:text>
 278   <xsl:apply-templates select="implementation"/>
 279   <xsl:text>    Pad Template: '</xsl:text>
 280   <xsl:value-of select="template"/>
 281   <xsl:text>'&#10;</xsl:text>
 282  </xsl:template>
 283
 284  <xsl:template match="implementation">
 285   <xsl:text>    Implementation:&#10;</xsl:text>
 286   <xsl:apply-templates select="*"/>
 287  </xsl:template>
 288
 289  <xsl:template match="chain-based">
 290   <xsl:text>      Has chainfunc(): </xsl:text>
 291   <xsl:value-of select="@function"/>
 292   <xsl:text>&#10;</xsl:text>
 293  </xsl:template>
 294
 295  <xsl:template match="bufferpool-function">
 296   <xsl:text>      Has bufferpoolfunc(): </xsl:text>
 297   <xsl:value-of select="@function"/>
 298   <xsl:text>&#10;</xsl:text>
 299  </xsl:template>
 300
 301  <xsl:template match="format">
 302   <xsl:text>                (</xsl:text>
 303   <xsl:value-of select="@id"/>
 304   <xsl:text>)&#9;</xsl:text>
 305   <xsl:value-of select="@nick"/>
 306   <xsl:text> (</xsl:text>
 307   <xsl:value-of select="."/>
 308   <xsl:text>)&#10;</xsl:text>
 309  </xsl:template>
 310
 311  <xsl:template match="formats-function">
 312   <xsl:text>      Supports seeking/conversion/query formats: </xsl:text>
 313   <xsl:value-of select="@function"/>
 314   <xsl:text>&#10;</xsl:text>
 315   <xsl:apply-templates select="format"/>
 316  </xsl:template>
 317
 318  <xsl:template match="convert-function">
 319   <xsl:text>      Has custom convertfunc(): </xsl:text>
 320   <xsl:value-of select="@function"/>
 321   <xsl:text>&#10;</xsl:text>
 322  </xsl:template>
 323
 324  <xsl:template match="query-function">
 325   <xsl:text>      Has custom queryfunc(): </xsl:text>
 326   <xsl:value-of select="@function"/>
 327   <xsl:text>&#10;</xsl:text>
 328  </xsl:template>
 329
 330  <xsl:template match="event-function">
 331   <xsl:text>      Has custom eventfunc(): </xsl:text>
 332   <xsl:value-of select="@function"/>
 333   <xsl:text>&#10;</xsl:text>
 334  </xsl:template>
 335
 336  <xsl:template match="event">
 337   <xsl:text>                </xsl:text>
 338   <xsl:value-of select="@type"/>
 339   <xsl:for-each select="flag">
 340    <xsl:text> | </xsl:text>
 341    <xsl:value-of select='.'/>
 342   </xsl:for-each>
 343   <xsl:text>&#10;</xsl:text>
 344  </xsl:template>
 345
 346  <xsl:template match="event-mask-func">
 347   <xsl:text>        Provides event masks: </xsl:text>
 348   <xsl:value-of select="@function"/>
 349   <xsl:text>&#10;</xsl:text>
 350   <xsl:apply-templates select="event"/>
 351  </xsl:template>
 352
 353  <xsl:template match="query-type">
 354   <xsl:text>                (</xsl:text>
 355   <xsl:value-of select="@id"/>
 356   <xsl:text>)&#9;</xsl:text>
 357   <xsl:value-of select="@nick"/>
 358   <xsl:text> (</xsl:text>
 359   <xsl:value-of select="."/>
 360   <xsl:text>)&#10;</xsl:text>
 361  </xsl:template>
 362
 363  <xsl:template match="query-type-func">
 364   <xsl:text>        Provides query types: </xsl:text>
 365   <xsl:value-of select="@function"/>
 366   <xsl:text>&#10;</xsl:text>
 367   <xsl:apply-templates select="query-type"/>
 368  </xsl:template>
 369
 370  <xsl:template match="element-properties">
 371   <xsl:text>Element Arguments:&#10;</xsl:text>
 372   <xsl:apply-templates select="element-property"/>
 373   <xsl:text>&#10;</xsl:text>
 374  </xsl:template>
 375
 376  <xsl:template match="default">
 377   <xsl:text>. (Default </xsl:text>
 378   <xsl:value-of select="."/>
 379   <xsl:text>)</xsl:text>
 380   <xsl:text>&#10;</xsl:text>
 381  </xsl:template>
 382
 383  <xsl:template match="range" mode="params">
 384   <xsl:value-of select="substring ($padding, 1, 25)"/>
 385   <xsl:text>Range : </xsl:text>
 386   <xsl:value-of select="concat(@min, ' - ', @max)"/>
 387   <xsl:text>&#10;</xsl:text>
 388  </xsl:template>
 389
 390  <xsl:template match="element-property|dyn-param">
 391   <xsl:text>  </xsl:text>
 392   <xsl:value-of select="substring (concat(name, $padding), 1, 20)"/>
 393   <xsl:text> : </xsl:text>
 394   <xsl:value-of select="blurb"/>
 395   <xsl:text>&#10;</xsl:text>
 396   <xsl:value-of select="substring ($padding, 1, 25)"/>
 397   <xsl:value-of select="type"/>
 398   <xsl:apply-templates select="default"/>
 399   <xsl:apply-templates select="range" mode="params"/>
 400  </xsl:template>
 401
 402  <xsl:template match="params">
 403   <xsl:for-each select="type">
 404    <xsl:text>,&#10;</xsl:text>
 405    <xsl:value-of select="substring ($padding, 1, 25)"/>
 406    <xsl:value-of select="substring ($padding, 1, 20)"/>
 407    <xsl:value-of select="."/>
 408    <xsl:text> arg</xsl:text>
 409    <xsl:value-of select="position()"/>
 410   </xsl:for-each>
 411  </xsl:template>
 412
 413  <xsl:template match="signal">
 414   <xsl:value-of select="substring (concat('&quot;', name, '&quot;', $padding), 1, 25)"/>
 415   <xsl:value-of select="return-type"/>
 416   <xsl:text> user_function </xsl:text>
 417   <xsl:value-of select="concat ('(', object-type, '* object')"/>
 418   <xsl:apply-templates select="params"/>
 419  </xsl:template>
 420
 421  <xsl:template match="element-signals">
 422   <xsl:text>Element Signals:&#10;</xsl:text>
 423   <xsl:choose>
 424    <xsl:when test="count(*) = 0">
 425     <xsl:text>  none&#10;</xsl:text>
 426    </xsl:when>
 427    <xsl:otherwise>
 428     <xsl:for-each select="signal">
 429      <xsl:apply-templates select="."/>
 430      <xsl:text>,&#10;</xsl:text>
 431      <xsl:value-of select="substring ($padding, 1, 25)"/>
 432      <xsl:value-of select="substring ($padding, 1, 20)"/>
 433      <xsl:text>gpointer user_data);&#10;</xsl:text>
 434     </xsl:for-each>
 435    </xsl:otherwise>
 436   </xsl:choose>
 437   <xsl:text>&#10;</xsl:text>
 438  </xsl:template>
 439
 440  <xsl:template match="element-actions">
 441   <xsl:text>Element Actions:&#10;</xsl:text>
 442   <xsl:choose>
 443    <xsl:when test="count(*) = 0">
 444     <xsl:text>  none&#10;</xsl:text>
 445    </xsl:when>
 446    <xsl:otherwise>
 447     <xsl:for-each select="signal">
 448      <xsl:apply-templates select="."/>
 449      <xsl:text>);&#10;</xsl:text>
 450     </xsl:for-each>
 451    </xsl:otherwise>
 452   </xsl:choose>
 453   <xsl:text>&#10;</xsl:text>
 454  </xsl:template>
 455
 456 </xsl:stylesheet>