subprojects/gstreamer/meson.build

   1 project('gstreamer', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 datadir = join_paths(prefix, get_option('datadir'))
  32 libexecdir = get_option('libexecdir')
  33 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  34
  35 cc = meson.get_compiler('c')
  36
  37 cdata = configuration_data()
  38
  39 if cc.get_id() == 'msvc'
  40   msvc_args = [
  41       # Ignore several spurious warnings for things gstreamer does very commonly
  42       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44       # NOTE: Only add warnings here if you are sure they're spurious
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50   ]
  51
  52   if gst_version_is_dev
  53     # Enable some warnings on MSVC to match GCC/Clang behaviour
  54     msvc_args += cc.get_supported_arguments([
  55       '/we4002', # too many actual parameters for macro 'identifier'
  56       '/we4003', # not enough actual parameters for macro 'identifier'
  57       '/we4013', # 'function' undefined; assuming extern returning int
  58       '/we4020', # 'function' : too many actual parameters
  59       '/we4027', # function declared without formal parameter list
  60       '/we4029', # declared formal parameter list different from definition
  61       '/we4033', # 'function' must return a value
  62       '/we4045', # 'array' : array bounds overflow
  63       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  64       '/we4053', # one void operand for '?:'
  65       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  66       '/we4098', # 'function' : void function returning a value
  67       '/we4101', # 'identifier' : unreferenced local variable
  68       '/we4189', # 'identifier' : local variable is initialized but not referenced
  69     ])
  70   endif
  71   add_project_arguments(msvc_args, language: 'c')
  72 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  73   # FIXME: Add an option for this if people ask for it
  74   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  75 endif
  76
  77 # Symbol visibility
  78 have_visibility_hidden = false
  79 if cc.get_id() == 'msvc'
  80   export_define = '__declspec(dllexport) extern'
  81 elif cc.has_argument('-fvisibility=hidden')
  82   add_project_arguments('-fvisibility=hidden', language: 'c')
  83   export_define = 'extern __attribute__ ((visibility ("default")))'
  84   have_visibility_hidden = true
  85 else
  86   export_define = 'extern'
  87 endif
  88
  89 # Passing this through the command line would be too messy
  90 cdata.set('GST_API_EXPORT', export_define)
  91
  92 # Disable strict aliasing
  93 if cc.has_argument('-fno-strict-aliasing')
  94   add_project_arguments('-fno-strict-aliasing', language: 'c')
  95 endif
  96
  97 # Define G_DISABLE_DEPRECATED for development versions
  98 if gst_version_is_dev
  99   message('Disabling deprecated GLib API')
 100   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 101 endif
 102
 103 cast_checks = get_option('gobject-cast-checks')
 104 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 105   message('Disabling GLib cast checks')
 106   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 107 endif
 108
 109 glib_asserts = get_option('glib-asserts')
 110 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 111   message('Disabling GLib asserts')
 112   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 113 endif
 114
 115 glib_checks = get_option('glib-checks')
 116 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 117   message('Disabling GLib checks')
 118   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 119 endif
 120
 121 cdata.set_quoted('GST_API_VERSION', apiversion)
 122 cdata.set_quoted('GST_DATADIR', datadir)
 123 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 124 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 125 cdata.set_quoted('GST_API_VERSION', '1.0')
 126 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 127 cdata.set_quoted('GST_LICENSE', 'LGPL')
 128 cdata.set_quoted('PACKAGE', 'gstreamer')
 129 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 130 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 131 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 132 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 133 cdata.set_quoted('PACKAGE_URL', '')
 134 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 135 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 136 cdata.set_quoted('VERSION', gst_version)
 137 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 138 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 139 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 140   description: 'plugin directory path component, used to find plugins on relocatable builds')
 141 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 142   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds')
 143 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 144
 145 mem_align_opt = get_option('memory-alignment')
 146 if mem_align_opt == 'malloc'
 147   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 148 elif mem_align_opt == 'pagesize'
 149   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 150 else
 151   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 152 endif
 153
 154 if ['darwin', 'ios'].contains(host_system)
 155   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 156 endif
 157
 158 if gst_version_nano > 0
 159     # Have GST_ERROR message printed when running from git
 160     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 161 else
 162     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 163 endif
 164
 165 # GStreamer package name and origin url
 166 gst_package_name = get_option('package-name')
 167 if gst_package_name == ''
 168   if gst_version_nano == 0
 169     gst_package_name = 'GStreamer source release'
 170   elif gst_version_nano == 1
 171     gst_package_name = 'GStreamer git'
 172   else
 173     gst_package_name = 'GStreamer prerelease'
 174   endif
 175 endif
 176 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 177 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 178
 179 # These are only needed/used by the ABI tests
 180 host_defines = [
 181   [ 'x86', 'HAVE_CPU_I386' ],
 182   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 183   [ 'arm', 'HAVE_CPU_ARM' ],
 184   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 185   [ 'mips', 'HAVE_CPU_MIPS' ],
 186   [ 'powerpc', 'HAVE_CPU_PPC' ],
 187   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 188   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 189   [ 'sparc', 'HAVE_CPU_SPARC' ],
 190   [ 'ia64', 'HAVE_CPU_IA64' ],
 191   [ 'hppa', 'HAVE_CPU_HPPA' ],
 192   [ 'm68k', 'HAVE_CPU_M68K' ],
 193   [ 's390', 'HAVE_CPU_S390' ],
 194 ]
 195 foreach h : host_defines
 196   if h.get(0) == host_machine.cpu_family()
 197     cdata.set(h.get(1), 1)
 198   endif
 199 endforeach
 200 # FIXME: should really be called HOST_CPU or such
 201 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 202
 203 check_headers = [
 204   'dlfcn.h',
 205   'inttypes.h',
 206   'memory.h',
 207   'poll.h',
 208   'stdint.h',
 209   'stdio_ext.h',
 210   'strings.h',
 211   'string.h',
 212   'sys/param.h',
 213   'sys/poll.h',
 214   'sys/prctl.h',
 215   'sys/socket.h',
 216   'sys/stat.h',
 217   'sys/times.h',
 218   'sys/time.h',
 219   'sys/types.h',
 220   'sys/utsname.h',
 221   'sys/wait.h',
 222   'ucontext.h',
 223   'unistd.h',
 224   'sys/resource.h',
 225   'sys/uio.h',
 226 ]
 227
 228 if host_system == 'windows'
 229   check_headers += ['winsock2.h']
 230 endif
 231
 232 foreach h : check_headers
 233   if cc.has_header(h)
 234     define = 'HAVE_' + h.underscorify().to_upper()
 235     cdata.set(define, 1)
 236   endif
 237 endforeach
 238
 239 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 240   cdata.set('HAVE_TM_GMTOFF', 1)
 241 endif
 242
 243 check_functions = [
 244   'gmtime_r',
 245   'sigaction',
 246   'getrusage',
 247   'fseeko',
 248   'ftello',
 249   'poll',
 250   'ppoll',
 251   'pselect',
 252   'getpagesize',
 253   'clock_gettime',
 254   'clock_nanosleep',
 255   'strnlen',
 256   # These are needed by libcheck
 257   'getline',
 258   'mkstemp',
 259   'alarm',
 260   'gettimeofday',
 261 ]
 262
 263 foreach f : check_functions
 264   if cc.has_function(f)
 265     define = 'HAVE_' + f.underscorify().to_upper()
 266     cdata.set(define, 1)
 267   endif
 268 endforeach
 269
 270 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 271   cdata.set('HAVE_LOCALTIME_R', 1)
 272   # Needed by libcheck
 273   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 274 endif
 275
 276 if cc.links('''#include <pthread.h>
 277                int main() {
 278                  pthread_setname_np("example"); return 0;
 279                }''', name : 'pthread_setname_np(const char*)')
 280   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 281 endif
 282 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 283   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 284 endif
 285 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 286   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 287 endif
 288
 289 # Check for futex(2)
 290 if cc.links('''#include <linux/futex.h>
 291                #include <sys/syscall.h>
 292                #include <unistd.h>
 293                int main (int argc, char ** argv) {
 294                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 295                  return 0;
 296                }''', name : 'futex(2) system call')
 297   cdata.set('HAVE_FUTEX', 1)
 298 endif
 299
 300 # Check for posix timers and monotonic clock
 301 time_prefix = '#include <time.h>\n'
 302 if cdata.has('HAVE_UNISTD_H')
 303   time_prefix += '#include <unistd.h>'
 304 endif
 305
 306 posix_timers_src = time_prefix + '''
 307 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 308 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 309 #endif
 310 '''
 311 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 312   cdata.set('HAVE_POSIX_TIMERS', 1)
 313 endif
 314
 315 monotonic_clock_src = time_prefix + '''
 316 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 317 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 318 #endif
 319 '''
 320 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 321   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 322 endif
 323
 324 # Check for __uint128_t (gcc) by checking for 128-bit division
 325 uint128_t_src = '''int main() {
 326 static __uint128_t v1 = 100;
 327 static __uint128_t v2 = 10;
 328 static __uint128_t u;
 329 u = v1 / v2;
 330 }'''
 331 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 332   cdata.set('HAVE_UINT128_T', 1)
 333 endif
 334
 335 # All supported platforms have long long now
 336 cdata.set('HAVE_LONG_LONG', 1)
 337
 338 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 339 # building with MSVC
 340 if cc.get_id() == 'msvc'
 341   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 342 else
 343   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 344 endif
 345
 346 # -------------------------------------------------------------------------------------
 347 # config.h things needed by libcheck
 348 # -------------------------------------------------------------------------------------
 349 if cc.has_function('getpid')
 350   cdata.set('HAVE_GETPID', 1)
 351 elif host_system == 'windows' and cc.has_function('_getpid')
 352   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 353   cdata.set('HAVE__GETPID', 1)
 354 endif
 355 if cc.has_function('strdup')
 356   cdata.set('HAVE_DECL_STRDUP', 1)
 357 elif host_system == 'windows' and cc.has_function('_strdup')
 358   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 359 endif
 360 if host_system != 'windows'
 361   cdata.set('HAVE_FORK', 1)
 362 else
 363   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 364   cdata.set('HAVE_FORK', 0)
 365 endif
 366 if cc.has_function('strsignal')
 367   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 368 endif
 369 # Check for availability of types
 370 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 371   cdata.set('clockid_t', 'int')
 372 endif
 373 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 374   cdata.set('timer_t', 'int')
 375 endif
 376 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 377                       prefix : '#include <time.h>')
 378   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 379 endif
 380 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 381                       prefix : '#include <time.h>')
 382   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 383 endif
 384 if host_system != 'windows'
 385   cdata.set('HAVE_PIPE', 1)
 386 elif cc.has_function('_pipe', prefix : '#include <io.h>')
 387   cdata.set('HAVE_PIPE', 1)
 388 endif
 389
 390 # Platform deps; only ws2_32 and execinfo for now
 391 platform_deps = []
 392 if host_system == 'windows'
 393   platform_deps = [cc.find_library('ws2_32')]
 394 endif
 395
 396 building_for_uwp = false
 397 if host_system == 'windows'
 398   # Check whether we're building for UWP apps
 399   code = '''
 400   #include <windows.h>
 401   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 402   #error "Not building for UWP"
 403   #endif'''
 404   if cc.compiles(code, name : 'building for UWP')
 405     building_for_uwp = true
 406   endif
 407
 408   building_for_win7 = cc.compiles('''#include <windows.h>
 409       #ifndef WINVER
 410       #error "unknown minimum supported OS version"
 411       #endif
 412       #if (WINVER < _WIN32_WINNT_WIN7)
 413       #error "Windows 7 API is not guaranteed"
 414       #endif
 415       ''',
 416       name: 'building for Windows 7')
 417
 418   if not building_for_win7
 419     add_project_arguments([
 420       '-D_WIN32_WINNT=_WIN32_WINNT_WIN7',
 421       '-DWINVER=_WIN32_WINNT_WIN7',
 422     ], language: ['c', 'cpp'])
 423   endif
 424 endif
 425
 426 backtrace_deps = []
 427 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 428 dw_dep = dependency('libdw', required: get_option('libdw'))
 429 dbghelp_option = get_option('dbghelp')
 430 if dbghelp_option.enabled() and building_for_uwp
 431   error('DbgHelp is not supported for UWP')
 432 endif
 433 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 434 backtrace_deps = [unwind_dep, dw_dep]
 435 backtrace_source_info = false
 436 backtrace_minimal = false
 437 # MSVC debug stack trace support
 438 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 439   cdata.set('HAVE_DBGHELP', 1)
 440   backtrace_source_info = true
 441 # DWARF stack trace support with libunwind and elf-utils
 442 elif unwind_dep.found()
 443   cdata.set('HAVE_UNWIND', 1)
 444   if dw_dep.found()
 445     cdata.set('HAVE_DW', 1)
 446     backtrace_source_info = true
 447   endif
 448   backtrace_minimal = true
 449 # Basic backtrace() stack trace support
 450 elif cc.has_function('backtrace')
 451   cdata.set('HAVE_BACKTRACE', 1)
 452   backtrace_minimal = true
 453 endif
 454 # Print messages about what was enabled
 455 if not backtrace_source_info
 456   if not backtrace_minimal
 457     message('NO support for stack traces.')
 458   else
 459     message('Minimal support for stack traces, no source info.')
 460   endif
 461 endif
 462
 463 if cc.has_header('execinfo.h')
 464   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 465     cdata.set('HAVE_BACKTRACE', 1)
 466   else
 467     execinfo_dep = cc.find_library('execinfo', required : false)
 468     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 469       cdata.set('HAVE_BACKTRACE', 1)
 470       platform_deps += execinfo_dep
 471     endif
 472   endif
 473 endif
 474
 475 gst_debug = get_option('gst_debug')
 476 if not gst_debug
 477   add_project_arguments(['-Wno-unused'], language: 'c')
 478 endif
 479
 480 warning_flags = [
 481   '-Wmissing-declarations',
 482   '-Wmissing-prototypes',
 483   '-Wredundant-decls',
 484   '-Wundef',
 485   '-Wwrite-strings',
 486   '-Wformat',
 487   '-Wformat-nonliteral',
 488   '-Wformat-security',
 489   '-Wold-style-definition',
 490   '-Winit-self',
 491   '-Wmissing-include-dirs',
 492   '-Waddress',
 493   '-Waggregate-return',
 494   '-Wno-multichar',
 495   '-Wdeclaration-after-statement',
 496   '-Wvla',
 497   '-Wpointer-arith',
 498 ]
 499
 500 foreach extra_arg : warning_flags
 501   if cc.has_argument (extra_arg)
 502     add_project_arguments([extra_arg], language: 'c')
 503   endif
 504 endforeach
 505
 506 # Used by the gstutils test
 507 gmp_dep = cc.find_library('gmp', required : false)
 508 cdata.set('HAVE_GMP', gmp_dep.found())
 509 gsl_dep = cc.find_library('gsl', required : false)
 510 gslcblas_dep = cc.find_library('gslcblas', required : false)
 511 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 512 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 513
 514 # Used by gstinfo.c
 515 dl_dep = cc.find_library('dl', required : false)
 516 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 517 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 518 cdata.set('USE_POISONING', get_option('poisoning'))
 519
 520 configinc = include_directories('.')
 521 libsinc = include_directories('libs')
 522 privinc = include_directories('gst')
 523
 524 # Find dependencies
 525 glib_dep = dependency('glib-2.0', version : '>=2.56.0',
 526   fallback: ['glib', 'libglib_dep'])
 527 gobject_dep = dependency('gobject-2.0')
 528 gmodule_dep = dependency('gmodule-no-export-2.0')
 529 if host_system == 'windows'
 530     gio_dep = dependency('gio-2.0')
 531 else
 532     gio_dep = [dependency('gio-2.0'),
 533                dependency('gio-unix-2.0')]
 534 endif
 535
 536 mathlib = cc.find_library('m', required : false)
 537 # Needed for timer_create/settime/delete
 538 # Also provides clock_gettime in glibc < 2.17
 539 rt_lib = cc.find_library('rt', required : false)
 540
 541 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 542 gnome = import('gnome')
 543
 544 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 545
 546 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 547     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 548     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 549     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 550     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 551     'gst_init(NULL,NULL);', '--quiet']
 552
 553 gst_c_args = ['-DHAVE_CONFIG_H']
 554
 555 # FIXME: This is only needed on windows and probably breaks when
 556 # default_library = 'both'. We should add this flag to static_c_args instead
 557 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 558 if get_option('default_library') == 'static'
 559   gst_c_args += ['-DGST_STATIC_COMPILATION']
 560 endif
 561
 562 # Used in gst/parse/meson.build and below
 563 python3 = import('python').find_installation()
 564
 565 bashcomp_option = get_option('bash-completion')
 566 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 567 bash_completions_dir = ''
 568 bash_helpers_dir = ''
 569
 570 bashcomp_found = false
 571 if bashcomp_dep.found()
 572   bashcomp_found = true
 573   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 574   bash_completions_dir = bashcomp_dep.get_variable('completionsdir', pkgconfig_define:  bashcomp_dir_override)
 575   if bash_completions_dir == ''
 576     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 577     if bashcomp_option.enabled()
 578       error(msg)
 579     else
 580       message(msg)
 581     endif
 582     bashcomp_found = false
 583   endif
 584
 585   bash_helpers_dir = bashcomp_dep.get_variable('helpersdir', pkgconfig_define:  bashcomp_dir_override)
 586   if bash_helpers_dir == ''
 587     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 588     if bashcomp_option.enabled()
 589       error(msg)
 590     else
 591       message(msg)
 592     endif
 593     bashcomp_found = false
 594   endif
 595 endif
 596
 597 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 598
 599 pkgconfig = import('pkgconfig')
 600 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 601 if get_option('default_library') == 'shared'
 602   # If we don't build static plugins there is no need to generate pc files
 603   plugins_pkgconfig_install_dir = disabler()
 604 endif
 605 pkgconfig_variables = ['exec_prefix=${prefix}',
 606     'toolsdir=${exec_prefix}/bin',
 607     'pluginsdir=${libdir}/gstreamer-1.0',
 608     'datarootdir=${prefix}/share',
 609     'datadir=${datarootdir}',
 610     'girdir=${datadir}/gir-1.0',
 611     'typelibdir=${libdir}/girepository-1.0',
 612     'libexecdir=${prefix}/libexec',
 613     'pluginscannerdir=${libexecdir}/gstreamer-1.0']
 614 pkgconfig_uninstalled_variables = ['exec_prefix=${prefix}',
 615         'gstreamerdir=${prefix}/subprojects/gstreamer',
 616     'bashhelpersdir=${gstreamerdir}/data/bash-completion/helpers',
 617     'helpersdir=${gstreamerdir}/libs/gst/helpers']
 618 pkgconfig_subdirs = ['gstreamer-1.0']
 619
 620 static_build = get_option('default_library') == 'static'
 621 libraries = []
 622 subdir('gst')
 623 subdir('libs')
 624 subdir('plugins')
 625 subdir('tools')
 626 subdir('tests')
 627 subdir('data')
 628 subdir('docs')
 629
 630 # xgettext is optional (on Windows for instance)
 631 if find_program('xgettext', required : get_option('nls')).found()
 632   cdata.set('ENABLE_NLS', 1)
 633   subdir('po')
 634 endif
 635
 636 subdir('scripts')
 637
 638 # Set release date
 639 if gst_version_nano == 0
 640   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 641   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'), check: true)
 642   release_date = run_result.stdout().strip()
 643   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 644   message('Package release date: ' + release_date)
 645 endif
 646
 647 configure_file(output : 'config.h', configuration : cdata)
 648 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 649
 650 plugin_names = []
 651 foreach plugin: plugins
 652   if plugin.name().startswith('gst')
 653     plugin_names += [plugin.name().substring(3)]
 654   else
 655     plugin_names += [plugin.name()]
 656   endif
 657 endforeach
 658
 659 summary({
 660     'Plugins': plugin_names,
 661 }, list_sep: ', ')