subprojects/gstreamer/meson.build

   1 project('gstreamer', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 datadir = join_paths(prefix, get_option('datadir'))
  32 libexecdir = get_option('libexecdir')
  33 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  34
  35 cc = meson.get_compiler('c')
  36
  37 cdata = configuration_data()
  38
  39 if cc.get_id() == 'msvc'
  40   msvc_args = [
  41       # Ignore several spurious warnings for things gstreamer does very commonly
  42       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44       # NOTE: Only add warnings here if you are sure they're spurious
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50   ]
  51
  52   if gst_version_is_dev
  53     # Enable some warnings on MSVC to match GCC/Clang behaviour
  54     msvc_args += cc.get_supported_arguments([
  55       '/we4002', # too many actual parameters for macro 'identifier'
  56       '/we4003', # not enough actual parameters for macro 'identifier'
  57       '/we4013', # 'function' undefined; assuming extern returning int
  58       '/we4020', # 'function' : too many actual parameters
  59       '/we4027', # function declared without formal parameter list
  60       '/we4029', # declared formal parameter list different from definition
  61       '/we4033', # 'function' must return a value
  62       '/we4045', # 'array' : array bounds overflow
  63       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  64       '/we4053', # one void operand for '?:'
  65       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  66       '/we4098', # 'function' : void function returning a value
  67       '/we4101', # 'identifier' : unreferenced local variable
  68       '/we4189', # 'identifier' : local variable is initialized but not referenced
  69     ])
  70   endif
  71   add_project_arguments(msvc_args, language: 'c')
  72 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  73   # FIXME: Add an option for this if people ask for it
  74   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  75 endif
  76
  77 # Symbol visibility
  78 have_visibility_hidden = false
  79 if cc.get_id() == 'msvc'
  80   export_define = '__declspec(dllexport) extern'
  81 elif cc.has_argument('-fvisibility=hidden')
  82   add_project_arguments('-fvisibility=hidden', language: 'c')
  83   export_define = 'extern __attribute__ ((visibility ("default")))'
  84   have_visibility_hidden = true
  85 else
  86   export_define = 'extern'
  87 endif
  88
  89 # Passing this through the command line would be too messy
  90 cdata.set('GST_API_EXPORT', export_define)
  91
  92 # Disable strict aliasing
  93 if cc.has_argument('-fno-strict-aliasing')
  94   add_project_arguments('-fno-strict-aliasing', language: 'c')
  95 endif
  96
  97 # Define G_DISABLE_DEPRECATED for development versions
  98 if gst_version_is_dev
  99   message('Disabling deprecated GLib API')
 100   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 101 endif
 102
 103 cast_checks = get_option('gobject-cast-checks')
 104 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 105   message('Disabling GLib cast checks')
 106   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 107 endif
 108
 109 glib_asserts = get_option('glib-asserts')
 110 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 111   message('Disabling GLib asserts')
 112   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 113 endif
 114
 115 glib_checks = get_option('glib-checks')
 116 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 117   message('Disabling GLib checks')
 118   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 119 endif
 120
 121 cdata.set_quoted('GST_API_VERSION', apiversion)
 122 cdata.set_quoted('GST_DATADIR', datadir)
 123 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 124 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 125 cdata.set_quoted('GST_API_VERSION', '1.0')
 126 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 127 cdata.set_quoted('GST_LICENSE', 'LGPL')
 128 cdata.set_quoted('PACKAGE', 'gstreamer')
 129 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 130 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 131 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 132 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 133 cdata.set_quoted('PACKAGE_URL', '')
 134 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 135 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 136 cdata.set_quoted('VERSION', gst_version)
 137 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 138 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 139 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 140   description: 'plugin directory path component, used to find plugins on relocatable builds')
 141 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 142   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds')
 143 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 144
 145 mem_align_opt = get_option('memory-alignment')
 146 if mem_align_opt == 'malloc'
 147   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 148 elif mem_align_opt == 'pagesize'
 149   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 150 else
 151   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 152 endif
 153
 154 if ['darwin', 'ios'].contains(host_system)
 155   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 156 endif
 157
 158 if gst_version_nano > 0
 159     # Have GST_ERROR message printed when running from git
 160     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 161 else
 162     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 163 endif
 164
 165 # GStreamer package name and origin url
 166 gst_package_name = get_option('package-name')
 167 if gst_package_name == ''
 168   if gst_version_nano == 0
 169     gst_package_name = 'GStreamer source release'
 170   elif gst_version_nano == 1
 171     gst_package_name = 'GStreamer git'
 172   else
 173     gst_package_name = 'GStreamer prerelease'
 174   endif
 175 endif
 176 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 177 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 178
 179 # These are only needed/used by the ABI tests
 180 host_defines = [
 181   [ 'x86', 'HAVE_CPU_I386' ],
 182   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 183   [ 'arm', 'HAVE_CPU_ARM' ],
 184   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 185   [ 'mips', 'HAVE_CPU_MIPS' ],
 186   [ 'powerpc', 'HAVE_CPU_PPC' ],
 187   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 188   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 189   [ 'sparc', 'HAVE_CPU_SPARC' ],
 190   [ 'ia64', 'HAVE_CPU_IA64' ],
 191   [ 'hppa', 'HAVE_CPU_HPPA' ],
 192   [ 'm68k', 'HAVE_CPU_M68K' ],
 193   [ 's390', 'HAVE_CPU_S390' ],
 194 ]
 195 foreach h : host_defines
 196   if h.get(0) == host_machine.cpu_family()
 197     cdata.set(h.get(1), 1)
 198   endif
 199 endforeach
 200 # FIXME: should really be called HOST_CPU or such
 201 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 202
 203 check_headers = [
 204   'dlfcn.h',
 205   'inttypes.h',
 206   'memory.h',
 207   'poll.h',
 208   'stdint.h',
 209   'stdio_ext.h',
 210   'strings.h',
 211   'string.h',
 212   'sys/param.h',
 213   'sys/poll.h',
 214   'sys/prctl.h',
 215   'sys/socket.h',
 216   'sys/stat.h',
 217   'sys/times.h',
 218   'sys/time.h',
 219   'sys/types.h',
 220   'sys/utsname.h',
 221   'sys/wait.h',
 222   'ucontext.h',
 223   'unistd.h',
 224   'sys/resource.h',
 225   'sys/uio.h',
 226 ]
 227
 228 if host_system == 'windows'
 229   check_headers += ['winsock2.h']
 230 endif
 231
 232 foreach h : check_headers
 233   if cc.has_header(h)
 234     define = 'HAVE_' + h.underscorify().to_upper()
 235     cdata.set(define, 1)
 236   endif
 237 endforeach
 238
 239 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 240   cdata.set('HAVE_TM_GMTOFF', 1)
 241 endif
 242
 243 check_functions = [
 244   'gmtime_r',
 245   'sigaction',
 246   'getrusage',
 247   'fseeko',
 248   'ftello',
 249   'poll',
 250   'ppoll',
 251   'pselect',
 252   'getpagesize',
 253   'clock_gettime',
 254   'clock_nanosleep',
 255   'strnlen',
 256   # These are needed by libcheck
 257   'getline',
 258   'mkstemp',
 259   'alarm',
 260   'gettimeofday',
 261 ]
 262
 263 foreach f : check_functions
 264   if cc.has_function(f)
 265     define = 'HAVE_' + f.underscorify().to_upper()
 266     cdata.set(define, 1)
 267   endif
 268 endforeach
 269
 270 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 271   cdata.set('HAVE_LOCALTIME_R', 1)
 272   # Needed by libcheck
 273   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 274 endif
 275
 276 if cc.links('''#include <pthread.h>
 277                int main() {
 278                  pthread_setname_np("example"); return 0;
 279                }''', name : 'pthread_setname_np(const char*)')
 280   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 281 endif
 282 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 283   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 284 endif
 285 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 286   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 287 endif
 288
 289 # Check for futex(2)
 290 if cc.links('''#include <linux/futex.h>
 291                #include <sys/syscall.h>
 292                #include <unistd.h>
 293                int main (int argc, char ** argv) {
 294                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 295                  return 0;
 296                }''', name : 'futex(2) system call')
 297   cdata.set('HAVE_FUTEX', 1)
 298 endif
 299
 300 # Check for posix timers and monotonic clock
 301 time_prefix = '#include <time.h>\n'
 302 if cdata.has('HAVE_UNISTD_H')
 303   time_prefix += '#include <unistd.h>'
 304 endif
 305
 306 posix_timers_src = time_prefix + '''
 307 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 308 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 309 #endif
 310 '''
 311 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 312   cdata.set('HAVE_POSIX_TIMERS', 1)
 313 endif
 314
 315 monotonic_clock_src = time_prefix + '''
 316 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 317 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 318 #endif
 319 '''
 320 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 321   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 322 endif
 323
 324 # Check for __uint128_t (gcc) by checking for 128-bit division
 325 uint128_t_src = '''int main() {
 326 static __uint128_t v1 = 100;
 327 static __uint128_t v2 = 10;
 328 static __uint128_t u;
 329 u = v1 / v2;
 330 }'''
 331 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 332   cdata.set('HAVE_UINT128_T', 1)
 333 endif
 334
 335 # All supported platforms have long long now
 336 cdata.set('HAVE_LONG_LONG', 1)
 337
 338 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 339 # building with MSVC
 340 if cc.get_id() == 'msvc'
 341   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 342 else
 343   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 344 endif
 345
 346 # -------------------------------------------------------------------------------------
 347 # config.h things needed by libcheck
 348 # -------------------------------------------------------------------------------------
 349 if cc.has_function('getpid')
 350   cdata.set('HAVE_GETPID', 1)
 351 elif host_system == 'windows' and cc.has_function('_getpid')
 352   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 353   cdata.set('HAVE__GETPID', 1)
 354 endif
 355 if cc.has_function('strdup')
 356   cdata.set('HAVE_DECL_STRDUP', 1)
 357 elif host_system == 'windows' and cc.has_function('_strdup')
 358   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 359 endif
 360 if host_system != 'windows'
 361   cdata.set('HAVE_FORK', 1)
 362 else
 363   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 364   cdata.set('HAVE_FORK', 0)
 365 endif
 366 if cc.has_function('strsignal')
 367   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 368 endif
 369 # Check for availability of types
 370 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 371   cdata.set('clockid_t', 'int')
 372 endif
 373 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 374   cdata.set('timer_t', 'int')
 375 endif
 376 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 377                       prefix : '#include <time.h>')
 378   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 379 endif
 380 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 381                       prefix : '#include <time.h>')
 382   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 383 endif
 384 if host_system != 'windows'
 385   cdata.set('HAVE_PIPE', 1)
 386 elif cc.has_function('_pipe', prefix : '#include <io.h>')
 387   cdata.set('HAVE_PIPE', 1)
 388 endif
 389
 390 # Platform deps; only ws2_32 and execinfo for now
 391 platform_deps = []
 392 if host_system == 'windows'
 393   platform_deps = [cc.find_library('ws2_32')]
 394 endif
 395
 396 building_for_uwp = false
 397 if host_system == 'windows'
 398   # Check whether we're building for UWP apps
 399   code = '''
 400   #include <windows.h>
 401   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 402   #error "Not building for UWP"
 403   #endif'''
 404   if cc.compiles(code, name : 'building for UWP')
 405     building_for_uwp = true
 406   endif
 407 endif
 408
 409 backtrace_deps = []
 410 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 411 dw_dep = dependency('libdw', required: get_option('libdw'))
 412 dbghelp_option = get_option('dbghelp')
 413 if dbghelp_option.enabled() and building_for_uwp
 414   error('DbgHelp is not supported for UWP')
 415 endif
 416 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 417 backtrace_deps = [unwind_dep, dw_dep]
 418 backtrace_source_info = false
 419 backtrace_minimal = false
 420 # MSVC debug stack trace support
 421 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 422   cdata.set('HAVE_DBGHELP', 1)
 423   backtrace_source_info = true
 424 # DWARF stack trace support with libunwind and elf-utils
 425 elif unwind_dep.found()
 426   cdata.set('HAVE_UNWIND', 1)
 427   if dw_dep.found()
 428     cdata.set('HAVE_DW', 1)
 429     backtrace_source_info = true
 430   endif
 431   backtrace_minimal = true
 432 # Basic backtrace() stack trace support
 433 elif cc.has_function('backtrace')
 434   cdata.set('HAVE_BACKTRACE', 1)
 435   backtrace_minimal = true
 436 endif
 437 # Print messages about what was enabled
 438 if not backtrace_source_info
 439   if not backtrace_minimal
 440     message('NO support for stack traces.')
 441   else
 442     message('Minimal support for stack traces, no source info.')
 443   endif
 444 endif
 445
 446 if cc.has_header('execinfo.h')
 447   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 448     cdata.set('HAVE_BACKTRACE', 1)
 449   else
 450     execinfo_dep = cc.find_library('execinfo', required : false)
 451     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 452       cdata.set('HAVE_BACKTRACE', 1)
 453       platform_deps += execinfo_dep
 454     endif
 455   endif
 456 endif
 457
 458 gst_debug = get_option('gst_debug')
 459 if not gst_debug
 460   add_project_arguments(['-Wno-unused'], language: 'c')
 461 endif
 462
 463 warning_flags = [
 464   '-Wmissing-declarations',
 465   '-Wmissing-prototypes',
 466   '-Wredundant-decls',
 467   '-Wundef',
 468   '-Wwrite-strings',
 469   '-Wformat',
 470   '-Wformat-nonliteral',
 471   '-Wformat-security',
 472   '-Wold-style-definition',
 473   '-Winit-self',
 474   '-Wmissing-include-dirs',
 475   '-Waddress',
 476   '-Waggregate-return',
 477   '-Wno-multichar',
 478   '-Wdeclaration-after-statement',
 479   '-Wvla',
 480   '-Wpointer-arith',
 481 ]
 482
 483 foreach extra_arg : warning_flags
 484   if cc.has_argument (extra_arg)
 485     add_project_arguments([extra_arg], language: 'c')
 486   endif
 487 endforeach
 488
 489 # Used by the gstutils test
 490 gmp_dep = cc.find_library('gmp', required : false)
 491 cdata.set('HAVE_GMP', gmp_dep.found())
 492 gsl_dep = cc.find_library('gsl', required : false)
 493 gslcblas_dep = cc.find_library('gslcblas', required : false)
 494 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 495 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 496
 497 # Used by gstinfo.c
 498 dl_dep = cc.find_library('dl', required : false)
 499 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 500 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 501 cdata.set('USE_POISONING', get_option('poisoning'))
 502
 503 configinc = include_directories('.')
 504 libsinc = include_directories('libs')
 505 privinc = include_directories('gst')
 506
 507 # Find dependencies
 508 glib_dep = dependency('glib-2.0', version : '>=2.56.0',
 509   fallback: ['glib', 'libglib_dep'])
 510 gobject_dep = dependency('gobject-2.0',
 511   fallback: ['glib', 'libgobject_dep'])
 512 gmodule_dep = dependency('gmodule-2.0',
 513   fallback: ['glib', 'libgmodule_dep'])
 514 if host_system == 'windows'
 515     gio_dep = dependency('gio-2.0',
 516         fallback: ['glib', 'libgio_dep'])
 517 else
 518     gio_dep = [dependency('gio-2.0',
 519                   fallback: ['glib', 'libgio_dep']),
 520                dependency('gio-unix-2.0',
 521                   fallback: ['glib', 'libgio_dep'])]
 522 endif
 523
 524 mathlib = cc.find_library('m', required : false)
 525 # Needed for timer_create/settime/delete
 526 # Also provides clock_gettime in glibc < 2.17
 527 rt_lib = cc.find_library('rt', required : false)
 528
 529 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 530 gnome = import('gnome')
 531
 532 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 533
 534 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 535     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 536     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 537     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 538     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 539     'gst_init(NULL,NULL);', '--quiet']
 540
 541 gst_c_args = ['-DHAVE_CONFIG_H']
 542
 543 # FIXME: This is only needed on windows and probably breaks when
 544 # default_library = 'both'. We should add this flag to static_c_args instead
 545 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 546 if get_option('default_library') == 'static'
 547   gst_c_args += ['-DGST_STATIC_COMPILATION']
 548 endif
 549
 550 # Used in gst/parse/meson.build and below
 551 python3 = import('python').find_installation()
 552
 553 bashcomp_option = get_option('bash-completion')
 554 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 555 bash_completions_dir = ''
 556 bash_helpers_dir = ''
 557
 558 bashcomp_found = false
 559 if bashcomp_dep.found()
 560   bashcomp_found = true
 561   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 562   bash_completions_dir = bashcomp_dep.get_variable('completionsdir', pkgconfig_define:  bashcomp_dir_override)
 563   if bash_completions_dir == ''
 564     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 565     if bashcomp_option.enabled()
 566       error(msg)
 567     else
 568       message(msg)
 569     endif
 570     bashcomp_found = false
 571   endif
 572
 573   bash_helpers_dir = bashcomp_dep.get_variable('helpersdir', pkgconfig_define:  bashcomp_dir_override)
 574   if bash_helpers_dir == ''
 575     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 576     if bashcomp_option.enabled()
 577       error(msg)
 578     else
 579       message(msg)
 580     endif
 581     bashcomp_found = false
 582   endif
 583 endif
 584
 585 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 586
 587 pkgconfig = import('pkgconfig')
 588 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 589 if get_option('default_library') == 'shared'
 590   # If we don't build static plugins there is no need to generate pc files
 591   plugins_pkgconfig_install_dir = disabler()
 592 endif
 593 pkgconfig_variables = ['exec_prefix=${prefix}',
 594     'toolsdir=${exec_prefix}/bin',
 595     'pluginsdir=${libdir}/gstreamer-1.0',
 596     'datarootdir=${prefix}/share',
 597     'datadir=${datarootdir}',
 598     'girdir=${datadir}/gir-1.0',
 599     'typelibdir=${libdir}/girepository-1.0',
 600     'libexecdir=${prefix}/libexec',
 601     'pluginscannerdir=${libexecdir}/gstreamer-1.0']
 602 pkgconfig_uninstalled_variables = ['exec_prefix=${prefix}',
 603         'gstreamerdir=${prefix}/subprojects/gstreamer',
 604     'bashhelpersdir=${gstreamerdir}/data/bash-completion/helpers',
 605     'helpersdir=${gstreamerdir}/libs/gst/helpers']
 606 pkgconfig_subdirs = ['gstreamer-1.0']
 607
 608 static_build = get_option('default_library') == 'static'
 609 libraries = []
 610 subdir('gst')
 611 subdir('libs')
 612 subdir('plugins')
 613 subdir('tools')
 614 subdir('tests')
 615 subdir('data')
 616 subdir('docs')
 617
 618 # xgettext is optional (on Windows for instance)
 619 if find_program('xgettext', required : get_option('nls')).found()
 620   cdata.set('ENABLE_NLS', 1)
 621   subdir('po')
 622 endif
 623
 624 subdir('scripts')
 625
 626 # Set release date
 627 if gst_version_nano == 0
 628   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 629   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'), check: true)
 630   release_date = run_result.stdout().strip()
 631   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 632   message('Package release date: ' + release_date)
 633 endif
 634
 635 configure_file(output : 'config.h', configuration : cdata)
 636 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 637
 638 plugin_names = []
 639 foreach plugin: plugins
 640   if plugin.name().startswith('gst')
 641     plugin_names += [plugin.name().substring(3)]
 642   else
 643     plugin_names += [plugin.name()]
 644   endif
 645 endforeach
 646
 647 summary({
 648     'Plugins': plugin_names,
 649 }, list_sep: ', ')