tests/check/meson.build

   1 # FIXME: use dependency('valgrind') once we have a method to get the includes
   2 if cc.has_header('valgrind/valgrind.h')
   3   cdata.set('HAVE_VALGRIND', 1)
   4 endif
   5
   6 # internal helper lib for unit testing audio parsers
   7 libparser = static_library('libparser', 'elements/parser.c',
   8   c_args : gst_plugins_good_args + ['-DGST_USE_UNSTABLE_API'],
   9   include_directories : [configinc],
  10   dependencies : [gstcheck_dep],
  11   install : false)
  12
  13 libparser_dep = declare_dependency(link_with : libparser,
  14   dependencies : gstcheck_dep)
  15
  16 # name, condition when to skip the test and extra dependencies
  17 good_tests = [
  18   [ 'elements/audioamplify' ],
  19   [ 'elements/audiochebband' ],
  20   [ 'elements/audiocheblimit' ],
  21   [ 'elements/audiodynamic' ],
  22   [ 'elements/audioecho' ],
  23   [ 'elements/audiofirfilter' ],
  24   [ 'elements/audioiirfilter' ],
  25   [ 'elements/audioinvert' ],
  26   [ 'elements/audiopanorama' ],
  27   [ 'elements/audiowsincband' ],
  28   [ 'elements/audiowsinclimit' ],
  29   [ 'elements/alphacolor' ],
  30   [ 'elements/alpha' ],
  31   [ 'elements/aacparse', false, [libparser_dep] ],
  32   [ 'elements/ac3parse', false, [libparser_dep] ],
  33   [ 'elements/amrparse', false, [libparser_dep] ],
  34   [ 'elements/flacparse', false, [libparser_dep] ],
  35   [ 'elements/mpegaudioparse', false, [libparser_dep] ],
  36   [ 'elements/wavpackparse' ],
  37   [ 'elements/autodetect' ],
  38   [ 'elements/avimux' ],
  39   [ 'elements/avisubtitle' ],
  40   [ 'elements/capssetter' ],
  41   [ 'elements/deinterlace' ],
  42   [ 'elements/dtmf' ],
  43   [ 'pipelines/flacdec', not flac_dep.found() ],
  44   [ 'elements/flvdemux' ],
  45   [ 'elements/flvmux' ],
  46   [ 'elements/qtmux' ],
  47   [ 'elements/qtdemux' ],
  48   [ 'elements/mulawdec' ],
  49   [ 'elements/mulawenc' ],
  50   [ 'elements/gdkpixbufsink', not gdkpixbuf_dep.found(), [gdkpixbuf_dep] ],
  51   [ 'elements/gdkpixbufoverlay', not gdkpixbuf_dep.found() ],
  52   [ 'elements/icydemux' ],
  53   [ 'elements/id3demux' ],
  54   [ 'elements/imagefreeze' ],
  55   [ 'elements/deinterleave' ],
  56   [ 'elements/interleave' ],
  57   [ 'elements/jpegdec', not jpeglib.found() ],
  58   [ 'elements/jpegenc', not jpeglib.found() ],
  59   [ 'elements/level' ],
  60   [ 'elements/matroskademux' ],
  61   [ 'elements/matroskamux' ],
  62   [ 'elements/matroskaparse' ],
  63   [ 'elements/multifile' ],
  64   [ 'elements/splitmux' ],
  65   [ 'elements/rganalysis' ],
  66   [ 'elements/rglimiter' ],
  67   [ 'elements/rgvolume' ],
  68   [ 'elements/rtp-payloading' ],
  69   [ 'elements/rtph261' ],
  70   [ 'elements/rtph263' ],
  71   [ 'elements/rtpvp9' ],
  72   [ 'elements/rtpaux' ],
  73   [ 'elements/rtpbin' ],
  74   [ 'elements/rtpbin_buffer_list' ],
  75   [ 'elements/rtpcollision' ],
  76   [ 'elements/rtpjitterbuffer' ],
  77   [ 'elements/rtpmux' ],
  78   [ 'elements/rtprtx' ],
  79   [ 'elements/rtpsession' ],
  80   [ 'elements/souphttpsrc', not libsoup_dep.found(), [libsoup_dep] ],
  81   [ 'elements/spectrum' ],
  82 #  [ 'elements/sunaudio' ],
  83   [ 'elements/shapewipe' ],
  84   [ 'elements/id3v2mux', not taglib_dep.found() ],
  85   [ 'elements/apev2mux', not taglib_dep.found() ],
  86   [ 'elements/udpsink' ],
  87   [ 'elements/udpsrc' ],
  88   [ 'elements/videobox' ],
  89   [ 'elements/aspectratiocrop' ],
  90   [ 'elements/videocrop' ],
  91   [ 'elements/videofilter' ],
  92   [ 'elements/videomixer' ],
  93   [ 'elements/vp8enc', not have_vp8_encoder ],
  94   [ 'elements/vp8dec', not have_vp8_decoder ],
  95   [ 'elements/vp9enc', not have_vp9_encoder ],
  96   [ 'pipelines/wavenc' ],
  97   [ 'elements/wavpackdec', not wavpack_dep.found() ],
  98   [ 'elements/wavpackenc', not wavpack_dep.found() ],
  99   [ 'pipelines/wavpack', not wavpack_dep.found() ],
 100   [ 'elements/wavparse' ],
 101   [ 'elements/y4menc' ],
 102   [ 'pipelines/effectv' ],
 103   [ 'elements/equalizer' ],
 104   [ 'generic/states' ],
 105   [ 'pipelines/simple-launch-lines' ],
 106   [ 'pipelines/tagschecking' ],
 107 ]
 108
 109 # FIXME: valgrind elements/rtp-payloading - needs fixing
 110 # elements/videocrop should be disabled since it takes way too long in valgrind
 111
 112 foo='''
 113 if HAVE_ORC
 114 check_orc = orc/deinterlace orc/videomixer orc/videobox
 115 else
 116 check_orc =
 117 endif
 118 '''
 119
 120 test_defines = [
 121   '-UG_DISABLE_ASSERT',
 122   '-UG_DISABLE_CAST_CHECKS',
 123   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_PLUGIN_LOADING_WHITELIST"',
 124   '-DGST_TEST_FILES_PATH="' + meson.source_root() + '/tests/files"',
 125   '-DGST_USE_UNSTABLE_API',
 126 ]
 127
 128 getpluginsdir = find_program('getpluginsdir')
 129 runcmd = run_command(getpluginsdir, 'gstreamer', 'gstreamer-' + api_version,
 130         'gst-plugins-base', 'gstreamer-plugins-base-' + api_version)
 131 if runcmd.returncode() == 0
 132   other_plugins_dir = runcmd.stdout().strip()
 133   message('Using GStreamer plug-ins in ' + other_plugins_dir)
 134 else
 135   error('Could not determine GStreamer plugins directory for unit tests.')
 136 endif
 137
 138 # fake device drivers: we could run hardware element tests against dummy drivers
 139 # v4l2: vivo (part of normal kernel)
 140 #   modprobe vivo;
 141 #   gst-launch v4l2src device="/dev/video1" ! xvimagesink;
 142 #   rmmod vivo
 143 #
 144 # alsa: snd-dummy (part of normal alsa, not removable)
 145 #   modprobe snd-dummy;
 146 #   gst-launch alsasrc device="hw:2" ! fakesink
 147 #   gst-launch fakesrc ! alsasink device="hw:2"
 148 #
 149 # need a way to figure out value for the device property
 150 state_ignore_elements = '''aasink autoaudiosrc autoaudiosink autovideosrc
 151  autovideosink cacasink cairotextoverlay jackaudiosrc jackaudiosink
 152  osssrc osssink osxaudiosink osxaudiosrc osxvideosrc osxvideosink
 153  pulsesink pulsesrc pulsemixer v4l2src'''
 154
 155 # FIXME: WHITELIST should probably refer to core/base paths properly
 156 # (need to make this work right for the subproject case too)
 157 test_env = [
 158   'GST_PLUGIN_SYSTEM_PATH_1_0=',
 159   'GST_PLUGIN_PATH_1_0=' + meson.build_root() + '/gst:' + meson.build_root() + '/ext:' + meson.build_root() + '/sys:' + other_plugins_dir,
 160   'GST_PLUGIN_LOADING_WHITELIST=gstreamer:gst-plugins-base:gst-plugins-good@' + meson.build_root(),
 161   'GST_STATE_IGNORE_ELEMENTS=@0@'.format(state_ignore_elements),
 162   'CK_DEFAULT_TIMEOUT=20',
 163   'GSETTINGS_BACKEND=memory',
 164 ]
 165
 166 # FIXME: check, also + PTHREAD_CFLAGS
 167 test_deps = [gst_dep, gstbase_dep, gstnet_dep, gstcheck_dep, gstaudio_dep,
 168   gstvideo_dep, gstpbutils_dep, gstrtp_dep, gstrtsp_dep, gsttag_dep,
 169   gstapp_dep, gio_dep] + glib_deps
 170
 171 # FIXME: add valgrind suppression common/gst.supp gst-plugins-good.supp
 172 foreach t : good_tests
 173   test_name = t.get(0)
 174   extra_deps = [ ]
 175   if t.length() == 3
 176     extra_deps = t.get(2)
 177     skip_test = t.get(1)
 178   elif t.length() == 2
 179     skip_test = t.get(1)
 180   else
 181     skip_test = false
 182   endif
 183   if not skip_test
 184     exe = executable(test_name, '@0@.c'.format(test_name),
 185       include_directories : [configinc],
 186       c_args : ['-DHAVE_CONFIG_H=1' ] + test_defines,
 187       dependencies : [libm] + test_deps + extra_deps,
 188     )
 189     test(test_name, exe,
 190       env: test_env + ['GST_REGISTRY=@0@/@1@.registry'.format(meson.current_build_dir(), test_name)],
 191       timeout: 3 * 60
 192     )
 193   endif
 194 endforeach
 195
 196 # FIXME: orc tests
 197 fixme_orc_tests='''
 198 orc_deinterlace_CFLAGS = $(ORC_CFLAGS)
 199 orc_deinterlace_LDADD = $(ORC_LIBS) -lorc-test-0.4
 200 nodist_orc_deinterlace_SOURCES = orc/deinterlace.c
 201 orc_videomixer_CFLAGS = $(ORC_CFLAGS)
 202 orc_videomixer_LDADD = $(ORC_LIBS) -lorc-test-0.4
 203 nodist_orc_videomixer_SOURCES = orc/videomixer.c
 204 orc_videobox_CFLAGS = $(ORC_CFLAGS)
 205 orc_videobox_LDADD = $(ORC_LIBS) -lorc-test-0.4
 206 nodist_orc_videobox_SOURCES = orc/videobox.c
 207
 208 orc/deinterlace.c: $(top_srcdir)/gst/deinterlace/tvtime.orc
 209         $(MKDIR_P) orc/
 210         $(ORCC) --test -o $@ $<
 211
 212 orc/videomixer.c: $(top_srcdir)/gst/videomixer/videomixerorc.orc
 213         $(MKDIR_P) orc/
 214         $(ORCC) --test -o $@ $<
 215
 216 orc/videobox.c: $(top_srcdir)/gst/videobox/gstvideoboxorc.orc
 217         $(MKDIR_P) orc/
 218         $(ORCC) --test -o $@ $<
 219 '''