subprojects/gstreamer/meson.build

   1 project('gstreamer', 'c',
   2   version : '1.21.2.1',
   3   meson_version : '>= 0.62',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 datadir = join_paths(prefix, get_option('datadir'))
  32 libexecdir = get_option('libexecdir')
  33 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  34
  35 cc = meson.get_compiler('c')
  36
  37 cdata = configuration_data()
  38
  39 if cc.get_id() == 'msvc'
  40   msvc_args = [
  41       # Ignore several spurious warnings for things gstreamer does very commonly
  42       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44       # NOTE: Only add warnings here if you are sure they're spurious
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50   ]
  51
  52   if gst_version_is_dev
  53     # Enable some warnings on MSVC to match GCC/Clang behaviour
  54     msvc_args += cc.get_supported_arguments([
  55       '/we4002', # too many actual parameters for macro 'identifier'
  56       '/we4003', # not enough actual parameters for macro 'identifier'
  57       '/we4013', # 'function' undefined; assuming extern returning int
  58       '/we4020', # 'function' : too many actual parameters
  59       '/we4027', # function declared without formal parameter list
  60       '/we4029', # declared formal parameter list different from definition
  61       '/we4033', # 'function' must return a value
  62       '/we4045', # 'array' : array bounds overflow
  63       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  64       '/we4053', # one void operand for '?:'
  65       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  66       '/we4098', # 'function' : void function returning a value
  67       '/we4101', # 'identifier' : unreferenced local variable
  68       '/we4189', # 'identifier' : local variable is initialized but not referenced
  69     ])
  70   endif
  71   add_project_arguments(msvc_args, language: 'c')
  72 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  73   # FIXME: Add an option for this if people ask for it
  74   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  75 endif
  76
  77 # glib doesn't support unloading, which means that unloading and reloading
  78 # any library that registers static types will fail
  79 if cc.has_link_argument('-Wl,-z,nodelete')
  80   add_project_link_arguments('-Wl,-z,nodelete', language: 'c')
  81 endif
  82
  83 # Symbol visibility
  84 have_visibility_hidden = false
  85 if cc.get_id() == 'msvc'
  86   export_define = '__declspec(dllexport) extern'
  87 elif cc.has_argument('-fvisibility=hidden')
  88   add_project_arguments('-fvisibility=hidden', language: 'c')
  89   export_define = 'extern __attribute__ ((visibility ("default")))'
  90   have_visibility_hidden = true
  91 else
  92   export_define = 'extern'
  93 endif
  94
  95 # Passing this through the command line would be too messy
  96 cdata.set('GST_API_EXPORT', export_define)
  97
  98 # Disable strict aliasing
  99 if cc.has_argument('-fno-strict-aliasing')
 100   add_project_arguments('-fno-strict-aliasing', language: 'c')
 101 endif
 102
 103 # Define G_DISABLE_DEPRECATED for development versions
 104 if gst_version_is_dev
 105   message('Disabling deprecated GLib API')
 106   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 107 endif
 108
 109 cast_checks = get_option('gobject-cast-checks')
 110 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 111   message('Disabling GLib cast checks')
 112   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 113 endif
 114
 115 glib_asserts = get_option('glib-asserts')
 116 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 117   message('Disabling GLib asserts')
 118   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 119 endif
 120
 121 glib_checks = get_option('glib-checks')
 122 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 123   message('Disabling GLib checks')
 124   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 125 endif
 126
 127 cdata.set_quoted('GST_API_VERSION', apiversion)
 128 cdata.set_quoted('GST_DATADIR', datadir)
 129 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 130 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 131 cdata.set_quoted('GST_API_VERSION', '1.0')
 132 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 133 cdata.set_quoted('GST_LICENSE', 'LGPL')
 134 cdata.set_quoted('PACKAGE', 'gstreamer')
 135 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 136 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 137 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 138 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 139 cdata.set_quoted('PACKAGE_URL', '')
 140 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 141 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 142 cdata.set_quoted('VERSION', gst_version)
 143 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 144 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 145 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 146   description: 'plugin directory path component, used to find plugins on relocatable builds')
 147 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 148   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds')
 149 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 150
 151 mem_align_opt = get_option('memory-alignment')
 152 if mem_align_opt == 'malloc'
 153   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 154 elif mem_align_opt == 'pagesize'
 155   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 156 else
 157   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 158 endif
 159
 160 if ['darwin', 'ios'].contains(host_system)
 161   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 162 endif
 163
 164 if gst_version_nano > 0
 165     # Have GST_ERROR message printed when running from git
 166     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 167 else
 168     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 169 endif
 170
 171 # GStreamer package name and origin url
 172 gst_package_name = get_option('package-name')
 173 if gst_package_name == ''
 174   if gst_version_nano == 0
 175     gst_package_name = 'GStreamer source release'
 176   elif gst_version_nano == 1
 177     gst_package_name = 'GStreamer git'
 178   else
 179     gst_package_name = 'GStreamer prerelease'
 180   endif
 181 endif
 182 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 183 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 184
 185 # These are only needed/used by the ABI tests
 186 host_defines = [
 187   [ 'x86', 'HAVE_CPU_I386' ],
 188   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 189   [ 'arm', 'HAVE_CPU_ARM' ],
 190   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 191   [ 'mips', 'HAVE_CPU_MIPS' ],
 192   [ 'powerpc', 'HAVE_CPU_PPC' ],
 193   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 194   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 195   [ 'sparc', 'HAVE_CPU_SPARC' ],
 196   [ 'ia64', 'HAVE_CPU_IA64' ],
 197   [ 'hppa', 'HAVE_CPU_HPPA' ],
 198   [ 'm68k', 'HAVE_CPU_M68K' ],
 199   [ 's390', 'HAVE_CPU_S390' ],
 200 ]
 201 foreach h : host_defines
 202   if h.get(0) == host_machine.cpu_family()
 203     cdata.set(h.get(1), 1)
 204   endif
 205 endforeach
 206 # FIXME: should really be called HOST_CPU or such
 207 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 208
 209 check_headers = [
 210   'dlfcn.h',
 211   'inttypes.h',
 212   'memory.h',
 213   'poll.h',
 214   'stdint.h',
 215   'stdio_ext.h',
 216   'strings.h',
 217   'string.h',
 218   'sys/param.h',
 219   'sys/poll.h',
 220   'sys/prctl.h',
 221   'sys/socket.h',
 222   'sys/stat.h',
 223   'sys/times.h',
 224   'sys/time.h',
 225   'sys/types.h',
 226   'sys/utsname.h',
 227   'sys/wait.h',
 228   'ucontext.h',
 229   'unistd.h',
 230   'sys/resource.h',
 231   'sys/uio.h',
 232 ]
 233
 234 if host_system == 'windows'
 235   check_headers += ['winsock2.h']
 236 endif
 237
 238 foreach h : check_headers
 239   if cc.has_header(h)
 240     define = 'HAVE_' + h.underscorify().to_upper()
 241     cdata.set(define, 1)
 242   endif
 243 endforeach
 244
 245 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 246   cdata.set('HAVE_TM_GMTOFF', 1)
 247 endif
 248
 249 check_functions = [
 250   'gmtime_r',
 251   'sigaction',
 252   'getrusage',
 253   'fseeko',
 254   'ftello',
 255   'poll',
 256   'ppoll',
 257   'pselect',
 258   'getpagesize',
 259   'clock_gettime',
 260   'clock_nanosleep',
 261   'strnlen',
 262   # These are needed by libcheck
 263   'getline',
 264   'mkstemp',
 265   'alarm',
 266   'gettimeofday',
 267 ]
 268
 269 foreach f : check_functions
 270   if cc.has_function(f)
 271     define = 'HAVE_' + f.underscorify().to_upper()
 272     cdata.set(define, 1)
 273   endif
 274 endforeach
 275
 276 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 277   cdata.set('HAVE_LOCALTIME_R', 1)
 278   # Needed by libcheck
 279   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 280 endif
 281
 282 if cc.links('''#include <pthread.h>
 283                int main() {
 284                  pthread_setname_np("example"); return 0;
 285                }''', name : 'pthread_setname_np(const char*)')
 286   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 287 endif
 288 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 289   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 290 endif
 291 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 292   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 293 endif
 294
 295 # Check for futex(2)
 296 if cc.links('''#include <linux/futex.h>
 297                #include <sys/syscall.h>
 298                #include <unistd.h>
 299                int main (int argc, char ** argv) {
 300                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 301                  return 0;
 302                }''', name : 'futex(2) system call')
 303   cdata.set('HAVE_FUTEX', 1)
 304 endif
 305
 306 # Check for posix timers and monotonic clock
 307 time_prefix = '#include <time.h>\n'
 308 if cdata.has('HAVE_UNISTD_H')
 309   time_prefix += '#include <unistd.h>'
 310 endif
 311
 312 posix_timers_src = time_prefix + '''
 313 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 314 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 315 #endif
 316 '''
 317 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 318   cdata.set('HAVE_POSIX_TIMERS', 1)
 319 endif
 320
 321 monotonic_clock_src = time_prefix + '''
 322 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 323 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 324 #endif
 325 '''
 326 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 327   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 328 endif
 329
 330 # Check for __uint128_t (gcc) by checking for 128-bit division
 331 uint128_t_src = '''int main() {
 332 static __uint128_t v1 = 100;
 333 static __uint128_t v2 = 10;
 334 static __uint128_t u;
 335 u = v1 / v2;
 336 }'''
 337 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 338   cdata.set('HAVE_UINT128_T', 1)
 339 endif
 340
 341 # All supported platforms have long long now
 342 cdata.set('HAVE_LONG_LONG', 1)
 343
 344 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 345 # building with MSVC
 346 if cc.get_id() == 'msvc'
 347   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 348 else
 349   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 350 endif
 351
 352 # -------------------------------------------------------------------------------------
 353 # config.h things needed by libcheck
 354 # -------------------------------------------------------------------------------------
 355 if cc.has_function('getpid')
 356   cdata.set('HAVE_GETPID', 1)
 357 elif host_system == 'windows' and cc.has_function('_getpid')
 358   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 359   cdata.set('HAVE__GETPID', 1)
 360 endif
 361 if cc.has_function('strdup')
 362   cdata.set('HAVE_DECL_STRDUP', 1)
 363 elif host_system == 'windows' and cc.has_function('_strdup')
 364   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 365 endif
 366 if host_system != 'windows'
 367   cdata.set('HAVE_FORK', 1)
 368 else
 369   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 370   cdata.set('HAVE_FORK', 0)
 371 endif
 372 if cc.has_function('strsignal')
 373   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 374 endif
 375 # Check for availability of types
 376 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 377   cdata.set('clockid_t', 'int')
 378 endif
 379 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 380   cdata.set('timer_t', 'int')
 381 endif
 382 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 383                       prefix : '#include <time.h>')
 384   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 385 endif
 386 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 387                       prefix : '#include <time.h>')
 388   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 389 endif
 390 if host_system != 'windows'
 391   cdata.set('HAVE_PIPE', 1)
 392 elif cc.has_function('_pipe', prefix : '#include <io.h>')
 393   cdata.set('HAVE_PIPE', 1)
 394 endif
 395
 396 # Platform deps; only ws2_32 and execinfo for now
 397 platform_deps = []
 398 if host_system == 'windows'
 399   platform_deps = [cc.find_library('ws2_32')]
 400 endif
 401
 402 building_for_uwp = false
 403 if host_system == 'windows'
 404   # Check whether we're building for UWP apps
 405   code = '''
 406   #include <windows.h>
 407   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 408   #error "Not building for UWP"
 409   #endif'''
 410   if cc.compiles(code, name : 'building for UWP')
 411     building_for_uwp = true
 412   endif
 413
 414   building_for_win7 = cc.compiles('''#include <windows.h>
 415       #ifndef WINVER
 416       #error "unknown minimum supported OS version"
 417       #endif
 418       #if (WINVER < _WIN32_WINNT_WIN7)
 419       #error "Windows 7 API is not guaranteed"
 420       #endif
 421       ''',
 422       name: 'building for Windows 7')
 423
 424   if not building_for_win7
 425     add_project_arguments([
 426       '-D_WIN32_WINNT=_WIN32_WINNT_WIN7',
 427       '-DWINVER=_WIN32_WINNT_WIN7',
 428     ], language: ['c', 'cpp'])
 429   endif
 430 endif
 431
 432 backtrace_deps = []
 433 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 434 dw_dep = dependency('libdw', required: get_option('libdw'))
 435 dbghelp_option = get_option('dbghelp')
 436 if dbghelp_option.enabled() and building_for_uwp
 437   error('DbgHelp is not supported for UWP')
 438 endif
 439 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 440 backtrace_deps = [unwind_dep, dw_dep]
 441 backtrace_source_info = false
 442 backtrace_minimal = false
 443 # MSVC debug stack trace support
 444 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 445   cdata.set('HAVE_DBGHELP', 1)
 446   backtrace_source_info = true
 447 # DWARF stack trace support with libunwind and elf-utils
 448 elif unwind_dep.found()
 449   cdata.set('HAVE_UNWIND', 1)
 450   if dw_dep.found()
 451     cdata.set('HAVE_DW', 1)
 452     backtrace_source_info = true
 453   endif
 454   backtrace_minimal = true
 455 # Basic backtrace() stack trace support
 456 elif cc.has_function('backtrace')
 457   cdata.set('HAVE_BACKTRACE', 1)
 458   backtrace_minimal = true
 459 endif
 460 # Print messages about what was enabled
 461 if not backtrace_source_info
 462   if not backtrace_minimal
 463     message('NO support for stack traces.')
 464   else
 465     message('Minimal support for stack traces, no source info.')
 466   endif
 467 endif
 468
 469 if cc.has_header('execinfo.h')
 470   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 471     cdata.set('HAVE_BACKTRACE', 1)
 472   else
 473     execinfo_dep = cc.find_library('execinfo', required : false)
 474     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 475       cdata.set('HAVE_BACKTRACE', 1)
 476       platform_deps += execinfo_dep
 477     endif
 478   endif
 479 endif
 480
 481 gst_debug = get_option('gst_debug')
 482 if not gst_debug
 483   add_project_arguments(['-Wno-unused'], language: 'c')
 484 endif
 485
 486 warning_flags = [
 487   '-Wmissing-declarations',
 488   '-Wmissing-prototypes',
 489   '-Wredundant-decls',
 490   '-Wundef',
 491   '-Wwrite-strings',
 492   '-Wformat',
 493   '-Wformat-nonliteral',
 494   '-Wformat-security',
 495   '-Wold-style-definition',
 496   '-Winit-self',
 497   '-Wmissing-include-dirs',
 498   '-Waddress',
 499   '-Waggregate-return',
 500   '-Wno-multichar',
 501   '-Wvla',
 502   '-Wpointer-arith',
 503 ]
 504
 505 foreach extra_arg : warning_flags
 506   if cc.has_argument (extra_arg)
 507     add_project_arguments([extra_arg], language: 'c')
 508   endif
 509 endforeach
 510
 511 # Used by the gstutils test
 512 gmp_dep = cc.find_library('gmp', required : false)
 513 cdata.set('HAVE_GMP', gmp_dep.found())
 514 gsl_dep = cc.find_library('gsl', required : false)
 515 gslcblas_dep = cc.find_library('gslcblas', required : false)
 516 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 517 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 518
 519 # Used by gstinfo.c
 520 dl_dep = cc.find_library('dl', required : false)
 521 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 522 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 523 cdata.set('USE_POISONING', get_option('poisoning'))
 524
 525 configinc = include_directories('.')
 526 libsinc = include_directories('libs')
 527 privinc = include_directories('gst')
 528
 529 glib_req = '>= 2.62.0'
 530
 531 # Find dependencies
 532 glib_dep = dependency('glib-2.0', version: glib_req,
 533   fallback: ['glib', 'libglib_dep'])
 534 gobject_dep = dependency('gobject-2.0')
 535 gmodule_dep = dependency('gmodule-no-export-2.0')
 536 if host_system == 'windows'
 537     gio_dep = dependency('gio-2.0')
 538 else
 539     gio_dep = [dependency('gio-2.0'),
 540                dependency('gio-unix-2.0')]
 541 endif
 542
 543 mathlib = cc.find_library('m', required : false)
 544 # Needed for timer_create/settime/delete
 545 # Also provides clock_gettime in glibc < 2.17
 546 rt_lib = cc.find_library('rt', required : false)
 547
 548 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 549 gnome = import('gnome')
 550
 551 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 552
 553 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 554     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 555     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 556     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 557     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 558     'gst_init(NULL,NULL);', '--quiet']
 559
 560 gst_c_args = ['-DHAVE_CONFIG_H']
 561
 562 # FIXME: This is only needed on windows and probably breaks when
 563 # default_library = 'both'. We should add this flag to static_c_args instead
 564 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 565 if get_option('default_library') == 'static'
 566   gst_c_args += ['-DGST_STATIC_COMPILATION']
 567 endif
 568
 569 # Used in gst/parse/meson.build and below
 570 python3 = import('python').find_installation()
 571
 572 bashcomp_option = get_option('bash-completion')
 573 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 574 bash_completions_dir = ''
 575 bash_helpers_dir = ''
 576
 577 bashcomp_found = false
 578 if bashcomp_dep.found()
 579   bashcomp_found = true
 580   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 581   bash_completions_dir = bashcomp_dep.get_variable('completionsdir', pkgconfig_define:  bashcomp_dir_override)
 582   if bash_completions_dir == ''
 583     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 584     if bashcomp_option.enabled()
 585       error(msg)
 586     else
 587       message(msg)
 588     endif
 589     bashcomp_found = false
 590   endif
 591
 592   bash_helpers_dir = bashcomp_dep.get_variable('helpersdir', pkgconfig_define:  bashcomp_dir_override)
 593   if bash_helpers_dir == ''
 594     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 595     if bashcomp_option.enabled()
 596       error(msg)
 597     else
 598       message(msg)
 599     endif
 600     bashcomp_found = false
 601   endif
 602 endif
 603
 604 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 605
 606 pkgconfig = import('pkgconfig')
 607 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 608 if get_option('default_library') == 'shared'
 609   # If we don't build static plugins there is no need to generate pc files
 610   plugins_pkgconfig_install_dir = disabler()
 611 endif
 612 pkgconfig_variables = [
 613   'exec_prefix=${prefix}',
 614   'toolsdir=${exec_prefix}/bin',
 615   'pluginsdir=${libdir}/gstreamer-1.0',
 616   'girdir=${datadir}/gir-1.0',
 617   'typelibdir=${libdir}/girepository-1.0',
 618   'pluginscannerdir=${libexecdir}/gstreamer-1.0'
 619 ]
 620 pkgconfig_uninstalled_variables = ['exec_prefix=${prefix}',
 621         'gstreamerdir=${prefix}/subprojects/gstreamer',
 622     'bashhelpersdir=${gstreamerdir}/data/bash-completion/helpers',
 623     'helpersdir=${gstreamerdir}/libs/gst/helpers']
 624 pkgconfig_subdirs = ['gstreamer-1.0']
 625 pkgconfig_libs = []
 626 if host_system == 'darwin'
 627   pkgconfig_libs = ['-Wl,-rpath,${libdir}']
 628 endif
 629
 630 static_build = get_option('default_library') == 'static'
 631 gst_libraries = []
 632 subdir('gst')
 633 subdir('libs')
 634 subdir('plugins')
 635 subdir('tools')
 636 subdir('tests')
 637 subdir('data')
 638 subdir('docs')
 639
 640 # xgettext is optional (on Windows for instance)
 641 if find_program('xgettext', required : get_option('nls')).found()
 642   cdata.set('ENABLE_NLS', 1)
 643   subdir('po')
 644 endif
 645
 646 subdir('scripts')
 647
 648 # Set release date
 649 if gst_version_nano == 0
 650   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 651   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'), check: true)
 652   release_date = run_result.stdout().strip()
 653   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 654   message('Package release date: ' + release_date)
 655 endif
 656
 657 configure_file(output : 'config.h', configuration : cdata)
 658 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 659
 660 meson.add_dist_script('scripts/gen-changelog.py', meson.project_name(), '1.20.0', meson.project_version())
 661
 662 plugin_names = []
 663 gst_plugins = []
 664 foreach plugin: plugins
 665   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 666   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 667   meson.override_dependency(plugin.name(), dep)
 668   gst_plugins += [dep]
 669   if plugin.name().startswith('gst')
 670     plugin_names += [plugin.name().substring(3)]
 671   else
 672     plugin_names += [plugin.name()]
 673   endif
 674 endforeach
 675
 676 summary({
 677     'Plugins': plugin_names,
 678 }, list_sep: ', ')