subprojects/gst-rtsp-server/gst/rtsp-server/meson.build

   1 rtsp_server_sources = files(
   2   'rtsp-address-pool.c',
   3   'rtsp-auth.c',
   4   'rtsp-client.c',
   5   'rtsp-context.c',
   6   'rtsp-latency-bin.c',
   7   'rtsp-media.c',
   8   'rtsp-media-factory.c',
   9   'rtsp-media-factory-uri.c',
  10   'rtsp-mount-points.c',
  11   'rtsp-params.c',
  12   'rtsp-permissions.c',
  13   'rtsp-sdp.c',
  14   'rtsp-server.c',
  15   'rtsp-session.c',
  16   'rtsp-session-media.c',
  17   'rtsp-session-pool.c',
  18   'rtsp-stream.c',
  19   'rtsp-stream-transport.c',
  20   'rtsp-thread-pool.c',
  21   'rtsp-token.c',
  22   'rtsp-onvif-server.c',
  23   'rtsp-onvif-client.c',
  24   'rtsp-onvif-media-factory.c',
  25   'rtsp-onvif-media.c',
  26 )
  27
  28 rtsp_server_headers = files(
  29   'rtsp-auth.h',
  30   'rtsp-address-pool.h',
  31   'rtsp-context.h',
  32   'rtsp-params.h',
  33   'rtsp-sdp.h',
  34   'rtsp-thread-pool.h',
  35   'rtsp-media.h',
  36   'rtsp-media-factory.h',
  37   'rtsp-media-factory-uri.h',
  38   'rtsp-mount-points.h',
  39   'rtsp-permissions.h',
  40   'rtsp-stream.h',
  41   'rtsp-stream-transport.h',
  42   'rtsp-session.h',
  43   'rtsp-session-media.h',
  44   'rtsp-session-pool.h',
  45   'rtsp-token.h',
  46   'rtsp-client.h',
  47   'rtsp-server.h',
  48   'rtsp-server-object.h',
  49   'rtsp-server-prelude.h',
  50   'rtsp-onvif-server.h',
  51   'rtsp-onvif-client.h',
  52   'rtsp-onvif-media-factory.h',
  53   'rtsp-onvif-media.h',
  54 )
  55
  56 install_headers(rtsp_server_headers, subdir : 'gstreamer-1.0/gst/rtsp-server')
  57
  58 gst_rtsp_server_deps = [gstrtsp_dep, gstrtp_dep, gstsdp_dep, gstnet_dep, gstapp_dep]
  59 gst_rtsp_server = library('gstrtspserver-@0@'.format(api_version),
  60   rtsp_server_sources,
  61   include_directories : rtspserver_incs,
  62   c_args: rtspserver_args + ['-DBUILDING_GST_RTSP_SERVER', '-DG_LOG_DOMAIN="GStreamer-RTSP-Server"'],
  63   version : libversion,
  64   soversion : soversion,
  65   darwin_versions : osxversion,
  66   install : true,
  67   dependencies : gst_rtsp_server_deps)
  68
  69 library_def = {'lib': gst_rtsp_server}
  70 pkg_name = 'gstreamer-rtsp-server-' + api_version
  71 pkgconfig.generate(gst_rtsp_server,
  72   libraries : [gst_dep],
  73   subdirs : pkgconfig_subdirs,
  74   name : 'gstreamer-rtsp-server-1.0',
  75   description : 'GStreamer based RTSP server',
  76 )
  77
  78 rtsp_server_gen_sources = []
  79 if build_gir
  80   gst_gir_extra_args = gir_init_section + ['--c-include=gst/rtsp-server/rtsp-server.h']
  81   gir = {
  82     'sources' : rtsp_server_headers + rtsp_server_sources,
  83     'namespace' : 'GstRtspServer',
  84     'nsversion' : api_version,
  85     'identifier_prefix' : 'Gst',
  86     'symbol_prefix' : 'gst',
  87     'export_packages' : pkg_name,
  88     'install' : true,
  89     'extra_args' : gst_gir_extra_args,
  90     'includes' : ['Gst-1.0', 'GstRtsp-1.0', 'GstNet-1.0'],
  91     'dependencies' : gst_rtsp_server_deps,
  92   }
  93   # FIXME: Expose gir for use in gstreamer-full
  94   # Disabled for now as we get `undefined reference` to many symbols
  95   # library_def = {'gir': [gir]}
  96   if not static_build
  97     rtsp_server_gir = gnome.generate_gir(gst_rtsp_server, kwargs: gir)
  98     rtsp_server_gen_sources += [rtsp_server_gir]
  99   endif
 100 endif
 101 libraries += [[pkg_name, library_def]]
 102
 103 gst_rtsp_server_dep = declare_dependency(link_with : gst_rtsp_server,
 104   include_directories : rtspserver_incs,
 105   sources : rtsp_server_gen_sources,
 106   dependencies : [gstrtsp_dep, gstrtp_dep, gstsdp_dep, gstnet_dep, gstapp_dep])
 107
 108 meson.override_dependency(pkg_name, gst_rtsp_server_dep)