tests/check/meson.build

   1 have_registry = true # FIXME get_option('registry')
   2
   3 libparser = static_library('parser',
   4   'elements/parser.c',
   5   install : false,
   6   dependencies : [gst_dep, gstcheck_dep],
   7 )
   8
   9 libparser_dep = declare_dependency(link_with: libparser,
  10   sources: ['elements/parser.h'])
  11
  12 # FIXME: automagic
  13 exif_dep = dependency('libexif', version : '>= 0.6.16', required : false)
  14
  15 enable_gst_player_tests = get_option('gst_player_tests')
  16
  17 # Need explicit dependency listing for nvenc on Windows
  18 nvenc_test_deps = []
  19 if cuda_dep.found() and cudart_dep.found()
  20   nvenc_test_deps += [cuda_dep, cudart_dep, gmodule_dep, gstgl_dep]
  21   if use_nvenc_gl
  22     nvenc_test_deps += gstgl_dep
  23   endif
  24 endif
  25
  26 # name, condition when to skip the test and extra dependencies
  27 base_tests = [
  28   [['elements/aiffparse.c']],
  29   [['elements/asfmux.c']],
  30   [['elements/autoconvert.c']],
  31   [['elements/autovideoconvert.c']],
  32   [['elements/avwait.c']],
  33   [['elements/camerabin.c']],
  34   [['elements/gdpdepay.c']],
  35   [['elements/gdppay.c']],
  36   [['elements/h263parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  37   [['elements/h264parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  38   [['elements/id3mux.c']],
  39   [['elements/mpegtsmux.c'], false, [gstmpegts_dep]],
  40   [['elements/mpeg4videoparse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  41   [['elements/mpegvideoparse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  42   [['elements/msdkh264enc.c'], not have_msdk, [msdk_dep]],
  43   [['elements/mxfdemux.c']],
  44   [['elements/mxfmux.c']],
  45   [['elements/nvenc.c'], not cuda_dep.found() or not cudart_dep.found(), nvenc_test_deps],
  46   [['elements/pcapparse.c'], false, [libparser_dep]],
  47   [['elements/pnm.c']],
  48   [['elements/rtponvifparse.c']],
  49   [['elements/rtponviftimestamp.c']],
  50   [['elements/rtpsrc.c']],
  51   [['elements/rtpsink.c']],
  52   [['elements/videoframe-audiolevel.c']],
  53   [['elements/viewfinderbin.c']],
  54   [['libs/h264parser.c'], false, [gstcodecparsers_dep]],
  55   [['libs/h265parser.c'], false, [gstcodecparsers_dep]],
  56   [['libs/insertbin.c'], false, [gstinsertbin_dep]],
  57   [['libs/isoff.c'], false, [gstisoff_dep]],
  58   [['libs/mpegts.c'], false, [gstmpegts_dep]],
  59   [['libs/mpegvideoparser.c'], false, [gstcodecparsers_dep]],
  60   [['libs/planaraudioadapter.c'], false, [gstbadaudio_dep]],
  61   [['libs/player.c'], not enable_gst_player_tests, [gstplayer_dep]],
  62   [['libs/vc1parser.c'], false, [gstcodecparsers_dep]],
  63   [['libs/vp8parser.c'], false, [gstcodecparsers_dep]],
  64 ]
  65
  66 # FIXME: unistd dependency, unstable or not tested yet on windows
  67 if host_machine.system() != 'windows'
  68   base_tests += [
  69     [['elements/assrender.c'], not ass_dep.found(), [ass_dep]],
  70     [['elements/ccconverter.c']],
  71     [['elements/cccombiner.c']],
  72     [['elements/ccextractor.c']],
  73     [['elements/line21.c']],
  74     [['elements/curlhttpsink.c'], not curl_dep.found(), [curl_dep]],
  75     [['elements/curlhttpsrc.c'], not curl_dep.found(), [curl_dep, gio_dep]],
  76     [['elements/curlfilesink.c'],
  77         not curl_dep.found() or not cdata.has('HAVE_UNISTD_H'), [curl_dep]],
  78     [['elements/curlftpsink.c'], not curl_dep.found(), [curl_dep]],
  79     [['elements/curlsmtpsink.c'], not curl_dep.found(), [curl_dep]],
  80     [['elements/dash_mpd.c'], not xml2_dep.found(), [xml2_dep]],
  81     [['elements/dtls.c'], not libcrypto_dep.found(), [libcrypto_dep]],
  82     [['elements/faac.c'],
  83         not faac_dep.found() or not cc.has_header_symbol('faac.h', 'faacEncOpen') or not cdata.has('HAVE_UNISTD_H'),
  84         [faac_dep]],
  85     [['elements/faad.c'],
  86         not faad_dep.found() or not have_faad_2_7 or not cdata.has('HAVE_UNISTD_H'),
  87         [faad_dep]],
  88     [['elements/jifmux.c'],
  89         not exif_dep.found() or not cdata.has('HAVE_UNISTD_H'), [exif_dep]],
  90     [['elements/jpegparse.c'], not cdata.has('HAVE_UNISTD_H')],
  91     [['elements/kate.c'],
  92         not kate_dep.found() or not cdata.has('HAVE_UNISTD_H'), [kate_dep]],
  93     [['elements/netsim.c']],
  94     [['elements/shm.c'], not shm_enabled, shm_deps],
  95     [['elements/voaacenc.c'],
  96         not voaac_dep.found() or not cdata.has('HAVE_UNISTD_H'), [voaac_dep]],
  97     [['elements/webrtcbin.c'], not libnice_dep.found(), [gstwebrtc_dep]],
  98     [['elements/x265enc.c'], not x265_dep.found(), [x265_dep]],
  99     [['elements/zbar.c'], not zbar_dep.found(), [zbar_dep]],
 100   ]
 101 endif
 102
 103 test_defines = [
 104   '-UG_DISABLE_ASSERT',
 105   '-UG_DISABLE_CAST_CHECKS',
 106   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_STATE_IGNORE_ELEMENTS"',
 107   '-DGST_TEST_FILES_PATH="' + meson.current_source_dir() + '/../files"',
 108   '-DTEST_PATH="' + meson.current_build_dir() + '/media"',
 109   '-DDASH_MPD_DATADIR=' + meson.current_source_dir() + '/elements/dash_mpd_data',
 110   '-DGST_USE_UNSTABLE_API',
 111 ]
 112
 113 test_deps = [gst_dep, gstapp_dep, gstbase_dep,
 114              gstbasecamerabin_dep, gstphotography_dep,
 115              gstpbutils_dep, gstcontroller_dep, gstaudio_dep,
 116              gstvideo_dep, gstrtp_dep, gsturidownloader_dep,
 117              gstcheck_dep, gio_dep, glib_dep, gsttag_dep]
 118
 119 pluginsdirs = [  ]
 120
 121 if gst_dep.type_name() == 'pkgconfig'
 122   pbase = dependency('gstreamer-plugins-base-' + api_version)
 123
 124   pluginsdirs = [gst_dep.get_pkgconfig_variable('pluginsdir')] + [pbase.get_pkgconfig_variable('pluginsdir')]
 125 endif
 126
 127 foreach t : base_tests
 128   fnames = t.get(0)
 129   test_name = fnames[0].split('.').get(0).underscorify()
 130   skip_test = false
 131   extra_deps = [ ]
 132
 133   if t.length() >= 3
 134     extra_deps = t.get(2)
 135   endif
 136
 137   if t.length() >= 2
 138     skip_test = t.get(1)
 139   endif
 140
 141   if not skip_test
 142     exe = executable(test_name, fnames,
 143       include_directories : [configinc],
 144       c_args : ['-DHAVE_CONFIG_H=1' ] + test_defines,
 145       cpp_args : gst_plugins_bad_args,
 146       dependencies : [libm] + test_deps + extra_deps,
 147     )
 148
 149     env = environment()
 150     env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
 151     env.set('CK_DEFAULT_TIMEOUT', '20')
 152     env.set('GST_STATE_IGNORE_ELEMENTS', '')
 153     env.set('GST_PLUGIN_PATH_1_0', [meson.build_root()] + pluginsdirs)
 154     env.set('GST_REGISTRY', join_paths(meson.current_build_dir(), '@0@.registry'.format(test_name)))
 155     env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-plugins-base',
 156       'gst-plugins-good', 'gst-plugins-ugly','gst-libav',
 157       'gst-plugins-bad@' + meson.build_root())
 158     test(test_name, exe, env: env, timeout: 3 * 60)
 159   endif
 160 endforeach
 161
 162 # orc tests
 163 orc_tests = [
 164   ['orc_bayer', files('../../gst/bayer/gstbayerorc.orc')],
 165 ]
 166
 167 orc_test_dep = dependency('', required : false)
 168 if have_orcc
 169   # FIXME: there should really just be a separate orc-test-0.4.pc file for this
 170   if orc_dep.type_name() == 'pkgconfig'
 171     orc_test_dep = cc.find_library('orc-test-0.4', required : false)
 172   else
 173     orc_test_dep = dependency('', fallback: ['orc', 'orc_test_dep'], required: false)
 174   endif
 175 endif
 176
 177 if have_orcc and orc_test_dep.found()
 178   foreach t : orc_tests
 179     tname = t[0]
 180     torcfile = t[1]
 181     tcfilename = '@0@.c'.format(tname)
 182     test_c = custom_target(tcfilename,
 183       output: tcfilename,
 184       input: torcfile,
 185       command: [orcc, '--include', 'stdint.h', '--test', '-o', '@OUTPUT@', '@INPUT@'])
 186     test_exe = executable(tname, test_c, dependencies: [orc_dep, orc_test_dep])
 187     test(tname, test_exe)
 188   endforeach
 189 endif
 190
 191 if enable_gst_player_tests
 192   subdir ('media')
 193 endif