tests/check/meson.build

   1 have_registry = true # FIXME get_option('registry')
   2
   3 libparser = static_library('parser',
   4   'elements/parser.c',
   5   install : false,
   6   dependencies : [gst_dep, gstcheck_dep],
   7 )
   8
   9 libparser_dep = declare_dependency(link_with: libparser,
  10   sources: ['elements/parser.h'])
  11
  12 # FIXME: automagic
  13 exif_dep = dependency('libexif', version : '>= 0.6.16', required : false)
  14
  15 # Since nalutils API is internal, need to build it again
  16 nalutils_dep = gstcodecparsers_dep.partial_dependency (compile_args: true, includes: true)
  17
  18 enable_gst_player_tests = get_option('gst_player_tests')
  19
  20 # name, condition when to skip the test and extra dependencies
  21 base_tests = [
  22   [['elements/aiffparse.c']],
  23   [['elements/asfmux.c']],
  24   [['elements/autoconvert.c']],
  25   [['elements/autovideoconvert.c']],
  26   [['elements/avwait.c']],
  27   [['elements/camerabin.c']],
  28   [['elements/d3d11colorconvert.c'], host_machine.system() != 'windows', ],
  29   [['elements/cudaconvert.c'], false, [gmodule_dep, gstgl_dep]],
  30   [['elements/cudafilter.c'], false, [gmodule_dep, gstgl_dep]],
  31   [['elements/gdpdepay.c']],
  32   [['elements/gdppay.c']],
  33   [['elements/h263parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  34   [['elements/h264parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  35   [['elements/h265parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  36   [['elements/hlsdemux_m3u8.c'], not hls_dep.found(), [hls_dep]],
  37   [['elements/id3mux.c']],
  38   [['elements/jpeg2000parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  39   [['elements/mfvideosrc.c'], host_machine.system() != 'windows', ],
  40   [['elements/mpegtsdemux.c'], false, [gstmpegts_dep]],
  41   [['elements/mpegtsmux.c'], false, [gstmpegts_dep]],
  42   [['elements/mpeg4videoparse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  43   [['elements/mpegvideoparse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  44   [['elements/msdkh264enc.c'], not have_msdk, [msdk_dep]],
  45   [['elements/mxfdemux.c']],
  46   [['elements/mxfmux.c']],
  47   [['elements/nvenc.c'], false, [gmodule_dep, gstgl_dep]],
  48   [['elements/nvdec.c'], not gstgl_dep.found(), [gmodule_dep, gstgl_dep]],
  49   [['elements/svthevcenc.c'], not svthevcenc_dep.found(), [svthevcenc_dep]],
  50   [['elements/pcapparse.c'], false, [libparser_dep]],
  51   [['elements/pnm.c']],
  52   [['elements/ristrtpext.c']],
  53   [['elements/rtponvifparse.c']],
  54   [['elements/rtponviftimestamp.c']],
  55   [['elements/rtpsrc.c']],
  56   [['elements/rtpsink.c']],
  57   [['elements/switchbin.c']],
  58   [['elements/videoframe-audiolevel.c']],
  59   [['elements/viewfinderbin.c']],
  60   [['elements/vp9parse.c'], false, [gstcodecparsers_dep]],
  61   [['elements/wasapi2.c'], host_machine.system() != 'windows', ],
  62   [['libs/h264parser.c'], false, [gstcodecparsers_dep]],
  63   [['libs/h265parser.c'], false, [gstcodecparsers_dep]],
  64   [['libs/insertbin.c'], false, [gstinsertbin_dep]],
  65   [['libs/isoff.c'], false, [gstisoff_dep]],
  66   [['libs/nalutils.c', '../../gst-libs/gst/codecparsers/nalutils.c'], false, [nalutils_dep]],
  67   [['libs/mpegts.c'], false, [gstmpegts_dep]],
  68   [['libs/mpegvideoparser.c'], false, [gstcodecparsers_dep]],
  69   [['libs/planaraudioadapter.c'], false, [gstbadaudio_dep]],
  70   [['libs/player.c'], not enable_gst_player_tests, [gstplayer_dep]],
  71   [['libs/vc1parser.c'], false, [gstcodecparsers_dep]],
  72   [['libs/vp8parser.c'], false, [gstcodecparsers_dep]],
  73   [['libs/vp9parser.c'], false, [gstcodecparsers_dep]],
  74   [['libs/av1parser.c'], false, [gstcodecparsers_dep]],
  75   [['libs/vkmemory.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  76   [['elements/vkcolorconvert.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  77   [['libs/vkwindow.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  78   [['libs/vkdevice.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  79   [['elements/vkdeviceprovider.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  80   [['libs/vkcommandpool.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  81   [['libs/vkimage.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  82   [['libs/vkinstance.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  83 ]
  84
  85 # FIXME: unistd dependency, unstable or not tested yet on windows
  86 if host_machine.system() != 'windows'
  87   base_tests += [
  88     [['elements/assrender.c'], not ass_dep.found(), [ass_dep]],
  89     [['elements/avtpaafpay.c'], not avtp_dep.found(), [avtp_dep]],
  90     [['elements/avtpaafdepay.c'], not avtp_dep.found(), [avtp_dep]],
  91     [['elements/avtpcrfbase.c'], not avtp_dep.found(), [avtp_dep]],
  92     [['elements/avtpcrfcheck.c'], not avtp_dep.found(), [avtp_dep], ['../../ext/avtp/gstavtpcrfutil.c']],
  93     [['elements/avtpcrfsync.c'], not avtp_dep.found(), [avtp_dep], ['../../ext/avtp/gstavtpcrfutil.c', '../../ext/avtp/gstavtpcrfbase.c']],
  94     [['elements/avtpcrfutil.c'], not avtp_dep.found(), [avtp_dep], ['../../ext/avtp/gstavtpcrfutil.c', '../../ext/avtp/gstavtpcrfbase.c']],
  95     [['elements/avtpcvfpay.c'], not avtp_dep.found(), [avtp_dep]],
  96     [['elements/avtpcvfdepay.c'], not avtp_dep.found(), [avtp_dep]],
  97     [['elements/avtpsink.c'], not avtp_dep.found(), [avtp_dep]],
  98     [['elements/avtpsrc.c'], not avtp_dep.found(), [avtp_dep]],
  99     [['elements/ccconverter.c'], not gstvideo_dep.found(), [gstvideo_dep]],
 100     [['elements/cccombiner.c']],
 101     [['elements/ccextractor.c']],
 102     [['elements/clockselect.c']],
 103     [['elements/line21.c']],
 104     [['elements/curlhttpsink.c'], not curl_dep.found(), [curl_dep]],
 105     [['elements/curlhttpsrc.c'], not curl_dep.found(), [curl_dep, gio_dep]],
 106     [['elements/curlfilesink.c'],
 107         not curl_dep.found() or not cdata.has('HAVE_UNISTD_H'), [curl_dep]],
 108     [['elements/curlftpsink.c'], not curl_dep.found(), [curl_dep]],
 109     [['elements/curlsmtpsink.c'], not curl_dep.found(), [curl_dep]],
 110     [['elements/dash_mpd.c'], not xml2_dep.found(), [xml2_dep]],
 111     [['elements/dtls.c'], not libcrypto_dep.found(), [libcrypto_dep]],
 112     [['elements/faac.c'],
 113         not faac_dep.found() or not cc.has_header_symbol('faac.h', 'faacEncOpen') or not cdata.has('HAVE_UNISTD_H'),
 114         [faac_dep]],
 115     [['elements/faad.c'],
 116         not faad_dep.found() or not have_faad_2_7 or not cdata.has('HAVE_UNISTD_H'),
 117         [faad_dep]],
 118     [['elements/jifmux.c'],
 119         not exif_dep.found() or not cdata.has('HAVE_UNISTD_H'), [exif_dep]],
 120     [['elements/jpegparse.c'], not cdata.has('HAVE_UNISTD_H')],
 121     [['elements/kate.c'],
 122         not kate_dep.found() or not cdata.has('HAVE_UNISTD_H'), [kate_dep]],
 123     [['elements/netsim.c']],
 124     [['elements/shm.c'], not shm_enabled, shm_deps],
 125     [['elements/voaacenc.c'],
 126         not voaac_dep.found() or not cdata.has('HAVE_UNISTD_H'), [voaac_dep]],
 127     [['elements/webrtcbin.c'], not libnice_dep.found(), [gstwebrtc_dep]],
 128     [['elements/x265enc.c'], not x265_dep.found(), [x265_dep]],
 129     [['elements/zbar.c'], not zbar_dep.found(), [zbar_dep]],
 130     [['elements/zxing.c'], not zxing_dep.found(), [zxing_dep]],
 131   ]
 132 endif
 133
 134 test_defines = [
 135   '-UG_DISABLE_ASSERT',
 136   '-UG_DISABLE_CAST_CHECKS',
 137   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_STATE_IGNORE_ELEMENTS"',
 138   '-DGST_TEST_FILES_PATH="' + meson.current_source_dir() + '/../files"',
 139   '-DTEST_PATH="' + meson.current_build_dir() + '/media"',
 140   '-DDASH_MPD_DATADIR=' + meson.current_source_dir() + '/elements/dash_mpd_data',
 141   '-DGST_USE_UNSTABLE_API',
 142 ]
 143
 144 test_deps = [gst_dep, gstapp_dep, gstbase_dep,
 145              gstbasecamerabin_dep, gstphotography_dep,
 146              gstpbutils_dep, gstcontroller_dep, gstaudio_dep,
 147              gstvideo_dep, gstrtp_dep, gsturidownloader_dep,
 148              gstcheck_dep, gio_dep, glib_dep, gsttag_dep]
 149
 150 pluginsdirs = [  ]
 151
 152 if gst_dep.type_name() == 'pkgconfig'
 153   pbase = dependency('gstreamer-plugins-base-' + api_version)
 154
 155   pluginsdirs = [gst_dep.get_pkgconfig_variable('pluginsdir'),
 156                  pbase.get_pkgconfig_variable('pluginsdir')]
 157   gst_plugin_scanner_dir = gst_dep.get_pkgconfig_variable('pluginscannerdir')
 158 else
 159   gst_plugin_scanner_dir = subproject('gstreamer').get_variable('gst_scanner_dir')
 160 endif
 161 gst_plugin_scanner_path = join_paths(gst_plugin_scanner_dir, 'gst-plugin-scanner')
 162
 163 foreach t : base_tests
 164   fnames = t.get(0)
 165   test_name = fnames[0].split('.').get(0).underscorify()
 166   skip_test = false
 167   extra_deps = [ ]
 168
 169   if t.length() >= 3
 170     extra_deps = t.get(2)
 171   endif
 172
 173   if t.length() >= 2
 174     skip_test = t.get(1)
 175   endif
 176
 177   extra_sources = t.get(3, [ ])
 178
 179   if not skip_test
 180     exe = executable(test_name, fnames, extra_sources,
 181       include_directories : [configinc],
 182       c_args : gst_plugins_bad_args + test_defines,
 183       cpp_args : gst_plugins_bad_args + test_defines,
 184       dependencies : [libm] + test_deps + extra_deps,
 185     )
 186
 187     env = environment()
 188     env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
 189     env.set('CK_DEFAULT_TIMEOUT', '20')
 190     env.set('GST_STATE_IGNORE_ELEMENTS', '')
 191     env.set('GST_PLUGIN_PATH_1_0', [meson.build_root()] + pluginsdirs)
 192     env.set('GST_REGISTRY', join_paths(meson.current_build_dir(), '@0@.registry'.format(test_name)))
 193     env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-plugins-base',
 194       'gst-plugins-good', 'gst-plugins-ugly','gst-libav', 'libnice',
 195       'gst-plugins-bad@' + meson.build_root())
 196     env.set('GST_PLUGIN_SCANNER_1_0', gst_plugin_scanner_path)
 197     test(test_name, exe, env: env, timeout: 3 * 60)
 198   endif
 199 endforeach
 200
 201 # orc tests
 202 orc_tests = [
 203   ['orc_bayer', files('../../gst/bayer/gstbayerorc.orc')],
 204 ]
 205
 206 orc_test_dep = dependency('', required : false)
 207 if have_orcc
 208   # FIXME: there should really just be a separate orc-test-0.4.pc file for this
 209   if orc_dep.type_name() == 'pkgconfig'
 210     orc_test_dep = cc.find_library('orc-test-0.4', required : false)
 211   else
 212     orc_test_dep = dependency('', fallback: ['orc', 'orc_test_dep'], required: false)
 213   endif
 214 endif
 215
 216 if have_orcc and orc_test_dep.found()
 217   foreach t : orc_tests
 218     tname = t[0]
 219     torcfile = t[1]
 220     tcfilename = '@0@.c'.format(tname)
 221     test_c = custom_target(tcfilename,
 222       output: tcfilename,
 223       input: torcfile,
 224       command: [orcc, '--include', 'stdint.h', '--test', '-o', '@OUTPUT@', '@INPUT@'])
 225     test_exe = executable(tname, test_c, dependencies: [orc_dep, orc_test_dep])
 226     test(tname, test_exe)
 227   endforeach
 228 endif
 229
 230 if enable_gst_player_tests
 231   subdir ('media')
 232 endif