tests/check/meson.build

   1 valgrind_dep = dependency('valgrind', required: false).partial_dependency(compile_args : true)
   2 if valgrind_dep.found()
   3   cdata.set('HAVE_VALGRIND', 1)
   4 endif
   5
   6 # internal helper lib for unit testing audio parsers
   7 libparser = static_library('libparser', 'elements/parser.c',
   8   c_args : gst_plugins_good_args + ['-DGST_USE_UNSTABLE_API'],
   9   include_directories : [configinc],
  10   dependencies : [gstcheck_dep],
  11   install : false)
  12
  13 libparser_dep = declare_dependency(link_with : libparser,
  14   dependencies : gstcheck_dep)
  15
  16 # name, condition when to skip the test and extra dependencies
  17 good_tests = [
  18   [ 'elements/audioamplify', false, [gstfft_dep] ],
  19   [ 'elements/audiochebband', false, [gstfft_dep] ],
  20   [ 'elements/audiocheblimit', false, [gstfft_dep] ],
  21   [ 'elements/audiodynamic', false, [gstfft_dep] ],
  22   [ 'elements/audioecho', false, [gstfft_dep] ],
  23   [ 'elements/audiofirfilter', false, [gstfft_dep] ],
  24   [ 'elements/audioiirfilter', false, [gstfft_dep] ],
  25   [ 'elements/audioinvert', false, [gstfft_dep] ],
  26   [ 'elements/audiopanorama', false, [gstfft_dep] ],
  27   [ 'elements/audiowsincband', false, [gstfft_dep] ],
  28   [ 'elements/audiowsinclimit', false, [gstfft_dep] ],
  29   [ 'elements/alphacolor' ],
  30   [ 'elements/alpha' ],
  31   [ 'elements/avimux', false, [gstriff_dep] ],
  32   [ 'elements/avisubtitle', false, [gstriff_dep] ],
  33   [ 'elements/capssetter' ],
  34   [ 'elements/aacparse', false, [libparser_dep] ],
  35   [ 'elements/ac3parse', false, [libparser_dep] ],
  36   [ 'elements/amrparse', false, [libparser_dep] ],
  37   [ 'elements/flacparse', false, [libparser_dep] ],
  38   [ 'elements/mpegaudioparse', false, [libparser_dep] ],
  39   [ 'elements/autodetect' ],
  40   [ 'elements/deinterlace' ],
  41   [ 'elements/dtmf' ],
  42   [ 'elements/flvdemux' ],
  43   [ 'elements/flvmux' ],
  44   [ 'elements/mulawdec' ],
  45   [ 'elements/mulawenc' ],
  46   [ 'elements/icydemux' ],
  47   [ 'elements/id3demux' ],
  48   [ 'elements/imagefreeze' ],
  49   [ 'elements/deinterleave' ],
  50   [ 'elements/interleave' ],
  51   [ 'elements/level' ],
  52   [ 'elements/matroskademux', false, [gstriff_dep] ],
  53   [ 'elements/matroskamux', false, [gstriff_dep] ],
  54   [ 'elements/matroskaparse', false, [gstriff_dep] ],
  55   [ 'elements/multifile' ],
  56   [ 'elements/splitmuxsink', ],
  57   [ 'elements/splitmuxsinktimecode', ],
  58   [ 'elements/splitmuxsrc', ],
  59   [ 'elements/qtmux', false, [gstriff_dep, zlib_dep] ],
  60   [ 'elements/qtdemux', false, [gstriff_dep, zlib_dep] ],
  61   [ 'elements/rganalysis' ],
  62   [ 'elements/rglimiter' ],
  63   [ 'elements/rgvolume' ],
  64   [ 'elements/rtph261' ],
  65   [ 'elements/rtph263' ],
  66   [ 'elements/rtph264' ],
  67   [ 'elements/rtph265' ],
  68   [ 'elements/rtpopus' ],
  69   [ 'elements/rtpvp9' ],
  70   [ 'elements/rtpbin' ],
  71   [ 'elements/rtpbin_buffer_list' ],
  72   [ 'elements/rtpcollision' ],
  73   [ 'elements/rtpfunnel' ],
  74   [ 'elements/rtpjitterbuffer' ],
  75   [ 'elements/rtpjpeg' ],
  76
  77   [ 'elements/rtptimerqueue', false, [gstrtp_dep],
  78       ['../../gst/rtpmanager/rtptimerqueue.c']],
  79
  80   [ 'elements/rtpmux' ],
  81   [ 'elements/rtpptdemux' ],
  82   [ 'elements/rtprtx' ],
  83   [ 'elements/rtpsession' ],
  84   [ 'elements/rtpstorage', false, [],  ['../../gst/rtp/gstrtpstorage.c',
  85                                         '../../gst/rtp/rtpstorage.c',
  86                                         '../../gst/rtp/rtpstoragestream.c']],
  87   [ 'elements/rtpred' ],
  88   [ 'elements/rtpulpfec' ],
  89   [ 'elements/rtpssrcdemux' ],
  90   [ 'elements/rtp-payloading' ],
  91   [ 'elements/spectrum', false, [gstfft_dep] ],
  92   [ 'elements/shapewipe' ],
  93   [ 'elements/udpsink' ],
  94   [ 'elements/udpsrc' ],
  95   [ 'elements/videobox' ],
  96   [ 'elements/videocrop' ],
  97   [ 'elements/videofilter' ],
  98   [ 'elements/videomixer' ],
  99   [ 'elements/aspectratiocrop' ],
 100   [ 'pipelines/wavenc' ],
 101   [ 'elements/wavparse', false, [gstriff_dep] ],
 102   [ 'elements/wavpackparse', ],
 103   [ 'elements/y4menc' ],
 104   [ 'pipelines/effectv' ],
 105   [ 'elements/equalizer' ],
 106   [ 'pipelines/simple-launch-lines' ],
 107   [ 'pipelines/tagschecking' ],
 108   [ 'generic/states' ],
 109 ]
 110
 111 # FIXME: valgrind elements/rtp-payloading - needs fixing
 112 # elements/videocrop should be disabled since it takes way too long in valgrind
 113
 114 # FIXME: unistd dependency or not tested yet on windows
 115 if host_machine.system() != 'windows'
 116   good_tests += [
 117     [ 'pipelines/flacdec', not flac_dep.found() ],
 118     [ 'elements/gdkpixbufsink', not gdkpixbuf_dep.found(), [gdkpixbuf_dep] ],
 119     [ 'elements/gdkpixbufoverlay', not gdkpixbuf_dep.found() ],
 120     [ 'elements/jpegdec', not jpeglib.found() ],
 121     [ 'elements/jpegenc', not jpeglib.found() ],
 122     [ 'elements/mpg123audiodec', not mpg123_dep.found(),  [gstfft_dep]],
 123     [ 'elements/souphttpsrc', not libsoup_dep.found(), [libsoup_dep] ],
 124     [ 'elements/id3v2mux', not taglib_dep.found() ],
 125     [ 'elements/apev2mux', not taglib_dep.found() ],
 126     [ 'elements/vp8enc', not vpx_dep.found() or not have_vp8_encoder ],
 127     [ 'elements/vp8dec', not vpx_dep.found() or not have_vp8_decoder ],
 128     [ 'elements/vp9enc', not vpx_dep.found() or not have_vp9_encoder ],
 129     [ 'pipelines/lame', not lame_dep.found() ],
 130     [ 'elements/wavpackdec', not wavpack_dep.found() ],
 131     [ 'elements/wavpackenc', not wavpack_dep.found() ],
 132     [ 'pipelines/wavpack', not wavpack_dep.found() ],
 133   ]
 134 endif
 135
 136 foo='''
 137 if HAVE_ORC
 138 check_orc = orc/deinterlace orc/videomixer orc/videobox
 139 else
 140 check_orc =
 141 endif
 142 '''
 143
 144 test_defines = [
 145   '-UG_DISABLE_ASSERT',
 146   '-UG_DISABLE_CAST_CHECKS',
 147   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_PLUGIN_LOADING_WHITELIST"',
 148   '-DGST_TEST_FILES_PATH="' + meson.current_source_dir() + '/../files"',
 149   '-DGST_USE_UNSTABLE_API',
 150 ]
 151
 152 pluginsdirs = []
 153 if gst_dep.type_name() == 'pkgconfig'
 154   pbase = dependency('gstreamer-plugins-base-' + api_version, required: true)
 155   pluginsdirs = [gst_dep.get_pkgconfig_variable('pluginsdir'),
 156                  pbase.get_pkgconfig_variable('pluginsdir')]
 157   gst_plugin_scanner_dir = gst_dep.get_pkgconfig_variable('pluginscannerdir')
 158 else
 159   gst_plugin_scanner_dir = subproject('gstreamer').get_variable('gst_scanner_dir')
 160 endif
 161 gst_plugin_scanner_path = join_paths(gst_plugin_scanner_dir, 'gst-plugin-scanner')
 162
 163 # fake device drivers: we could run hardware element tests against dummy drivers
 164 # v4l2: vivo (part of normal kernel)
 165 #   modprobe vivo;
 166 #   gst-launch v4l2src device="/dev/video1" ! xvimagesink;
 167 #   rmmod vivo
 168 #
 169 # alsa: snd-dummy (part of normal alsa, not removable)
 170 #   modprobe snd-dummy;
 171 #   gst-launch alsasrc device="hw:2" ! fakesink
 172 #   gst-launch fakesrc ! alsasink device="hw:2"
 173 #
 174 # need a way to figure out value for the device property
 175 state_ignore_elements = '''aasink autoaudiosrc autoaudiosink autovideosrc
 176  autovideosink cacasink cairotextoverlay gtkglsink gtksink jackaudiosrc
 177  jackaudiosink osssrc osssink osxaudiosink osxaudiosrc osxvideosrc osxvideosink
 178  pulsesink pulsesrc pulsemixer v4l2src'''
 179
 180 # FIXME: check, also + PTHREAD_CFLAGS
 181 test_deps = [gst_dep, gstbase_dep, gstnet_dep, gstcheck_dep, gstaudio_dep,
 182   gstvideo_dep, gstpbutils_dep, gstrtp_dep, gstrtsp_dep, gsttag_dep,
 183   gstapp_dep, gio_dep, valgrind_dep] + glib_deps
 184
 185 # FIXME: add valgrind suppression common/gst.supp gst-plugins-good.supp
 186 foreach t : good_tests
 187   fname = '@0@.c'.format(t.get(0))
 188   test_name = t.get(0).underscorify()
 189   extra_sources = t.get(3, [ ])
 190   extra_deps = t.get(2, [ ])
 191   skip_test = t.get(1, false)
 192   if not skip_test
 193     env = environment()
 194     env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
 195     env.set('GST_STATE_IGNORE_ELEMENTS', state_ignore_elements)
 196     env.set('CK_DEFAULT_TIMEOUT', '20')
 197     env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-plugins-base',
 198       'gst-plugins-bad', 'gst-plugins-good@' + meson.build_root())
 199     env.set('GST_PLUGIN_PATH_1_0', [meson.build_root()] + pluginsdirs)
 200     env.set('GSETTINGS_BACKEND', 'memory')
 201
 202     env.set('GST_REGISTRY', join_paths(meson.current_build_dir(), '@0@.registry'.format(test_name)))
 203     env.set('GST_PLUGIN_SCANNER_1_0', gst_plugin_scanner_path)
 204     exe = executable(test_name, fname, extra_sources,
 205       include_directories : [configinc, libsinc],
 206       c_args : ['-DHAVE_CONFIG_H=1' ] + test_defines,
 207       dependencies : [libm] + test_deps + extra_deps,
 208     )
 209     test(test_name, exe, env: env, timeout: 3 * 60)
 210   endif
 211 endforeach
 212
 213 # orc tests
 214 orc_tests = [
 215   ['orc_deinterlace', files('../../gst/deinterlace/tvtime.orc')],
 216   ['orc_videomixer', files('../../gst/videomixer/videomixerorc.orc')],
 217   ['orc_videobox', files('../../gst/videobox/gstvideoboxorc.orc')],
 218 ]
 219
 220 orc_test_dep = dependency('', required : false)
 221 if have_orcc
 222   # FIXME: there should really just be a separate orc-test-0.4.pc file for this
 223   if orc_dep.type_name() == 'pkgconfig'
 224     orc_test_dep = cc.find_library('orc-test-0.4', required : false)
 225   else
 226     orc_test_dep = dependency('', fallback: ['orc', 'orc_test_dep'], required: false)
 227   endif
 228 endif
 229
 230 if have_orcc and orc_test_dep.found()
 231   foreach t : orc_tests
 232     tname = t[0]
 233     torcfile = t[1]
 234     tcfilename = '@0@.c'.format(tname)
 235     test_c = custom_target(tcfilename,
 236       output: tcfilename,
 237       input: torcfile,
 238       command: [orcc, '--include', 'stdint.h', '--test', '-o', '@OUTPUT@', '@INPUT@'])
 239     test_exe = executable(tname, test_c, dependencies: [orc_dep, orc_test_dep])
 240     test(tname, test_exe)
 241   endforeach
 242 endif