subprojects/gstreamer/meson.build

   1 project('gstreamer', 'c',
   2   version : '1.22.0',
   3   meson_version : '>= 0.62',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 apiversion = '1.0'
  20 soversion = 0
  21 # maintaining compatibility with the previous libtool versioning
  22 # current = minor * 100 + micro
  23 curversion = gst_version_minor * 100 + gst_version_micro
  24 libversion = '@0@.@1@.0'.format(soversion, curversion)
  25 osxversion = curversion + 1
  26
  27 prefix = get_option('prefix')
  28
  29 datadir = join_paths(prefix, get_option('datadir'))
  30 libexecdir = get_option('libexecdir')
  31 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  32
  33 cc = meson.get_compiler('c')
  34 host_system = host_machine.system()
  35
  36 if host_system == 'darwin'
  37   ios_test_code = '''#include <TargetConditionals.h>
  38   #if ! TARGET_OS_IPHONE
  39   #error "Not iOS/tvOS/watchOS/iPhoneSimulator"
  40   #endif'''
  41   if cc.compiles(ios_test_code, name : 'building for iOS')
  42     host_system = 'ios'
  43   endif
  44
  45   add_languages('objc', native: false, required: true)
  46 endif
  47
  48 cdata = configuration_data()
  49
  50 if cc.get_id() == 'msvc'
  51   msvc_args = [
  52       # Ignore several spurious warnings for things gstreamer does very commonly
  53       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  54       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  55       # NOTE: Only add warnings here if you are sure they're spurious
  56       '/wd4018', # implicit signed/unsigned conversion
  57       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  58       '/wd4244', # lossy type conversion (e.g. double -> int)
  59       '/wd4305', # truncating type conversion (e.g. double -> float)
  60       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  61   ]
  62
  63   if gst_version_is_dev
  64     # Enable some warnings on MSVC to match GCC/Clang behaviour
  65     msvc_args += cc.get_supported_arguments([
  66       '/we4002', # too many actual parameters for macro 'identifier'
  67       '/we4003', # not enough actual parameters for macro 'identifier'
  68       '/we4013', # 'function' undefined; assuming extern returning int
  69       '/we4020', # 'function' : too many actual parameters
  70       '/we4027', # function declared without formal parameter list
  71       '/we4029', # declared formal parameter list different from definition
  72       '/we4033', # 'function' must return a value
  73       '/we4045', # 'array' : array bounds overflow
  74       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  75       '/we4053', # one void operand for '?:'
  76       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  77       '/we4098', # 'function' : void function returning a value
  78       '/we4101', # 'identifier' : unreferenced local variable
  79       '/we4189', # 'identifier' : local variable is initialized but not referenced
  80     ])
  81   endif
  82   add_project_arguments(msvc_args, language: 'c')
  83 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  84   # FIXME: Add an option for this if people ask for it
  85   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  86 endif
  87
  88 # glib doesn't support unloading, which means that unloading and reloading
  89 # any library that registers static types will fail
  90 if cc.has_link_argument('-Wl,-z,nodelete')
  91   add_project_link_arguments('-Wl,-z,nodelete', language: 'c')
  92 endif
  93
  94 # Symbol visibility
  95 have_visibility_hidden = false
  96 if cc.has_argument('-fvisibility=hidden')
  97   add_project_arguments('-fvisibility=hidden', language: 'c')
  98   have_visibility_hidden = true
  99 endif
 100
 101 # Disable strict aliasing
 102 if cc.has_argument('-fno-strict-aliasing')
 103   add_project_arguments('-fno-strict-aliasing', language: 'c')
 104 endif
 105
 106 # Define G_DISABLE_DEPRECATED for development versions
 107 if gst_version_is_dev
 108   message('Disabling deprecated GLib API')
 109   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 110 endif
 111
 112 cast_checks = get_option('gobject-cast-checks')
 113 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 114   message('Disabling GLib cast checks')
 115   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 116 endif
 117
 118 glib_asserts = get_option('glib-asserts')
 119 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 120   message('Disabling GLib asserts')
 121   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 122 endif
 123
 124 glib_checks = get_option('glib-checks')
 125 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 126   message('Disabling GLib checks')
 127   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 128 endif
 129
 130 cdata.set_quoted('GST_API_VERSION', apiversion)
 131 cdata.set_quoted('GST_DATADIR', datadir)
 132 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 133 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 134 cdata.set_quoted('GST_API_VERSION', '1.0')
 135 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 136 cdata.set_quoted('GST_LICENSE', 'LGPL')
 137 cdata.set_quoted('PACKAGE', 'gstreamer')
 138 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 139 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 140 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 141 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 142 cdata.set_quoted('PACKAGE_URL', '')
 143 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 144 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 145 cdata.set_quoted('VERSION', gst_version)
 146 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 147 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 148 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 149   description: 'plugin directory path component, used to find plugins on relocatable builds')
 150 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 151   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds')
 152 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 153
 154 mem_align_opt = get_option('memory-alignment')
 155 if mem_align_opt == 'malloc'
 156   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 157 elif mem_align_opt == 'pagesize'
 158   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 159 else
 160   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 161 endif
 162
 163 if ['darwin', 'ios'].contains(host_system)
 164   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 165 endif
 166
 167 if gst_version_nano > 0
 168     # Have GST_ERROR message printed when running from git
 169     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 170 else
 171     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 172 endif
 173
 174 # GStreamer package name and origin url
 175 gst_package_name = get_option('package-name')
 176 if gst_package_name == ''
 177   if gst_version_nano == 0
 178     gst_package_name = 'GStreamer source release'
 179   elif gst_version_nano == 1
 180     gst_package_name = 'GStreamer git'
 181   else
 182     gst_package_name = 'GStreamer prerelease'
 183   endif
 184 endif
 185 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 186 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 187
 188 # These are only needed/used by the ABI tests
 189 host_defines = [
 190   [ 'x86', 'HAVE_CPU_I386' ],
 191   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 192   [ 'arm', 'HAVE_CPU_ARM' ],
 193   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 194   [ 'mips', 'HAVE_CPU_MIPS' ],
 195   [ 'powerpc', 'HAVE_CPU_PPC' ],
 196   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 197   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 198   [ 'sparc', 'HAVE_CPU_SPARC' ],
 199   [ 'ia64', 'HAVE_CPU_IA64' ],
 200   [ 'hppa', 'HAVE_CPU_HPPA' ],
 201   [ 'm68k', 'HAVE_CPU_M68K' ],
 202   [ 's390', 'HAVE_CPU_S390' ],
 203 ]
 204 foreach h : host_defines
 205   if h.get(0) == host_machine.cpu_family()
 206     cdata.set(h.get(1), 1)
 207   endif
 208 endforeach
 209 # FIXME: should really be called HOST_CPU or such
 210 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 211
 212 check_headers = [
 213   'dlfcn.h',
 214   'inttypes.h',
 215   'memory.h',
 216   'poll.h',
 217   'stdint.h',
 218   'stdio_ext.h',
 219   'strings.h',
 220   'string.h',
 221   'sys/param.h',
 222   'sys/poll.h',
 223   'sys/prctl.h',
 224   'sys/socket.h',
 225   'sys/stat.h',
 226   'sys/times.h',
 227   'sys/time.h',
 228   'sys/types.h',
 229   'sys/utsname.h',
 230   'sys/wait.h',
 231   'ucontext.h',
 232   'unistd.h',
 233   'sys/resource.h',
 234   'sys/uio.h',
 235 ]
 236
 237 if host_system == 'windows'
 238   check_headers += ['winsock2.h']
 239 endif
 240
 241 foreach h : check_headers
 242   if cc.has_header(h)
 243     define = 'HAVE_' + h.underscorify().to_upper()
 244     cdata.set(define, 1)
 245   endif
 246 endforeach
 247
 248 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 249   cdata.set('HAVE_TM_GMTOFF', 1)
 250 endif
 251
 252 check_functions = [
 253   'gmtime_r',
 254   'sigaction',
 255   'getrusage',
 256   'fseeko',
 257   'ftello',
 258   'poll',
 259   'ppoll',
 260   'pselect',
 261   'getpagesize',
 262   'clock_gettime',
 263   'clock_nanosleep',
 264   'strnlen',
 265   # These are needed by libcheck
 266   'getline',
 267   'mkstemp',
 268   'alarm',
 269   'gettimeofday',
 270 ]
 271
 272 foreach f : check_functions
 273   if cc.has_function(f)
 274     define = 'HAVE_' + f.underscorify().to_upper()
 275     cdata.set(define, 1)
 276   endif
 277 endforeach
 278
 279 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 280   cdata.set('HAVE_LOCALTIME_R', 1)
 281   # Needed by libcheck
 282   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 283 endif
 284
 285 if cc.links('''#define _GNU_SOURCE
 286                #include <pthread.h>
 287                int main() {
 288                  pthread_setname_np("example"); return 0;
 289                }''', name : 'pthread_setname_np(const char*)')
 290   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 291 endif
 292 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 293   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 294 endif
 295 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 296   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 297 endif
 298
 299 # Check for futex(2)
 300 if cc.compiles('''#include <linux/futex.h>
 301                #include <sys/syscall.h>
 302                #include <unistd.h>
 303                int main (int argc, char ** argv) {
 304                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 305                  return 0;
 306                }''', name : 'futex(2) system call')
 307   cdata.set('HAVE_FUTEX', 1)
 308 endif
 309 if cc.compiles('''#include <linux/futex.h>
 310                #include <sys/syscall.h>
 311                #include <unistd.h>
 312                int main (int argc, char ** argv) {
 313                  syscall (__NR_futex_time64, NULL, FUTEX_WAKE, FUTEX_WAIT);
 314                  return 0;
 315                }''', name : 'futex(2) system call')
 316   cdata.set('HAVE_FUTEX_TIME64', 1)
 317 endif
 318
 319 # Check for posix timers and monotonic clock
 320 time_prefix = '#include <time.h>\n'
 321 if cdata.has('HAVE_UNISTD_H')
 322   time_prefix += '#include <unistd.h>'
 323 endif
 324
 325 posix_timers_src = time_prefix + '''
 326 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 327 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 328 #endif
 329 '''
 330 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 331   cdata.set('HAVE_POSIX_TIMERS', 1)
 332 endif
 333
 334 monotonic_clock_src = time_prefix + '''
 335 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 336 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 337 #endif
 338 '''
 339 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 340   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 341 endif
 342
 343 # Check for __uint128_t (gcc) by checking for 128-bit division
 344 uint128_t_src = '''int main() {
 345 static __uint128_t v1 = 100;
 346 static __uint128_t v2 = 10;
 347 static __uint128_t u;
 348 u = v1 / v2;
 349 }'''
 350 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 351   cdata.set('HAVE_UINT128_T', 1)
 352 endif
 353
 354 # All supported platforms have long long now
 355 cdata.set('HAVE_LONG_LONG', 1)
 356
 357 # -------------------------------------------------------------------------------------
 358 # config.h things needed by libcheck
 359 # -------------------------------------------------------------------------------------
 360 if cc.has_function('getpid')
 361   cdata.set('HAVE_GETPID', 1)
 362 elif host_system == 'windows' and cc.has_function('_getpid')
 363   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 364   cdata.set('HAVE__GETPID', 1)
 365 endif
 366 if cc.has_function('strdup')
 367   cdata.set('HAVE_DECL_STRDUP', 1)
 368 elif host_system == 'windows' and cc.has_function('_strdup')
 369   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 370 endif
 371 if host_system != 'windows'
 372   cdata.set('HAVE_FORK', 1)
 373 else
 374   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 375   cdata.set('HAVE_FORK', 0)
 376 endif
 377 if cc.has_function('strsignal')
 378   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 379 endif
 380 # Check for availability of types
 381 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 382   cdata.set('clockid_t', 'int')
 383 endif
 384 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 385   cdata.set('timer_t', 'int')
 386 endif
 387 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 388                       prefix : '#include <time.h>')
 389   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 390 endif
 391 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 392                       prefix : '#include <time.h>')
 393   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 394 endif
 395 if host_system != 'windows'
 396   cdata.set('HAVE_PIPE', 1)
 397 elif cc.has_function('_pipe', prefix : '#include <io.h>')
 398   cdata.set('HAVE_PIPE', 1)
 399 endif
 400
 401 # Platform deps; only ws2_32 and execinfo for now
 402 platform_deps = []
 403 if host_system == 'windows'
 404   platform_deps = [cc.find_library('ws2_32')]
 405 endif
 406
 407 building_for_uwp = false
 408 if host_system == 'windows'
 409   # Check whether we're building for UWP apps
 410   code = '''
 411   #include <windows.h>
 412   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 413   #error "Not building for UWP"
 414   #endif'''
 415   if cc.compiles(code, name : 'building for UWP')
 416     building_for_uwp = true
 417   endif
 418
 419   building_for_win7 = cc.compiles('''#include <windows.h>
 420       #ifndef WINVER
 421       #error "unknown minimum supported OS version"
 422       #endif
 423       #if (WINVER < _WIN32_WINNT_WIN7)
 424       #error "Windows 7 API is not guaranteed"
 425       #endif
 426       ''',
 427       name: 'building for Windows 7')
 428
 429   if not building_for_win7
 430     add_project_arguments([
 431       '-D_WIN32_WINNT=_WIN32_WINNT_WIN7',
 432       '-DWINVER=_WIN32_WINNT_WIN7',
 433     ], language: ['c', 'cpp'])
 434   endif
 435 endif
 436
 437 backtrace_deps = []
 438 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 439 dw_dep = dependency('libdw', required: get_option('libdw'))
 440 dbghelp_option = get_option('dbghelp')
 441 if dbghelp_option.enabled() and building_for_uwp
 442   error('DbgHelp is not supported for UWP')
 443 endif
 444 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 445 backtrace_deps = [unwind_dep, dw_dep]
 446 backtrace_source_info = false
 447 backtrace_minimal = false
 448 # MSVC debug stack trace support
 449 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 450   cdata.set('HAVE_DBGHELP', 1)
 451   backtrace_source_info = true
 452 # DWARF stack trace support with libunwind and elf-utils
 453 elif unwind_dep.found()
 454   cdata.set('HAVE_UNWIND', 1)
 455   if dw_dep.found()
 456     cdata.set('HAVE_DW', 1)
 457     backtrace_source_info = true
 458   endif
 459   backtrace_minimal = true
 460 # Basic backtrace() stack trace support
 461 elif cc.has_function('backtrace')
 462   cdata.set('HAVE_BACKTRACE', 1)
 463   backtrace_minimal = true
 464 endif
 465 # Print messages about what was enabled
 466 if not backtrace_source_info
 467   if not backtrace_minimal
 468     message('NO support for stack traces.')
 469   else
 470     message('Minimal support for stack traces, no source info.')
 471   endif
 472 endif
 473
 474 if cc.has_header('execinfo.h')
 475   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 476     cdata.set('HAVE_BACKTRACE', 1)
 477   else
 478     execinfo_dep = cc.find_library('execinfo', required : false)
 479     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 480       cdata.set('HAVE_BACKTRACE', 1)
 481       platform_deps += execinfo_dep
 482     endif
 483   endif
 484 endif
 485
 486 gst_debug = get_option('gst_debug')
 487 if not gst_debug
 488   add_project_arguments(['-Wno-unused'], language: 'c')
 489 endif
 490
 491 warning_flags = [
 492   '-Wmissing-declarations',
 493   '-Wmissing-prototypes',
 494   '-Wredundant-decls',
 495   '-Wundef',
 496   '-Wwrite-strings',
 497   '-Wformat',
 498   '-Wformat-nonliteral',
 499   '-Wformat-security',
 500   '-Wold-style-definition',
 501   '-Winit-self',
 502   '-Wmissing-include-dirs',
 503   '-Waddress',
 504   '-Waggregate-return',
 505   '-Wno-multichar',
 506   '-Wvla',
 507   '-Wpointer-arith',
 508 ]
 509
 510 foreach extra_arg : warning_flags
 511   if cc.has_argument (extra_arg)
 512     add_project_arguments([extra_arg], language: 'c')
 513   endif
 514 endforeach
 515
 516 # Used by the gstutils test
 517 gmp_dep = cc.find_library('gmp', required : false)
 518 cdata.set('HAVE_GMP', gmp_dep.found())
 519 gsl_dep = cc.find_library('gsl', required : false)
 520 gslcblas_dep = cc.find_library('gslcblas', required : false)
 521 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 522 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 523
 524 # Used by gstinfo.c
 525 dl_dep = cc.find_library('dl', required : false)
 526 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 527 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 528 cdata.set('USE_POISONING', get_option('poisoning'))
 529
 530 configinc = include_directories('.')
 531 libsinc = include_directories('libs')
 532 privinc = include_directories('gst')
 533
 534 glib_req = '>= 2.62.0'
 535
 536 # Find dependencies
 537 glib_dep = dependency('glib-2.0', version: glib_req,
 538   fallback: ['glib', 'libglib_dep'])
 539 gobject_dep = dependency('gobject-2.0')
 540 gmodule_dep = dependency('gmodule-no-export-2.0')
 541 if host_system == 'windows'
 542     gio_dep = dependency('gio-2.0')
 543 else
 544     gio_dep = [dependency('gio-2.0'),
 545                dependency('gio-unix-2.0')]
 546 endif
 547
 548 mathlib = cc.find_library('m', required : false)
 549 # Needed for timer_create/settime/delete
 550 # Also provides clock_gettime in glibc < 2.17
 551 rt_lib = cc.find_library('rt', required : false)
 552
 553 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 554 gnome = import('gnome')
 555
 556 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 557
 558 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 559     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 560     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 561     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 562     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 563     'gst_init(NULL,NULL);', '--quiet']
 564
 565 gst_c_args = ['-DHAVE_CONFIG_H']
 566
 567 # FIXME: This is only needed on windows and probably breaks when
 568 # default_library = 'both'. We should add this flag to static_c_args instead
 569 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 570 if get_option('default_library') == 'static'
 571   gst_c_args += ['-DGST_STATIC_COMPILATION']
 572 endif
 573
 574 # Used in gst/parse/meson.build and below
 575 python3 = import('python').find_installation()
 576
 577 bashcomp_option = get_option('bash-completion')
 578 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 579 bash_completions_dir = ''
 580 bash_helpers_dir = ''
 581
 582 bashcomp_found = false
 583 if bashcomp_dep.found()
 584   bashcomp_found = true
 585   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 586   bash_completions_dir = bashcomp_dep.get_variable('completionsdir', pkgconfig_define:  bashcomp_dir_override)
 587   if bash_completions_dir == ''
 588     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 589     if bashcomp_option.enabled()
 590       error(msg)
 591     else
 592       message(msg)
 593     endif
 594     bashcomp_found = false
 595   endif
 596
 597   bash_helpers_dir = bashcomp_dep.get_variable('helpersdir', pkgconfig_define:  bashcomp_dir_override)
 598   if bash_helpers_dir == ''
 599     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 600     if bashcomp_option.enabled()
 601       error(msg)
 602     else
 603       message(msg)
 604     endif
 605     bashcomp_found = false
 606   endif
 607 endif
 608
 609 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 610
 611 pkgconfig = import('pkgconfig')
 612 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 613 if get_option('default_library') == 'shared'
 614   # If we don't build static plugins there is no need to generate pc files
 615   plugins_pkgconfig_install_dir = disabler()
 616 endif
 617 pkgconfig_variables = [
 618   'exec_prefix=${prefix}',
 619   'toolsdir=${exec_prefix}/bin',
 620   'pluginsdir=${libdir}/gstreamer-1.0',
 621   'girdir=${datadir}/gir-1.0',
 622   'typelibdir=${libdir}/girepository-1.0',
 623   'pluginscannerdir=${libexecdir}/gstreamer-1.0'
 624 ]
 625 pkgconfig_uninstalled_variables = ['exec_prefix=${prefix}',
 626         'gstreamerdir=${prefix}/subprojects/gstreamer',
 627     'bashhelpersdir=${gstreamerdir}/data/bash-completion/helpers',
 628     'helpersdir=${gstreamerdir}/libs/gst/helpers']
 629 pkgconfig_subdirs = ['gstreamer-1.0']
 630 pkgconfig_libs = []
 631 if host_system == 'darwin'
 632   pkgconfig_libs = ['-Wl,-rpath,${libdir}']
 633 endif
 634
 635 static_build = get_option('default_library') == 'static'
 636 gst_libraries = []
 637 subdir('gst')
 638 subdir('libs')
 639 subdir('plugins')
 640 subdir('tools')
 641 subdir('tests')
 642 subdir('data')
 643 subdir('docs')
 644
 645 # xgettext is optional (on Windows for instance)
 646 if find_program('xgettext', required : get_option('nls')).found()
 647   cdata.set('ENABLE_NLS', 1)
 648   subdir('po')
 649 endif
 650
 651 subdir('scripts')
 652
 653 # Set release date
 654 if gst_version_nano == 0
 655   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 656   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'), check: true)
 657   release_date = run_result.stdout().strip()
 658   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 659   message('Package release date: ' + release_date)
 660 endif
 661
 662 configure_file(output : 'config.h', configuration : cdata)
 663 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 664
 665 meson.add_dist_script('scripts/gen-changelog.py', meson.project_name(), '1.20.0', meson.project_version())
 666
 667 plugin_names = []
 668 gst_plugins = []
 669 foreach plugin: plugins
 670   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 671   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 672   meson.override_dependency(plugin.name(), dep)
 673   gst_plugins += [dep]
 674   if plugin.name().startswith('gst')
 675     plugin_names += [plugin.name().substring(3)]
 676   else
 677     plugin_names += [plugin.name()]
 678   endif
 679 endforeach
 680
 681 summary({
 682     'Plugins': plugin_names,
 683 }, list_sep: ', ')