subprojects/gstreamer/meson.build

   1 project('gstreamer', 'c',
   2   version : '1.21.3.1',
   3   meson_version : '>= 0.62',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 apiversion = '1.0'
  20 soversion = 0
  21 # maintaining compatibility with the previous libtool versioning
  22 # current = minor * 100 + micro
  23 curversion = gst_version_minor * 100 + gst_version_micro
  24 libversion = '@0@.@1@.0'.format(soversion, curversion)
  25 osxversion = curversion + 1
  26
  27 prefix = get_option('prefix')
  28
  29 datadir = join_paths(prefix, get_option('datadir'))
  30 libexecdir = get_option('libexecdir')
  31 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  32
  33 cc = meson.get_compiler('c')
  34 host_system = host_machine.system()
  35
  36 if host_system == 'darwin'
  37   ios_test_code = '''#include <TargetConditionals.h>
  38   #if ! TARGET_OS_IPHONE
  39   #error "Not iOS/tvOS/watchOS/iPhoneSimulator"
  40   #endif'''
  41   if cc.compiles(ios_test_code, name : 'building for iOS')
  42     host_system = 'ios'
  43   endif
  44
  45   add_languages('objc', native: false, required: true)
  46 endif
  47
  48 cdata = configuration_data()
  49
  50 if cc.get_id() == 'msvc'
  51   msvc_args = [
  52       # Ignore several spurious warnings for things gstreamer does very commonly
  53       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  54       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  55       # NOTE: Only add warnings here if you are sure they're spurious
  56       '/wd4018', # implicit signed/unsigned conversion
  57       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  58       '/wd4244', # lossy type conversion (e.g. double -> int)
  59       '/wd4305', # truncating type conversion (e.g. double -> float)
  60       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  61   ]
  62
  63   if gst_version_is_dev
  64     # Enable some warnings on MSVC to match GCC/Clang behaviour
  65     msvc_args += cc.get_supported_arguments([
  66       '/we4002', # too many actual parameters for macro 'identifier'
  67       '/we4003', # not enough actual parameters for macro 'identifier'
  68       '/we4013', # 'function' undefined; assuming extern returning int
  69       '/we4020', # 'function' : too many actual parameters
  70       '/we4027', # function declared without formal parameter list
  71       '/we4029', # declared formal parameter list different from definition
  72       '/we4033', # 'function' must return a value
  73       '/we4045', # 'array' : array bounds overflow
  74       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  75       '/we4053', # one void operand for '?:'
  76       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  77       '/we4098', # 'function' : void function returning a value
  78       '/we4101', # 'identifier' : unreferenced local variable
  79       '/we4189', # 'identifier' : local variable is initialized but not referenced
  80     ])
  81   endif
  82   add_project_arguments(msvc_args, language: 'c')
  83 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  84   # FIXME: Add an option for this if people ask for it
  85   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  86 endif
  87
  88 # glib doesn't support unloading, which means that unloading and reloading
  89 # any library that registers static types will fail
  90 if cc.has_link_argument('-Wl,-z,nodelete')
  91   add_project_link_arguments('-Wl,-z,nodelete', language: 'c')
  92 endif
  93
  94 # Symbol visibility
  95 have_visibility_hidden = false
  96 if cc.get_id() == 'msvc'
  97   export_define = '__declspec(dllexport) extern'
  98 elif cc.has_argument('-fvisibility=hidden')
  99   add_project_arguments('-fvisibility=hidden', language: 'c')
 100   export_define = 'extern __attribute__ ((visibility ("default")))'
 101   have_visibility_hidden = true
 102 else
 103   export_define = 'extern'
 104 endif
 105
 106 # Passing this through the command line would be too messy
 107 cdata.set('GST_API_EXPORT', export_define)
 108
 109 # Disable strict aliasing
 110 if cc.has_argument('-fno-strict-aliasing')
 111   add_project_arguments('-fno-strict-aliasing', language: 'c')
 112 endif
 113
 114 # Define G_DISABLE_DEPRECATED for development versions
 115 if gst_version_is_dev
 116   message('Disabling deprecated GLib API')
 117   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 118 endif
 119
 120 cast_checks = get_option('gobject-cast-checks')
 121 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 122   message('Disabling GLib cast checks')
 123   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 124 endif
 125
 126 glib_asserts = get_option('glib-asserts')
 127 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 128   message('Disabling GLib asserts')
 129   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 130 endif
 131
 132 glib_checks = get_option('glib-checks')
 133 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 134   message('Disabling GLib checks')
 135   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 136 endif
 137
 138 cdata.set_quoted('GST_API_VERSION', apiversion)
 139 cdata.set_quoted('GST_DATADIR', datadir)
 140 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 141 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 142 cdata.set_quoted('GST_API_VERSION', '1.0')
 143 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 144 cdata.set_quoted('GST_LICENSE', 'LGPL')
 145 cdata.set_quoted('PACKAGE', 'gstreamer')
 146 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 147 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 148 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 149 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 150 cdata.set_quoted('PACKAGE_URL', '')
 151 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 152 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 153 cdata.set_quoted('VERSION', gst_version)
 154 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 155 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 156 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 157   description: 'plugin directory path component, used to find plugins on relocatable builds')
 158 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 159   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds')
 160 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 161
 162 mem_align_opt = get_option('memory-alignment')
 163 if mem_align_opt == 'malloc'
 164   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 165 elif mem_align_opt == 'pagesize'
 166   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 167 else
 168   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 169 endif
 170
 171 if ['darwin', 'ios'].contains(host_system)
 172   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 173 endif
 174
 175 if gst_version_nano > 0
 176     # Have GST_ERROR message printed when running from git
 177     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 178 else
 179     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 180 endif
 181
 182 # GStreamer package name and origin url
 183 gst_package_name = get_option('package-name')
 184 if gst_package_name == ''
 185   if gst_version_nano == 0
 186     gst_package_name = 'GStreamer source release'
 187   elif gst_version_nano == 1
 188     gst_package_name = 'GStreamer git'
 189   else
 190     gst_package_name = 'GStreamer prerelease'
 191   endif
 192 endif
 193 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 194 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 195
 196 # These are only needed/used by the ABI tests
 197 host_defines = [
 198   [ 'x86', 'HAVE_CPU_I386' ],
 199   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 200   [ 'arm', 'HAVE_CPU_ARM' ],
 201   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 202   [ 'mips', 'HAVE_CPU_MIPS' ],
 203   [ 'powerpc', 'HAVE_CPU_PPC' ],
 204   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 205   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 206   [ 'sparc', 'HAVE_CPU_SPARC' ],
 207   [ 'ia64', 'HAVE_CPU_IA64' ],
 208   [ 'hppa', 'HAVE_CPU_HPPA' ],
 209   [ 'm68k', 'HAVE_CPU_M68K' ],
 210   [ 's390', 'HAVE_CPU_S390' ],
 211 ]
 212 foreach h : host_defines
 213   if h.get(0) == host_machine.cpu_family()
 214     cdata.set(h.get(1), 1)
 215   endif
 216 endforeach
 217 # FIXME: should really be called HOST_CPU or such
 218 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 219
 220 check_headers = [
 221   'dlfcn.h',
 222   'inttypes.h',
 223   'memory.h',
 224   'poll.h',
 225   'stdint.h',
 226   'stdio_ext.h',
 227   'strings.h',
 228   'string.h',
 229   'sys/param.h',
 230   'sys/poll.h',
 231   'sys/prctl.h',
 232   'sys/socket.h',
 233   'sys/stat.h',
 234   'sys/times.h',
 235   'sys/time.h',
 236   'sys/types.h',
 237   'sys/utsname.h',
 238   'sys/wait.h',
 239   'ucontext.h',
 240   'unistd.h',
 241   'sys/resource.h',
 242   'sys/uio.h',
 243 ]
 244
 245 if host_system == 'windows'
 246   check_headers += ['winsock2.h']
 247 endif
 248
 249 foreach h : check_headers
 250   if cc.has_header(h)
 251     define = 'HAVE_' + h.underscorify().to_upper()
 252     cdata.set(define, 1)
 253   endif
 254 endforeach
 255
 256 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 257   cdata.set('HAVE_TM_GMTOFF', 1)
 258 endif
 259
 260 check_functions = [
 261   'gmtime_r',
 262   'sigaction',
 263   'getrusage',
 264   'fseeko',
 265   'ftello',
 266   'poll',
 267   'ppoll',
 268   'pselect',
 269   'getpagesize',
 270   'clock_gettime',
 271   'clock_nanosleep',
 272   'strnlen',
 273   # These are needed by libcheck
 274   'getline',
 275   'mkstemp',
 276   'alarm',
 277   'gettimeofday',
 278 ]
 279
 280 foreach f : check_functions
 281   if cc.has_function(f)
 282     define = 'HAVE_' + f.underscorify().to_upper()
 283     cdata.set(define, 1)
 284   endif
 285 endforeach
 286
 287 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 288   cdata.set('HAVE_LOCALTIME_R', 1)
 289   # Needed by libcheck
 290   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 291 endif
 292
 293 if cc.links('''#define _GNU_SOURCE
 294                #include <pthread.h>
 295                int main() {
 296                  pthread_setname_np("example"); return 0;
 297                }''', name : 'pthread_setname_np(const char*)')
 298   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 299 endif
 300 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 301   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 302 endif
 303 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 304   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 305 endif
 306
 307 # Check for futex(2)
 308 if cc.compiles('''#include <linux/futex.h>
 309                #include <sys/syscall.h>
 310                #include <unistd.h>
 311                int main (int argc, char ** argv) {
 312                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 313                  return 0;
 314                }''', name : 'futex(2) system call')
 315   cdata.set('HAVE_FUTEX', 1)
 316 endif
 317 if cc.compiles('''#include <linux/futex.h>
 318                #include <sys/syscall.h>
 319                #include <unistd.h>
 320                int main (int argc, char ** argv) {
 321                  syscall (__NR_futex_time64, NULL, FUTEX_WAKE, FUTEX_WAIT);
 322                  return 0;
 323                }''', name : 'futex(2) system call')
 324   cdata.set('HAVE_FUTEX_TIME64', 1)
 325 endif
 326
 327 # Check for posix timers and monotonic clock
 328 time_prefix = '#include <time.h>\n'
 329 if cdata.has('HAVE_UNISTD_H')
 330   time_prefix += '#include <unistd.h>'
 331 endif
 332
 333 posix_timers_src = time_prefix + '''
 334 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 335 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 336 #endif
 337 '''
 338 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 339   cdata.set('HAVE_POSIX_TIMERS', 1)
 340 endif
 341
 342 monotonic_clock_src = time_prefix + '''
 343 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 344 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 345 #endif
 346 '''
 347 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 348   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 349 endif
 350
 351 # Check for __uint128_t (gcc) by checking for 128-bit division
 352 uint128_t_src = '''int main() {
 353 static __uint128_t v1 = 100;
 354 static __uint128_t v2 = 10;
 355 static __uint128_t u;
 356 u = v1 / v2;
 357 }'''
 358 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 359   cdata.set('HAVE_UINT128_T', 1)
 360 endif
 361
 362 # All supported platforms have long long now
 363 cdata.set('HAVE_LONG_LONG', 1)
 364
 365 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 366 # building with MSVC
 367 if cc.get_id() == 'msvc'
 368   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 369 else
 370   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 371 endif
 372
 373 # -------------------------------------------------------------------------------------
 374 # config.h things needed by libcheck
 375 # -------------------------------------------------------------------------------------
 376 if cc.has_function('getpid')
 377   cdata.set('HAVE_GETPID', 1)
 378 elif host_system == 'windows' and cc.has_function('_getpid')
 379   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 380   cdata.set('HAVE__GETPID', 1)
 381 endif
 382 if cc.has_function('strdup')
 383   cdata.set('HAVE_DECL_STRDUP', 1)
 384 elif host_system == 'windows' and cc.has_function('_strdup')
 385   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 386 endif
 387 if host_system != 'windows'
 388   cdata.set('HAVE_FORK', 1)
 389 else
 390   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 391   cdata.set('HAVE_FORK', 0)
 392 endif
 393 if cc.has_function('strsignal')
 394   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 395 endif
 396 # Check for availability of types
 397 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 398   cdata.set('clockid_t', 'int')
 399 endif
 400 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 401   cdata.set('timer_t', 'int')
 402 endif
 403 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 404                       prefix : '#include <time.h>')
 405   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 406 endif
 407 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 408                       prefix : '#include <time.h>')
 409   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 410 endif
 411 if host_system != 'windows'
 412   cdata.set('HAVE_PIPE', 1)
 413 elif cc.has_function('_pipe', prefix : '#include <io.h>')
 414   cdata.set('HAVE_PIPE', 1)
 415 endif
 416
 417 # Platform deps; only ws2_32 and execinfo for now
 418 platform_deps = []
 419 if host_system == 'windows'
 420   platform_deps = [cc.find_library('ws2_32')]
 421 endif
 422
 423 building_for_uwp = false
 424 if host_system == 'windows'
 425   # Check whether we're building for UWP apps
 426   code = '''
 427   #include <windows.h>
 428   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 429   #error "Not building for UWP"
 430   #endif'''
 431   if cc.compiles(code, name : 'building for UWP')
 432     building_for_uwp = true
 433   endif
 434
 435   building_for_win7 = cc.compiles('''#include <windows.h>
 436       #ifndef WINVER
 437       #error "unknown minimum supported OS version"
 438       #endif
 439       #if (WINVER < _WIN32_WINNT_WIN7)
 440       #error "Windows 7 API is not guaranteed"
 441       #endif
 442       ''',
 443       name: 'building for Windows 7')
 444
 445   if not building_for_win7
 446     add_project_arguments([
 447       '-D_WIN32_WINNT=_WIN32_WINNT_WIN7',
 448       '-DWINVER=_WIN32_WINNT_WIN7',
 449     ], language: ['c', 'cpp'])
 450   endif
 451 endif
 452
 453 backtrace_deps = []
 454 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 455 dw_dep = dependency('libdw', required: get_option('libdw'))
 456 dbghelp_option = get_option('dbghelp')
 457 if dbghelp_option.enabled() and building_for_uwp
 458   error('DbgHelp is not supported for UWP')
 459 endif
 460 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 461 backtrace_deps = [unwind_dep, dw_dep]
 462 backtrace_source_info = false
 463 backtrace_minimal = false
 464 # MSVC debug stack trace support
 465 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 466   cdata.set('HAVE_DBGHELP', 1)
 467   backtrace_source_info = true
 468 # DWARF stack trace support with libunwind and elf-utils
 469 elif unwind_dep.found()
 470   cdata.set('HAVE_UNWIND', 1)
 471   if dw_dep.found()
 472     cdata.set('HAVE_DW', 1)
 473     backtrace_source_info = true
 474   endif
 475   backtrace_minimal = true
 476 # Basic backtrace() stack trace support
 477 elif cc.has_function('backtrace')
 478   cdata.set('HAVE_BACKTRACE', 1)
 479   backtrace_minimal = true
 480 endif
 481 # Print messages about what was enabled
 482 if not backtrace_source_info
 483   if not backtrace_minimal
 484     message('NO support for stack traces.')
 485   else
 486     message('Minimal support for stack traces, no source info.')
 487   endif
 488 endif
 489
 490 if cc.has_header('execinfo.h')
 491   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 492     cdata.set('HAVE_BACKTRACE', 1)
 493   else
 494     execinfo_dep = cc.find_library('execinfo', required : false)
 495     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 496       cdata.set('HAVE_BACKTRACE', 1)
 497       platform_deps += execinfo_dep
 498     endif
 499   endif
 500 endif
 501
 502 gst_debug = get_option('gst_debug')
 503 if not gst_debug
 504   add_project_arguments(['-Wno-unused'], language: 'c')
 505 endif
 506
 507 warning_flags = [
 508   '-Wmissing-declarations',
 509   '-Wmissing-prototypes',
 510   '-Wredundant-decls',
 511   '-Wundef',
 512   '-Wwrite-strings',
 513   '-Wformat',
 514   '-Wformat-nonliteral',
 515   '-Wformat-security',
 516   '-Wold-style-definition',
 517   '-Winit-self',
 518   '-Wmissing-include-dirs',
 519   '-Waddress',
 520   '-Waggregate-return',
 521   '-Wno-multichar',
 522   '-Wvla',
 523   '-Wpointer-arith',
 524 ]
 525
 526 foreach extra_arg : warning_flags
 527   if cc.has_argument (extra_arg)
 528     add_project_arguments([extra_arg], language: 'c')
 529   endif
 530 endforeach
 531
 532 # Used by the gstutils test
 533 gmp_dep = cc.find_library('gmp', required : false)
 534 cdata.set('HAVE_GMP', gmp_dep.found())
 535 gsl_dep = cc.find_library('gsl', required : false)
 536 gslcblas_dep = cc.find_library('gslcblas', required : false)
 537 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 538 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 539
 540 # Used by gstinfo.c
 541 dl_dep = cc.find_library('dl', required : false)
 542 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 543 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 544 cdata.set('USE_POISONING', get_option('poisoning'))
 545
 546 configinc = include_directories('.')
 547 libsinc = include_directories('libs')
 548 privinc = include_directories('gst')
 549
 550 glib_req = '>= 2.62.0'
 551
 552 # Find dependencies
 553 glib_dep = dependency('glib-2.0', version: glib_req,
 554   fallback: ['glib', 'libglib_dep'])
 555 gobject_dep = dependency('gobject-2.0')
 556 gmodule_dep = dependency('gmodule-no-export-2.0')
 557 if host_system == 'windows'
 558     gio_dep = dependency('gio-2.0')
 559 else
 560     gio_dep = [dependency('gio-2.0'),
 561                dependency('gio-unix-2.0')]
 562 endif
 563
 564 mathlib = cc.find_library('m', required : false)
 565 # Needed for timer_create/settime/delete
 566 # Also provides clock_gettime in glibc < 2.17
 567 rt_lib = cc.find_library('rt', required : false)
 568
 569 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 570 gnome = import('gnome')
 571
 572 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 573
 574 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 575     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 576     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 577     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 578     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 579     'gst_init(NULL,NULL);', '--quiet']
 580
 581 gst_c_args = ['-DHAVE_CONFIG_H']
 582
 583 # FIXME: This is only needed on windows and probably breaks when
 584 # default_library = 'both'. We should add this flag to static_c_args instead
 585 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 586 if get_option('default_library') == 'static'
 587   gst_c_args += ['-DGST_STATIC_COMPILATION']
 588 endif
 589
 590 # Used in gst/parse/meson.build and below
 591 python3 = import('python').find_installation()
 592
 593 bashcomp_option = get_option('bash-completion')
 594 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 595 bash_completions_dir = ''
 596 bash_helpers_dir = ''
 597
 598 bashcomp_found = false
 599 if bashcomp_dep.found()
 600   bashcomp_found = true
 601   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 602   bash_completions_dir = bashcomp_dep.get_variable('completionsdir', pkgconfig_define:  bashcomp_dir_override)
 603   if bash_completions_dir == ''
 604     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 605     if bashcomp_option.enabled()
 606       error(msg)
 607     else
 608       message(msg)
 609     endif
 610     bashcomp_found = false
 611   endif
 612
 613   bash_helpers_dir = bashcomp_dep.get_variable('helpersdir', pkgconfig_define:  bashcomp_dir_override)
 614   if bash_helpers_dir == ''
 615     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 616     if bashcomp_option.enabled()
 617       error(msg)
 618     else
 619       message(msg)
 620     endif
 621     bashcomp_found = false
 622   endif
 623 endif
 624
 625 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 626
 627 pkgconfig = import('pkgconfig')
 628 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 629 if get_option('default_library') == 'shared'
 630   # If we don't build static plugins there is no need to generate pc files
 631   plugins_pkgconfig_install_dir = disabler()
 632 endif
 633 pkgconfig_variables = [
 634   'exec_prefix=${prefix}',
 635   'toolsdir=${exec_prefix}/bin',
 636   'pluginsdir=${libdir}/gstreamer-1.0',
 637   'girdir=${datadir}/gir-1.0',
 638   'typelibdir=${libdir}/girepository-1.0',
 639   'pluginscannerdir=${libexecdir}/gstreamer-1.0'
 640 ]
 641 pkgconfig_uninstalled_variables = ['exec_prefix=${prefix}',
 642         'gstreamerdir=${prefix}/subprojects/gstreamer',
 643     'bashhelpersdir=${gstreamerdir}/data/bash-completion/helpers',
 644     'helpersdir=${gstreamerdir}/libs/gst/helpers']
 645 pkgconfig_subdirs = ['gstreamer-1.0']
 646 pkgconfig_libs = []
 647 if host_system == 'darwin'
 648   pkgconfig_libs = ['-Wl,-rpath,${libdir}']
 649 endif
 650
 651 static_build = get_option('default_library') == 'static'
 652 gst_libraries = []
 653 subdir('gst')
 654 subdir('libs')
 655 subdir('plugins')
 656 subdir('tools')
 657 subdir('tests')
 658 subdir('data')
 659 subdir('docs')
 660
 661 # xgettext is optional (on Windows for instance)
 662 if find_program('xgettext', required : get_option('nls')).found()
 663   cdata.set('ENABLE_NLS', 1)
 664   subdir('po')
 665 endif
 666
 667 subdir('scripts')
 668
 669 # Set release date
 670 if gst_version_nano == 0
 671   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 672   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'), check: true)
 673   release_date = run_result.stdout().strip()
 674   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 675   message('Package release date: ' + release_date)
 676 endif
 677
 678 configure_file(output : 'config.h', configuration : cdata)
 679 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 680
 681 meson.add_dist_script('scripts/gen-changelog.py', meson.project_name(), '1.20.0', meson.project_version())
 682
 683 plugin_names = []
 684 gst_plugins = []
 685 foreach plugin: plugins
 686   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 687   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 688   meson.override_dependency(plugin.name(), dep)
 689   gst_plugins += [dep]
 690   if plugin.name().startswith('gst')
 691     plugin_names += [plugin.name().substring(3)]
 692   else
 693     plugin_names += [plugin.name()]
 694   endif
 695 endforeach
 696
 697 summary({
 698     'Plugins': plugin_names,
 699 }, list_sep: ', ')